Added full CMake build support and enabled CI

.github/workflows/linux.yml

@@ -0,0 +1,61 @@
+name: Linux CI
+
+on:
+  push:
+    branches:
+      - 'master'
+  pull_request:
+    branches:
+      - '*'
+
+jobs:
+  build:
+    name: Build, test and install project
+    runs-on: ubuntu-latest
+    strategy:
+      fail-fast: false
+      matrix:
+        compiler: ['clang', 'gcc']
+        include:
+          - compiler: 'clang'
+            cc: 'clang'
+            cxx: 'clang++'
+          - compiler: 'gcc'
+            cc: 'gcc'
+            cxx: 'g++'
+    steps:
+    - name: Fetching sources
+      uses: actions/checkout@v3
+    - name: Updating apt package metadata
+      run: |
+        sudo apt-get update
+    - name: Installing compiler
+      run: |
+        sudo apt-get -y install ${{ matrix.compiler }}
+    - name: Installing build system
+      run: |
+        sudo apt-get -y install cmake make
+    - name: Building project with CMake
+      run: |
+        cmake -S . -B build \
+            -DCMAKE_C_COMPILER=${{ matrix.cc }} \
+            -DCMAKE_CXX_COMPILER=${{ matrix.cxx }} \
+            -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON \
+            -DCMAKE_INSTALL_PREFIX:PATH=/usr \
+            -DCMAKE_BUILD_TYPE=RelWithDebInfo \
+            -DBUILD_SHARED_LIBS:BOOL=ON \
+            -DBUILD_EXAMPLES:BOOL=ON \
+            -DBUILD_TESTS:BOOL=ON
+        cmake --build build
+      env:
+        CFLAGS: -O2 -fexceptions -pipe -Wall -Wextra -Wp,-D_FORTIFY_SOURCE=2 -Wp,-D_GLIBCXX_ASSERTIONS -fPIC -fstack-protector-strong -fasynchronous-unwind-tables -fcf-protection
+        CXXFLAGS: -O2 -fexceptions -pipe -Wall -Wextra -Wp,-D_FORTIFY_SOURCE=2 -Wp,-D_GLIBCXX_ASSERTIONS -fPIC -fstack-protector-strong -fasynchronous-unwind-tables -fcf-protection
+        LDFLAGS: -Wl,-z,relro -Wl,--as-needed -Wl,-z,now
+    - name: Running unit tests with CTest
+      run: |
+        pushd build
+        ctest --output-on-failure
+        popd
+    - name: Installing project with CMake
+      run: |
+        sudo cmake --install build

CMakeLists.txt

@@ -0,0 +1,235 @@
+# ==============================
+# === Project initialization ===
+# ==============================
+
+cmake_minimum_required(VERSION 3.12)
+
+project(QR-Code-generator
+    VERSION 1.8.0
+    DESCRIPTION "High-quality QR Code generator library in Java, TypeScript/JavaScript, Python, C++, C, Rust"
+    HOMEPAGE_URL "https://www.nayuki.io/page/qr-code-generator-library"
+    LANGUAGES C CXX
+)
+
+set(CMAKE_CXX_STANDARD 11)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+# =======================
+# === Project options ===
+# =======================
+
+option(BUILD_EXAMPLES "Build examples and demos" OFF)
+option(BUILD_TESTS "Build and run unit tests" OFF)
+
+# =======================
+# === Paths detection ===
+# =======================
+
+include(GNUInstallDirs)
+
+# ============================
+# === CMake config helpers ===
+# ============================
+
+include(CMakePackageConfigHelpers)
+
+# ========================
+# === C library target ===
+# ========================
+
+set(QRCODEGEN_NAME "qrcodegen")
+
+set(QRCODEGEN_SOURCES
+    c/qrcodegen.c
+)
+
+set(QRCODEGEN_HEADERS
+    c/qrcodegen.h
+)
+
+add_library(${QRCODEGEN_NAME}
+    ${QRCODEGEN_SOURCES}
+    ${QRCODEGEN_HEADERS}
+)
+
+target_include_directories(${QRCODEGEN_NAME} PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/c>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/${QRCODEGEN_NAME}>
+)
+
+set_property(TARGET ${QRCODEGEN_NAME} PROPERTY PUBLIC_HEADER ${QRCODEGEN_HEADERS})
+set_property(TARGET ${QRCODEGEN_NAME} PROPERTY VERSION ${CMAKE_PROJECT_VERSION})
+set_property(TARGET ${QRCODEGEN_NAME} PROPERTY SOVERSION 1)
+
+install(TARGETS ${QRCODEGEN_NAME}
+    EXPORT ${QRCODEGEN_NAME}-targets
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    BUNDLE DESTINATION ${CMAKE_INSTALL_BINDIR}
+    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${QRCODEGEN_NAME}
+)
+
+configure_package_config_file(cmake/${QRCODEGEN_NAME}-config.cmake.in
+    ${QRCODEGEN_NAME}-config.cmake
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGEN_NAME}
+)
+write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGEN_NAME}-config-version.cmake
+    COMPATIBILITY ExactVersion
+)
+
+install(FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGEN_NAME}-config.cmake
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGEN_NAME}-config-version.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGEN_NAME}
+)
+
+install(EXPORT ${QRCODEGEN_NAME}-targets
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGEN_NAME}
+    NAMESPACE ${QRCODEGEN_NAME}::
+)
+
+configure_file(cmake/${QRCODEGEN_NAME}.pc.in
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGEN_NAME}.pc
+    @ONLY
+)
+
+install(FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGEN_NAME}.pc
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
+)
+
+# =========================
+# === C examples target ===
+# =========================
+
+if(BUILD_EXAMPLES)
+    set(QRCODEGENDEMO_SOURCES
+        c/qrcodegen-demo.c
+    )
+
+    add_executable(${QRCODEGEN_NAME}-demo
+        ${QRCODEGENDEMO_SOURCES}
+    )
+
+    target_link_libraries(${QRCODEGEN_NAME}-demo PRIVATE
+        ${QRCODEGEN_NAME}
+    )
+endif()
+
+# ======================
+# === C tests target ===
+# ======================
+
+if (BUILD_TESTS)
+    set(QRCODEGENTEST_SOURCES
+        c/qrcodegen-test.c
+    )
+
+    add_library(${QRCODEGEN_NAME}-testable OBJECT
+        ${QRCODEGEN_SOURCES}
+        ${QRCODEGEN_HEADERS}
+    )
+
+    target_compile_options(${QRCODEGEN_NAME}-testable PUBLIC
+        -DQRCODEGEN_TEST
+    )
+
+    add_executable(${QRCODEGEN_NAME}-test
+        ${QRCODEGENTEST_SOURCES}
+    )
+
+    target_link_libraries(${QRCODEGEN_NAME}-test PRIVATE
+        ${QRCODEGEN_NAME}-testable
+    )
+
+    add_test(NAME ${QRCODEGEN_NAME}-test COMMAND ${QRCODEGEN_NAME}-test)
+endif()
+
+# ==========================
+# === C++ library target ===
+# ==========================
+
+set(QRCODEGENCPP_NAME "qrcodegencpp")
+
+set(QRCODEGENCPP_SOURCES
+    cpp/qrcodegen.cpp
+)
+
+set(QRCODEGENCPP_HEADERS
+    cpp/qrcodegen.hpp
+)
+
+add_library(${QRCODEGENCPP_NAME}
+    ${QRCODEGENCPP_SOURCES}
+    ${QRCODEGENCPP_HEADERS}
+)
+
+target_include_directories(${QRCODEGENCPP_NAME} PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/cpp>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/${QRCODEGENCPP_NAME}>
+)
+
+set_property(TARGET ${QRCODEGENCPP_NAME} PROPERTY PUBLIC_HEADER ${QRCODEGENCPP_HEADERS})
+set_property(TARGET ${QRCODEGENCPP_NAME} PROPERTY VERSION ${CMAKE_PROJECT_VERSION})
+set_property(TARGET ${QRCODEGENCPP_NAME} PROPERTY SOVERSION 1)
+
+install(TARGETS ${QRCODEGENCPP_NAME}
+    EXPORT ${QRCODEGENCPP_NAME}-targets
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    BUNDLE DESTINATION ${CMAKE_INSTALL_BINDIR}
+    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${QRCODEGENCPP_NAME}
+)
+
+configure_package_config_file(cmake/${QRCODEGENCPP_NAME}-config.cmake.in
+    ${QRCODEGENCPP_NAME}-config.cmake
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGENCPP_NAME}
+)
+write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGENCPP_NAME}-config-version.cmake
+    COMPATIBILITY ExactVersion
+)
+
+install(FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGENCPP_NAME}-config.cmake
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGENCPP_NAME}-config-version.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGENCPP_NAME}
+)
+
+install(EXPORT ${QRCODEGENCPP_NAME}-targets
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${QRCODEGENCPP_NAME}
+    NAMESPACE ${QRCODEGENCPP_NAME}::
+)
+
+configure_file(cmake/${QRCODEGENCPP_NAME}.pc.in
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGENCPP_NAME}.pc
+    @ONLY
+)
+
+install(FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/${QRCODEGENCPP_NAME}.pc
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
+)
+
+# ===========================
+# === C++ examples target ===
+# ===========================
+
+if(BUILD_EXAMPLES)
+    set(QRCODEGENCPPDEMO_SOURCES
+        cpp/QrCodeGeneratorDemo.cpp
+    )
+
+    add_executable(${QRCODEGENCPP_NAME}-demo
+        ${QRCODEGENCPPDEMO_SOURCES}
+    )
+
+    target_link_libraries(${QRCODEGENCPP_NAME}-demo PRIVATE
+        ${QRCODEGENCPP_NAME}
+    )
+endif()
+
+# ====================
+# === Tests export ===
+# ====================
+
+if (BUILD_TESTS)
+    enable_testing()
+endif()

cmake/qrcodegen-config.cmake.in

@@ -0,0 +1,4 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/@QRCODEGEN_NAME@-targets.cmake")
+check_required_components(@QRCODEGEN_NAME@)