Half a year later, I switched to an easier distro (Gentoo), so I can finally compile xmonad. I still have no idea if there is a way to do it in a config file but here's a patch for xmonad to make it stop ignoring numlock state, if anyone's interested:

diff --git a/src/XMonad/Operations.hs b/src/XMonad/Operations.hs
index 4b46571..ef3978f 100644
--- a/src/XMonad/Operations.hs
+++ b/src/XMonad/Operations.hs
@@ -423,17 +423,15 @@ isClient :: Window -> X Bool
 isClient w = withWindowSet $ return . W.member w
 
 -- | Combinations of extra modifier masks we need to grab keys\/buttons for.
--- (numlock and capslock)
+-- (capslock)
 extraModifiers :: X [KeyMask]
 extraModifiers = do
-    nlm <- gets numberlockMask
-    return [0, nlm, lockMask, nlm .|. lockMask ]
+    return [0, lockMask]
 
--- | Strip numlock\/capslock from a mask
+-- | Strip capslock from a mask
 cleanMask :: KeyMask -> X KeyMask
 cleanMask km = do
-    nlm <- gets numberlockMask
-    return (complement (nlm .|. lockMask) .&. km)
+    return (complement lockMask .&. km)
 
 -- | Get the 'Pixel' value for a named color
 initColor :: Display -> String -> IO (Maybe Pixel)

I'm not sure if removing stuff from extraModifiers is needed, but it seems consistent to do it and it works. Unfortunatelly I have to duplicate most of my key bindings in my config file now, so it gets messy, but at least it's possible to do.

There's discussion of a related issue in xmonad-contrib - xmonad/xmonad-contrib#290 - since XMonad.Prompt has its own cleanMask

Ignoring numlock state is probably intended. As in you want your key bindings perform the same regardless of numlock state. On many keyboards the key is missing and the state is not displayed anywhere. Same for capslock.

Ignoring numlock state is probably intended. As in you want your key bindings perform the same regardless of numlock state. On many keyboards the key is missing and the state is not displayed anywhere. Same for capslock.

Is there a way to override this? I WANT my keybindings to be different depending on capslock and numlock state and be able to write key-bindings like

  , ((modm,              xKey), do something)
  , ((modm .|. lockMask, xKey), do somethingElse) -- do this when capslock in on
  , ((modm .|. mod2Mask, xKey), do somethingDifferent) -- do this when numlock is on

While xmonad processes an event, the event is stored inside XConf. From that, the uncleaned modifier mask can be extracted.

The following code is a possible implementation of the requested behavior.

import XMonad
import Data.Bits ((.&.))

currentModifiers :: X (Maybe KeyMask)
currentModifiers = do
  event <- asks currentEvent
  pure $ case event of
    Just (KeyEvent { ev_state = modifiers }) -> Just modifiers
    _ -> Nothing

onModifierState :: KeyMask -> X () -> X () -> X ()
onModifierState wanted ifActive ifInactive = do
  modifiers <- currentModifiers
  case modifiers of
    Just mods
      | mods .&. wanted == wanted -> ifActive
      | otherwise -> ifInactive
    _ -> pure ()

onNumLockState :: X () -> X () -> X ()
onNumLockState ifActive ifInactive = do
  numLock <- gets numberlockMask
  onModifierState numLock ifActive ifInactive

onCapsLockState :: X () -> X () -> X ()
onCapsLockState = onModifierState lockMask

Using this, a keybinding might look like this:

  , ((0, xF86XK_AudioMute), onNumLockState (xmessage "num lock is on") (xmessage "num lock is off"))

Note that this key binding will not trigger if any modifer which is not cleaned by XMonad is active. (The set of cleaned modifiers is num lock and caps lock.)

if someone still needs this, I could create a pull request to add this as a module to xmonad-contrib.

I think there's one problem with @ibbem's solution: xmonad still configures passive grabs for the key with all extraModifiers combinations, which means those numpad keys are grabbed even while numlock is on and their keypresses are delivered to xmonad rather than the current window.

I suspect that we might need to add a stripMask :: X KeyMask (or ignoreMask or something) defaulting to (lockMask .|.) <$> gets numberlockMask to XConfig and rewrite extraModifiers/cleanMask to use it. Then people can override this to not strip numlock mask and not grab keys with numlock mask set (and duplicate keybindings where ignoring numlock is desired).

I suspect that we might need to add a stripMask :: X KeyMask …

Implemented in #374, and I've also opened xmonad/xmonad-contrib#686 to address Michael's xmonad/xmonad-contrib#290.