PMW for dc motor, servo-mechanisms in zetptoforth.

[photoplane]

Hi Travis

I contacted you on facebook about this.
I have already programmed in pmw but with EPS32Forth.
I send you the code (from Atle Bergstrom) that I adapted for an articulated arm.
I would like to know if it is possible to translate this code into zeptoforth.
I hope to get along to go further!

( testservo )
FORTH DEFINITIONS also LEDC
( vocabulary )
DECIMAL
10 constant PWMR
2 constant chRIGHT
: init-pwm
PWMR chRIGHT
ledcAttachPin
chRIGHT 40000 10 ledcSetup ;
: servo ( speed -- ) chRIGHT swap ledcWrite ;
init-pwm

( examples )
: >armHight 25 60 DO I servo 100 ms -1 +LOOP ;
: >armDown 60 25 DO I servo 100 ms 1 +LOOP ;
: test4 >armHight >armDown ;

Best regards

Daniel

[robzed]

_There was a reply on Facebook by Travis. For my own purposes, here is record of that ;-)

There is a wiki page on operating the PWM at https://github.com/tabemann/zeptoforth/wiki/Pulse-Width-Modulation-and-Hardware-Timers-in-zeptoforth-on-the-Raspberry-Pi-Pico in case you have not read it, along with API documentation at https://github.com/tabemann/zeptoforth/blob/master/docs/words/pwm.md.

An example of the PWM in action can be found at https://github.com/tabemann/zeptoforth/blob/master/test/rp2040/pwm_counter_test.fs - here we have two pins for different PWM "slices" linked by a wire, one on which we are generating an output signal and the other on which we are inputting the signal outputted by the other pin, which wraps after 65536 rising edges and generates an interrupt, which we use to increment a counter.

[tabemann]

@photoplane I cannot from the code you posted tell exactly what you are trying to do, but here is some code (note I have not tested it) which may do something like what you want to do:

pwm import

\ My PWM output pin
\ Note that this corresponds to my-servo-pwm-slice below; if you change this you will have to change that.
4 constant my-servo-pin

\ My PWM slice
2 constant my-servo-pwm-slice

\ Initialize the PWM for the servo
: init-servo ( -- )
  \ We want the PWM slice to be disabled at this point
  my-servo-pwm-slice bit disable-pwm

  \ We configure our GPIO pin to be for PWM; note that each GPIO pin is linked to a particular PWM slice and channel
  my-servo-pin pwm-pin

  \ Here we set our PWM slice to be free-running, rather than gated or a counter
  my-servo-pwm-slice free-running-pwm

  \ Here we set phase correction off
  false my-servo-pwm-slice pwm-phase-correct!
  
  \ As the system clock is 125 MHz, this gives us a clock of 125 * 40 kHz
  0 25 my-servo-pwm-slice pwm-clock-div!

  \ Change this to the top counter value you want for PWM
  \ Note that you will have to change the values you set for pwm-counter-compare-a! accordingly
  125 my-servo-pwm-slice pwm-top!

  \ This is our initial compare value for slice channel A, as GPIO pin 4 is on slice channel A.
  \ This should start out the same as pwm-top!
  125 my-servo-pwm-slice pwm-counter-compare-a!

  \ This initializes our counter to 0 
  0 my-servo-pwm-slice pwm-counter!
;

\ Start the servo
: start-servo { compare -- }
  \ You want the PWM slice to be disabled at this point
  my-servo-pwm-slice bit disable-pwm

  \ Change this to pwm-counter-compare-b! if you want to use a slice channel B
  compare my-servo-pwm-slice pwm-counter-compare-a!

  \ Reset our counter to 0
  0 my-servo-pwm-slice pwm-counter!

  \ Now we enable the PWM slice
  my-servo-pwm-slice bit enable-pwm
;

\ Set the servo; make sure we have initialized and started the servo first
: servo { compare -- }
  \ Change this to pwm-counter-compare-b! if you want to use a slice channel B
  compare my-servo-pwm-slice pwm-counter-compare-a!
;

\ Here are your examples
\ Note that you will likely have to change the values of 25 and 60 and the rate at which you change them
\ dependent on the clock divider and the value passed into pwm-top!
: >armHight 25 60 DO I servo 100 ms -1 +LOOP ;
: >armDown 60 25 DO I servo 100 ms 1 +LOOP ;
: test4 >armHight >armDown ;

[photoplane]

Thank you.