-
Notifications
You must be signed in to change notification settings - Fork 3
/
flake.nix
87 lines (79 loc) · 2.03 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
{
description = "Trying to build the perfect system";
inputs = {
# I use unstable by default
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
impermanence.url = "github:nix-community/impermanence";
home-manager = {
url = "github:nix-community/home-manager";
inputs.nixpkgs.follows = "nixpkgs";
};
emacs-overlay = {
url = "github:nix-community/emacs-overlay";
inputs.nixpkgs.follows = "nixpkgs";
};
chemacs = {
url = "github:plexus/chemacs2";
flake = false;
};
# Never going to be on melpa.
copilot-el = {
url = "github:zerolfx/copilot.el";
flake = false;
};
# Eventually will be on elpa https://github.com/nemethf/eglot-x/issues/1
eglot-x = {
url = "github:nemethf/eglot-x";
flake = false;
};
# Soothing pastel theme for Nix
catppuccin.url = "github:catppuccin/nix";
};
outputs =
{
catppuccin,
impermanence,
nixpkgs,
...
}@inputs:
let
inherit (nixpkgs) lib;
inherit (lib) nixosSystem;
inherit (lib.attrsets) genAttrs;
system = "x86_64-linux";
hosts = [
"blazar"
"ton-618"
];
toConfig =
hostName:
nixosSystem {
inherit system;
modules = [
(./hosts + "/${hostName}.nix")
catppuccin.nixosModules.catppuccin
impermanence.nixosModules.impermanence
inputs.home-manager.nixosModules.home-manager
{
home-manager = {
useGlobalPkgs = true;
useUserPackages = true;
extraSpecialArgs = {
inherit inputs;
};
};
}
{
networking.hostName = hostName;
nixpkgs.overlays = [ inputs.emacs-overlay.overlays.default ];
}
];
specialArgs = {
inherit inputs;
};
};
in
{
nixosConfigurations = genAttrs hosts toConfig;
};
}