Issue834 modular ahu

AixLib/Airflow/AirHandlingUnit/ModularAirHandlingUnit/Components/BaseClasses/HeatTransfer/ConvectiveHeatTransferCoefficient.mo

@@ -0,0 +1,45 @@
+within AixLib.Airflow.AirHandlingUnit.ModularAirHandlingUnit.Components.BaseClasses.HeatTransfer;
+model ConvectiveHeatTransferCoefficient
+  "model that calculates the convective heat transfer coefficient for plane gaps in an air heat exchanger"
+
+  //Inputs
+  input Modelica.Units.SI.MassFlowRate m_flow "mass flow rate of air";
+
+  //parameters
+  parameter Modelica.Units.SI.Length s "distance between fins";
+  parameter Modelica.Units.SI.Length length "length of heat exchanger";
+  parameter Modelica.Units.SI.Length width "width of heat exchanger";
+  parameter Real nFins "number of parallel plates in heat exchanger";
+
+  //Variables
+  Real Pr "Prandtl number";
+  Real Re "Reynolds number";
+  Real Nu "Nusselt number";
+  Modelica.Units.SI.Velocity v "velocity of air";
+
+  //outputs
+  output Modelica.Units.SI.CoefficientOfHeatTransfer alpha "convective heat transfer coefficient";
+
+protected
+  constant Modelica.Units.SI.Density rho = 1.18 "density of air";
+  constant Modelica.Units.SI.DynamicViscosity mu = 17.1E-6  "dynamic viscosity of air";
+  constant Modelica.Units.SI.ThermalConductivity lambda = 0.0262 "thermal conductivity of air";
+  constant Modelica.Units.SI.SpecificHeatCapacity cp =  1006 "heat capacity of air";
+
+  Modelica.Units.SI.Length diameter "hydraulic diameter";
+
+equation
+  Pr = mu*cp/lambda;
+  Re = abs(v)*rho*diameter/mu;
+
+  diameter = 2 * s;
+  v = m_flow/(nFins * width * s);
+
+  Nu = 7.55 + (0.024*(Re*Pr*diameter/length)^1.14)/(1+0.0358*(Re*Pr*diameter/length)^0.64*Pr^0.17);
+  // Nusselt number according to: VDI-Waermeatlas 2013, p.800 eq.45
+
+  Nu = alpha * diameter / lambda;
+
+  annotation (Icon(coordinateSystem(preserveAspectRatio=false)), Diagram(
+        coordinateSystem(preserveAspectRatio=false)));
+end ConvectiveHeatTransferCoefficient;

AixLib/Airflow/AirHandlingUnit/ModularAirHandlingUnit/Components/BaseClasses/HeatTransfer/package.mo

@@ -0,0 +1,3 @@
+within AixLib.Airflow.AirHandlingUnit.ModularAirHandlingUnit.Components.BaseClasses;
+package HeatTransfer
+end HeatTransfer;

AixLib/Airflow/AirHandlingUnit/ModularAirHandlingUnit/Components/BaseClasses/HeatTransfer/package.order

@@ -0,0 +1 @@
+ConvectiveHeatTransferCoefficient

AixLib/Airflow/AirHandlingUnit/ModularAirHandlingUnit/Components/BaseClasses/PartialCooler.mo

@@ -0,0 +1,170 @@
+within AixLib.Airflow.AirHandlingUnit.ModularAirHandlingUnit.Components.BaseClasses;
+partial model PartialCooler
+  "BaseClass for cooling heat exchangers in air handling units"
+
+  // parameters
+  parameter Modelica.Units.SI.SpecificHeatCapacity c_wat = 4180 "specific heat capacity of water" annotation (HideResult = (use_T_set));
+  parameter Modelica.Units.SI.SpecificHeatCapacity cp_air = 1005 "specific heat capacity of dry air";
+  parameter Modelica.Units.SI.SpecificHeatCapacity cp_steam = 1860 "specific heat capacity of steam";
+  parameter Modelica.Units.SI.Density rho_air = 1.2 "Density of air";
+
+  parameter Boolean use_T_set=false "if true, a set temperature is used to calculate the necessary heat flow rate";
+
+  parameter Modelica.Units.SI.HeatFlowRate Q_flow_nominal(min=0) = 45E3 "maximum cooling power of cooler (design point)";
+
+  // constants
+  constant Modelica.Units.SI.SpecificEnthalpy r0 = 2500E3 "specific heat of vaporization at 0°C";
+
+  // Variables
+  Modelica.Units.SI.SpecificEnthalpy h_airIn "specific enthalpy of incoming air";
+  Modelica.Units.SI.SpecificEnthalpy h_airOut "specific enthalpy of outgoing air";
+  Modelica.Units.SI.SpecificEnthalpy h_wat "specific enthalpy of extracted water";
+
+  Modelica.Units.SI.MassFlowRate m_flow_dryairIn "mass flow rate of incoming dry air";
+  Modelica.Units.SI.MassFlowRate m_flow_dryairOut "mass flow rate of outgoing dry air";
+
+  Modelica.Units.SI.HeatFlowRate Q_flow "heat flow";
+
+  replaceable model PartialPressureDrop =
+      Components.PressureDrop.BaseClasses.partialPressureDrop annotation(choicesAllMatching=true);
+
+      PartialPressureDrop partialPressureDrop(m_flow = m_flow_airIn,
+      rho = rho_air);
+
+  Modelica.Blocks.Interfaces.RealInput m_flow_airIn(
+    final quantity = "MassFlowRate",
+    final unit = "kg/s")
+    "mass flow rate of incoming air"
+    annotation (Placement(transformation(extent={{-140,50},{-100,90}}),
+        iconTransformation(extent={{-120,70},{-100,90}})));
+  Modelica.Blocks.Interfaces.RealInput T_airIn(
+    final quantity="ThermodynamicTemperature",
+    final unit="K",
+    displayUnit="degC")
+    "Temperature of incoming air"
+    annotation (Placement(transformation(extent={{-140,20},{-100,60}}),
+        iconTransformation(extent={{-120,40},{-100,60}})));
+  Modelica.Blocks.Interfaces.RealInput X_airIn(
+    final quantity = "MassFraction",
+    final unit = "kg/kg")
+    "absolute humidity of incoming air"
+    annotation (Placement(transformation(extent={{-140,-10},{-100,30}}),
+        iconTransformation(extent={{-120,10},{-100,30}})));
+  Modelica.Blocks.Interfaces.RealOutput m_flow_airOut(
+    final quantity = "MassFlowRate",
+    final unit = "kg/s") "mass flow rate of outgoing air"
+    annotation (Placement(transformation(extent={{100,70},{120,90}})));
+  Modelica.Blocks.Interfaces.RealOutput T_airOut(
+    final quantity="ThermodynamicTemperature",
+    final unit="K",
+    displayUnit="degC") "temperature of outgoing air"
+    annotation (Placement(transformation(extent={{100,40},{120,60}}),
+        iconTransformation(extent={{100,40},{120,60}})));
+  Modelica.Blocks.Interfaces.RealOutput X_airOut(
+    final quantity = "MassFraction",
+    final unit = "kg/kg") "absolute humidity of outgoing air"
+    annotation (Placement(transformation(extent={{100,10},{120,30}}),
+        iconTransformation(extent={{100,10},{120,30}})));
+
+  Modelica.Blocks.Interfaces.RealInput T_set if use_T_set annotation (Placement(
+        transformation(
+        extent={{-20,-20},{20,20}},
+        rotation=-90,
+        origin={0,110}), iconTransformation(
+        extent={{-10,-10},{10,10}},
+        rotation=-90,
+        origin={0,100})));
+
+  Modelica.Blocks.Interfaces.RealOutput dp "pressure difference"
+    annotation (Placement(transformation(extent={{100,-30},{120,-10}})));
+  Modelica.Blocks.Interfaces.RealOutput Q "heat flow rate"
+    annotation (Placement(transformation(extent={{100,-70},{120,-50}})));
+  Modelica.Blocks.Interfaces.RealInput u(min=0,max=1) if not use_T_set "input connector scaling heat flow rate [0..1]" annotation (Placement(transformation(
+        extent={{-20,-20},{20,20}},
+        rotation=-90,
+        origin={40,110}), iconTransformation(
+        extent={{-10,-10},{10,10}},
+        rotation=-90,
+        origin={0,100})));
+protected
+  Modelica.Units.SI.MassFlowRate mb_flow "mass flow over boundary";
+  Modelica.Blocks.Interfaces.RealInput T_intern "internal temperature";
+  Modelica.Blocks.Interfaces.RealInput X_intern "internal mass fraction";
+  Modelica.Blocks.Interfaces.RealInput u_intern "internal input connector for heat flow scaling";
+  Modelica.Blocks.Math.Min min_T if use_T_set
+    annotation (Placement(transformation(extent={{-48,68},{-36,80}})));
+equation
+
+  // mass balances
+  m_flow_airIn - m_flow_airOut = mb_flow;
+
+  m_flow_dryairIn * (1 + X_airIn) = m_flow_airIn;
+  m_flow_dryairOut - m_flow_dryairIn = 0;
+
+  mb_flow = m_flow_dryairIn * (X_airIn - X_airOut); // condensate
+
+  // heat flows
+  Q_flow = m_flow_dryairIn * h_airIn - m_flow_dryairOut * h_airOut - mb_flow * h_wat;
+  Q = Q_flow;
+  if not use_T_set then
+    Q_flow = u_intern * Q_flow_nominal;
+    T_intern = T_airIn;
+  else
+    T_airOut = T_intern;
+    u_intern = 0;
+  end if;
+
+  // sepcific enthalpies
+  h_airIn = cp_air * (T_airIn - 273.15) + X_airIn * (cp_steam * (T_airIn - 273.15) + r0);
+  h_airOut = cp_air * (T_airOut - 273.15) + X_airOut * (cp_steam * (T_airOut - 273.15) + r0);
+  h_wat = c_wat * (T_airOut - 273.15);
+
+  partialPressureDrop.dp = dp;
+
+  // conditional connectors
+  connect(min_T.y,T_intern);
+  connect(u, u_intern);
+
+  // connectors
+  connect(T_set, min_T.u1) annotation (Line(points={{0,110},{0,86},{-56,86},{-56,
+          77.6},{-49.2,77.6}}, color={0,0,127}));
+  connect(T_airIn, min_T.u2) annotation (Line(points={{-120,40},{-80,40},{-80,70.4},
+          {-49.2,70.4}}, color={0,0,127}));
+  annotation (Icon(graphics={
+        Rectangle(
+          extent={{-100,94},{100,-94}},
+          lineColor={0,0,0},
+          fillColor={175,175,175},
+          fillPattern=FillPattern.Solid,
+          lineThickness=0.5),
+        Line(
+          points={{-100,94},{100,-94}},
+          color={0,0,0},
+          thickness=0.5),
+        Text(
+          extent={{-14,66},{62,48}},
+          lineColor={0,0,0},
+          lineThickness=1,
+          fillColor={175,175,175},
+          fillPattern=FillPattern.Solid,
+          textString="%name")}), Documentation(info="<html><p>
+  This partial model provides a idealized heat exchanger. The model
+  considers the convective heat transfer from the heat transfer surface
+  in the air stream. Moreover the heat capacity of the heating surface
+  and the housing of the heat exchanger is considered.
+</p>
+</html>", revisions="<html>
+<ul>
+  <li>April, 2019, by Martin Kremer:<br/>
+    First implementation.
+  </li>
+  <li>August, 2019, by Martin Kremer:<br/>
+    Added possibility to use set temperature.
+  </li>
+  <li>December, 2019, by Martin Kremer:<br/>
+    Removed internal PID. Output temperature and humidity are now
+    directly set to set temperature.
+  </li>
+</ul>
+</html>"));
+end PartialCooler;

AixLib/Airflow/AirHandlingUnit/ModularAirHandlingUnit/Components/BaseClasses/PartialHeater.mo

@@ -0,0 +1,170 @@
+within AixLib.Airflow.AirHandlingUnit.ModularAirHandlingUnit.Components.BaseClasses;
+partial model PartialHeater
+  "BaseClass for heat exchangers in air handling units"
+
+  // parameters
+  parameter Modelica.Units.SI.SpecificHeatCapacity c_wat = 4180 "specific heat capacity of water" annotation (HideResult = (use_T_set));
+  parameter Modelica.Units.SI.SpecificHeatCapacity cp_air = 1005 "specific heat capacity of dry air";
+  parameter Modelica.Units.SI.SpecificHeatCapacity cp_steam = 1860 "specific heat capacity of steam";
+  parameter Modelica.Units.SI.Density rho_air = 1.2 "Density of air";
+
+  parameter Boolean use_T_set=false "if true, a set temperature is used to calculate the necessary heat flow rate";
+
+  parameter Modelica.Units.SI.HeatFlowRate Q_flow_nominal = 45E3 "maximum heat output of heater at design point. Only used, if use_T_set = true" annotation (HideResult = (not use_T_set));
+
+  // constants
+  constant Modelica.Units.SI.SpecificEnthalpy r0 = 2500E3 "specific heat of vaporization at 0°C";
+
+  // Variables
+  Modelica.Units.SI.SpecificEnthalpy h_airIn "specific enthalpy of incoming air";
+  Modelica.Units.SI.SpecificEnthalpy h_airOut "specific enthalpy of outgoing air";
+
+  Modelica.Units.SI.MassFlowRate m_flow_dryairIn "mass flow rate of incoming dry air";
+  Modelica.Units.SI.MassFlowRate m_flow_dryairOut "mass flow rate of outgoing dry air";
+
+  Modelica.Units.SI.HeatFlowRate Q_flow "heat flow";
+
+  Modelica.Blocks.Interfaces.RealInput m_flow_airIn(
+    final quantity = "MassFlowRate",
+    final unit = "kg/s")
+    "mass flow rate of incoming air"
+    annotation (Placement(transformation(extent={{-140,50},{-100,90}}),
+        iconTransformation(extent={{-120,70},{-100,90}})));
+  Modelica.Blocks.Interfaces.RealInput T_airIn(
+    final quantity="ThermodynamicTemperature",
+    final unit="K",
+    displayUnit="degC")
+    "Temperature of incoming air"
+    annotation (Placement(transformation(extent={{-140,20},{-100,60}}),
+        iconTransformation(extent={{-120,40},{-100,60}})));
+  Modelica.Blocks.Interfaces.RealInput X_airIn(
+    final quantity = "MassFraction",
+    final unit = "kg/kg")
+    "absolute humidity of incoming air"
+    annotation (Placement(transformation(extent={{-140,-10},{-100,30}}),
+        iconTransformation(extent={{-120,10},{-100,30}})));
+  Modelica.Blocks.Interfaces.RealOutput m_flow_airOut(
+    final quantity = "MassFlowRate",
+    final unit = "kg/s") "mass flow rate of outgoing air"
+    annotation (Placement(transformation(extent={{100,70},{120,90}})));
+  Modelica.Blocks.Interfaces.RealOutput T_airOut(
+    final quantity="ThermodynamicTemperature",
+    final unit="K",
+    displayUnit="degC") "temperature of outgoing air"
+    annotation (Placement(transformation(extent={{100,40},{120,60}}),
+        iconTransformation(extent={{100,40},{120,60}})));
+  Modelica.Blocks.Interfaces.RealOutput X_airOut(
+    final quantity = "MassFraction",
+    final unit = "kg/kg") "absolute humidity of outgoing air"
+    annotation (Placement(transformation(extent={{100,10},{120,30}}),
+        iconTransformation(extent={{100,10},{120,30}})));
+
+  Modelica.Blocks.Interfaces.RealInput T_set if use_T_set annotation (Placement(
+        transformation(
+        extent={{-20,-20},{20,20}},
+        rotation=-90,
+        origin={0,110}), iconTransformation(
+        extent={{-10,-10},{10,10}},
+        rotation=-90,
+        origin={0,100})));
+
+  Modelica.Blocks.Interfaces.RealOutput dp "pressure difference"
+    annotation (Placement(transformation(extent={{100,-30},{120,-10}})));
+  replaceable model PartialPressureDrop =
+      Components.PressureDrop.BaseClasses.partialPressureDrop annotation(choicesAllMatching=true);
+
+      PartialPressureDrop partialPressureDrop(m_flow = m_flow_airIn,
+      rho = rho_air);
+
+  Modelica.Blocks.Interfaces.RealOutput Q "heat flow rate"
+    annotation (Placement(transformation(extent={{100,-70},{120,-50}})));
+  Modelica.Blocks.Interfaces.RealInput u(min=0, max=1)
+    if not use_T_set "input connector scaling heat flow rate [0..1]" annotation (Placement(transformation(
+        extent={{-20,-20},{20,20}},
+        rotation=-90,
+        origin={48,110}), iconTransformation(
+        extent={{-10,-10},{10,10}},
+        rotation=-90,
+        origin={0,100})));
+protected
+  parameter Real Q_in=0 "dummy heat flow rate, if use_T_set = false";
+  Modelica.Blocks.Interfaces.RealInput Q_in_internal "internal heat flow rate";
+  Modelica.Blocks.Interfaces.RealInput T_intern "internal temperature";
+  Modelica.Blocks.Math.Max max
+    annotation (Placement(transformation(extent={{-18,74},{-8,84}})));
+  Modelica.Blocks.Sources.Constant Q_nominal(k=Q_flow_nominal) if not use_T_set
+    annotation (Placement(transformation(extent={{12,40},{32,60}})));
+  Modelica.Blocks.Math.Product product1 if not use_T_set
+    annotation (Placement(transformation(extent={{52,22},{72,42}})));
+equation
+
+  // mass balances
+  m_flow_airIn - m_flow_airOut = 0;
+  m_flow_dryairIn - m_flow_dryairOut = 0;
+  m_flow_dryairIn * (1 + X_airIn) = m_flow_airIn;
+
+  // heat flows
+  Q_flow = -(m_flow_dryairIn * h_airIn - m_flow_dryairOut * h_airOut);
+  Q = Q_flow;
+
+  Q_flow = Q_in_internal;
+
+  // sepcific enthalpies
+  h_airIn = cp_air * (T_airIn - 273.15) + X_airIn * (cp_steam * (T_airIn - 273.15) + r0);
+  h_airOut = cp_air * (T_intern - 273.15) + X_airOut * (cp_steam * (T_intern - 273.15) + r0);
+
+  T_airOut = T_intern;
+
+  partialPressureDrop.dp = dp;
+
+  // Conditional connectors
+  connect(max.y,T_intern);
+  connect(product1.y, Q_in_internal);
+
+  // Connectors
+  connect(T_set, max.u1) annotation (Line(points={{0,110},{0,88},{-22,88},{-22,82},
+          {-19,82}}, color={0,0,127}));
+  connect(T_airIn, max.u2) annotation (Line(points={{-120,40},{-80,40},{-80,76},
+          {-19,76}}, color={0,0,127}));
+  connect(Q_nominal.y, product1.u1) annotation (Line(points={{33,50},{42,50},{42,
+          38},{50,38}}, color={0,0,127}));
+  connect(u, product1.u2) annotation (Line(points={{48,110},{48,82},{42,82},{42,
+          26},{50,26}}, color={0,0,127}));
+  annotation (Icon(graphics={
+        Rectangle(
+          extent={{-100,94},{100,-94}},
+          lineColor={0,0,0},
+          fillColor={175,175,175},
+          fillPattern=FillPattern.Solid,
+          lineThickness=0.5),
+        Line(
+          points={{-100,94},{100,-94}},
+          color={0,0,0},
+          thickness=0.5),
+        Text(
+          extent={{-14,66},{62,48}},
+          lineColor={0,0,0},
+          lineThickness=1,
+          fillColor={175,175,175},
+          fillPattern=FillPattern.Solid,
+          textString="%name")}), Documentation(info="<html><p>
+  This partial model provides a idealized heat exchanger. The model
+  considers the convective heat transfer from the heat transfer surface
+  in the air stream. Moreover the heat capacity of the heating surface
+  and the housing of the heat exchanger is considered.
+</p>
+</html>", revisions="<html>
+<ul>
+  <li>April, 2019, by Martin Kremer:<br/>
+    First implementation.
+  </li>
+  <li>August, 2019, by Martin Kremer:<br/>
+    Added possibility to use set temperature.
+  </li>
+  <li>December, 2019, by Martin Kremer:<br/>
+    Removed internal PID. Output temperature is now directly set to set
+    temperature.
+  </li>
+</ul>
+</html>"));
+end PartialHeater;