Block / RPC explorer

ngui/attestationlist.nim

@@ -0,0 +1,65 @@
+import
+  std/[tables],
+  NimQml,
+  ../beacon_chain/spec/[helpers, eth2_apis/beacon_rpc_client],
+  ../beacon_chain/ssz/merkleization,
+  ./objecttablemodel, ./utils
+
+type
+  AttestationInfo* = object
+    slot*: int
+    index*: int
+    beacon_block_root*: string
+    source_epoch*: int
+    source_root*: string
+    target_epoch*: int
+    target_root*: string
+    aggregation_bits*: string
+
+proc toAttestationInfo*(v: Attestation): AttestationInfo =
+  AttestationInfo(
+    slot: v.data.slot.int,
+    index: v.data.index.int,
+    beacon_block_root: toBlockLink(v.data.beacon_block_root),
+    source_epoch: v.data.source.epoch.int,
+    source_root: toBlockLink(v.data.source.root),
+    target_epoch: v.data.target.epoch.int,
+    target_root: toBlockLink(v.data.target.root),
+    aggregation_bits: $v.aggregation_bits,
+  )
+
+QtObject:
+  type AttestationList* = ref object of QAbstractTableModel
+    # TODO this could be a generic ObjectTableModel, except generics + method don't work..
+    data: ObjectTableModelImpl[AttestationInfo]
+
+  proc setup(self: AttestationList) = self.QAbstractTableModel.setup
+
+  proc delete(self: AttestationList) =
+    self.QAbstractTableModel.delete
+
+  proc newAttestationList*(data: seq[AttestationInfo]): AttestationList =
+    new(result, delete)
+    result.data = ObjectTableModelImpl[AttestationInfo](items: data)
+    result.setup
+
+  method rowCount(self: AttestationList, index: QModelIndex = nil): int =
+    self.data.rowCount(index)
+
+  method columnCount(self: AttestationList, index: QModelIndex = nil): int =
+    self.data.columnCount(index)
+
+  method headerData*(self: AttestationList, section: int, orientation: QtOrientation, role: int): QVariant =
+    self.data.headerData(section, orientation, role)
+
+  method data(self: AttestationList, index: QModelIndex, role: int): QVariant =
+    self.data.data(index, role)
+
+  method roleNames(self: AttestationList): Table[int, string] =
+    self.data.roleNames()
+
+  proc setNewData*(self: AttestationList, v: seq[AttestationInfo]) =
+    self.data.setNewData(self, v)
+
+  proc sort*(self: AttestationList, section: int) {.slot.} =
+    self.data.sort(self, section)

ngui/blockmodel.nim

@@ -0,0 +1,84 @@
+import NimQml
+
+import
+  std/[sequtils, json, times],
+  NimQml,
+  ../beacon_chain/eth2_json_rpc_serialization,
+  ../beacon_chain/spec/[datatypes, crypto],
+  ./attestationlist, ./depositlist, ./utils
+
+QtObject:
+  type
+    BlockModel* = ref object of QObject
+      blck: SignedBeaconBlock
+      attestationsx: AttestationList
+      depositsx: DepositList
+      genesis_time*: uint64
+
+  proc delete*(self: BlockModel) =
+    self.QObject.delete
+
+  proc setup*(self: BlockModel) =
+    self.QObject.setup
+
+  proc newBlockModel*(blck: SignedBeaconBlock, genesis_time: uint64): BlockModel =
+    let res = BlockModel(
+      blck: blck,
+      attestationsx: newAttestationList(blck.message.body.attestations.mapIt(it.toAttestationInfo())),
+      depositsx: newDepositList(blck.message.body.deposits.mapIt(it.toDepositInfo())),
+      genesis_time: genesis_time,
+    )
+    res.setup()
+    res
+
+  proc `blck=`*(self: BlockModel, blck: SignedBeaconBlock) =
+      self.blck = blck
+      self.attestationsx.setNewData(blck.message.body.attestations.mapIt(it.toAttestationInfo()))
+      self.depositsx.setNewData(blck.message.body.deposits.mapIt(it.toDepositInfo()))
+
+  proc slot*(self: BlockModel): int {.slot.} = self.blck.message.slot.int
+  QtProperty[int] slot: read = slot
+
+  proc time*(self: BlockModel): string {.slot.} =
+    let t = self.genesis_time + self.blck.message.slot * SECONDS_PER_SLOT
+    $fromUnix(t.int64).utc
+  QtProperty[string] time: read = time
+
+  proc root*(self: BlockModel): string {.slot.} = toDisplayHex(self.blck.root.data)
+  QtProperty[string] root: read = root
+
+  proc proposer_index*(self: BlockModel): int {.slot.} = self.blck.message.proposer_index.int
+  QtProperty[int] proposer_index: read = proposer_index
+
+  proc parent_root*(self: BlockModel): string {.slot.} = toBlockLink(self.blck.message.parent_root)
+  QtProperty[string] parent_root: read = parent_root
+
+  proc state_root*(self: BlockModel): string {.slot.} = toDisplayHex(self.blck.message.state_root.data)
+  QtProperty[string] state_root: read = state_root
+
+  proc randao_reveal*(self: BlockModel): string {.slot.} = toDisplayHex(self.blck.message.body.randao_reveal)
+  QtProperty[string] randao_reveal: read = randao_reveal
+
+  proc eth1_data*(self: BlockModel): string {.slot.} = (%*self.blck.message.body.eth1_data).pretty()
+  QtProperty[string] eth1_data: read = eth1_data
+
+  proc graffiti*(self: BlockModel): string {.slot.} = $self.blck.message.body.graffiti
+  QtProperty[string] graffiti: read = graffiti
+
+  proc proposer_slashings*(self: BlockModel): string {.slot.} = (%*self.blck.message.body.proposer_slashings.asSeq()).pretty()
+  QtProperty[string] proposer_slashings: read = proposer_slashings
+
+  proc attester_slashings*(self: BlockModel): string {.slot.} = (%*self.blck.message.body.attester_slashings.asSeq()).pretty()
+  QtProperty[string] attester_slashings: read = attester_slashings
+
+  proc attestations*(self: BlockModel): QVariant {.slot.} = newQVariant(self.attestationsx)
+  QtProperty[QVariant] attestations: read = attestations
+
+  proc deposits*(self: BlockModel): QVariant {.slot.} = newQVariant(self.depositsx)
+  QtProperty[QVariant] deposits: read = deposits
+
+  proc voluntary_exits*(self: BlockModel): string {.slot.} = (%*self.blck.message.body.voluntary_exits.asSeq()).pretty()
+  QtProperty[string] voluntary_exits: read = voluntary_exits
+
+  proc signature*(self: BlockModel): string {.slot.} = toDisplayHex(self.blck.signature)
+  QtProperty[string] signature: read = signature

ngui/depositlist.nim

@@ -0,0 +1,56 @@
+import
+  std/[tables],
+  NimQml,
+  ../beacon_chain/spec/[eth2_apis/beacon_rpc_client],
+  ./objecttablemodel, ./utils
+
+type
+  DepositInfo* = object
+    pubkey*: string
+    withdrawal_credentials*: string
+    amount*: uint64
+    signature*: string
+
+proc toDepositInfo*(v: Deposit): DepositInfo =
+  DepositInfo(
+    pubkey: toDisplayHex(v.data.pubkey.toRaw()),
+    withdrawal_credentials: toDisplayHex(v.data.withdrawal_credentials),
+    amount: v.data.amount,
+    signature: toDisplayHex(v.data.signature),
+  )
+
+QtObject:
+  type DepositList* = ref object of QAbstractTableModel
+    # TODO this could be a generic ObjectTableModel, except generics + method don't work..
+    data: ObjectTableModelImpl[DepositInfo]
+
+  proc setup(self: DepositList) = self.QAbstractTableModel.setup
+
+  proc delete(self: DepositList) =
+    self.QAbstractTableModel.delete
+
+  proc newDepositList*(data: seq[DepositInfo]): DepositList =
+    new(result, delete)
+    result.data = ObjectTableModelImpl[DepositInfo](items: data)
+    result.setup
+
+  method rowCount(self: DepositList, index: QModelIndex = nil): int =
+    self.data.rowCount(index)
+
+  method columnCount(self: DepositList, index: QModelIndex = nil): int =
+    self.data.columnCount(index)
+
+  method headerData*(self: DepositList, section: int, orientation: QtOrientation, role: int): QVariant =
+    self.data.headerData(section, orientation, role)
+
+  method data(self: DepositList, index: QModelIndex, role: int): QVariant =
+    self.data.data(index, role)
+
+  method roleNames(self: DepositList): Table[int, string] =
+    self.data.roleNames()
+
+  proc setNewData*(self: DepositList,  v: seq[DepositInfo]) =
+    self.data.setNewData(self, v)
+
+  proc sort*(self: DepositList, section: int) {.slot.} =
+    self.data.sort(self, section)

ngui/epochmodel.nim

@@ -0,0 +1,52 @@
+import NimQml
+
+import
+  ./slotlist,
+  ../beacon_chain/[spec/eth2_apis/beacon_rpc_client]
+
+QtObject:
+  type
+    EpochModel* = ref object of QObject
+      client: RpcHttpClient
+      epoch: int
+      slotList: SlotList
+
+  proc delete*(self: EpochModel) =
+    self.QObject.delete
+
+  proc setup*(self: EpochModel) =
+    self.QObject.setup
+
+  proc newEpochModel*(client: RpcHttpClient, epoch: int): EpochModel =
+    let data = client.loadSlots(epoch.Epoch)
+    let res = EpochModel(client: client, epoch: epoch, slotList: newSlotList(data))
+    res.setup()
+    res
+
+  proc epoch*(self: EpochModel): int {.slot.} = self.epoch
+  proc epochChanged*(self: EpochModel, v: int) {.signal.}
+  QtProperty[int] epoch:
+    read = epoch
+    notify = epochChanged
+
+  proc getSlotList*(self: EpochModel): QVariant {.slot.} = newQVariant(self.slotList)
+  QtProperty[QVariant] slotList: read = getSlotList
+
+  proc setNewData*(self: EpochModel, epoch: int, data: seq[SlotInfo]) =
+    self.epoch = epoch
+    self.epochChanged(epoch)
+
+    self.slotList.setNewData(data)
+
+  proc reload(self: EpochModel) {.slot.} =
+    self.slotList.setNewData(self.client.loadSlots(self.epoch.Epoch))
+
+  proc next(self: EpochModel) {.slot.} =
+    self.epoch = self.epoch + 1
+    self.epochChanged(self.epoch)
+    self.reload() # TODO listen to epochchanged
+
+  proc prev(self: EpochModel) {.slot.} =
+    self.epoch = self.epoch - 1
+    self.epochChanged(self.epoch)
+    self.reload() # TODO listen to epochchanged

ngui/footermodel.nim

@@ -0,0 +1,42 @@
+import NimQml
+
+QtObject:
+  type
+    FooterModel* = ref object of QObject
+      finalized: string
+      head: string
+      syncing: string
+
+  proc delete*(self: FooterModel) =
+    self.QObject.delete
+
+  proc setup*(self: FooterModel) =
+    self.QObject.setup
+
+  proc newFooterModel*(): FooterModel =
+    let res = FooterModel()
+    res.setup()
+    res
+
+  proc finalized*(self: FooterModel): string {.slot.} = self.finalized
+  proc finalizedChanged*(self: FooterModel, v: string) {.signal.}
+  proc `finalized=`*(self: FooterModel, v: string) =
+    self.finalized = v
+    self.finalizedChanged(v)
+  QtProperty[string] finalized:
+    read = finalized
+    notify = finalizedChanged
+
+  proc head*(self: FooterModel): string {.slot.} = self.head
+  proc headChanged*(self: FooterModel, v: string) {.signal.}
+  proc `head=`*(self: FooterModel, v: string) =
+    self.head = v
+    self.headChanged(v)
+  QtProperty[string] head: read = head; notify = headChanged
+
+  proc syncing*(self: FooterModel): string {.slot.} = self.syncing
+  proc syncingChanged*(self: FooterModel, v: string) {.signal.}
+  proc `syncing=`*(self: FooterModel, v: string) =
+    self.syncing = v
+    self.syncingChanged(v)
+  QtProperty[string] syncing: read = syncing; notify = syncingChanged