Nix(OS) derivation for servo

[campbellcole]

I have written a servo derivation that uses prebuilt binaries to avoid recompiling the whole browser in release mode and figured I'd share it here in case any other Nix users want to try running servo.

Here is the derivation:

{ lib
, stdenv
, fetchurl
, autoPatchelfHook
, zlib
, glib
, harfbuzz
, fontconfig
, freetype
, dbus
, libunwind
, gst_all_1
, xorg
, libxkbcommon
, vulkan-loader
}:

stdenv.mkDerivation rec {
  pname = "servo";
  version = "2024-01-05";

  src = fetchurl {
    url = "https://github.com/servo/servo-nightly-builds/releases/download/${version}/servo-latest.tar.gz";
    hash = "sha256-IlmoYIFk0QO0CieJ49m8PnEou1Q3w+Tk9rypI0ya2WQ=";
  };

  nativeBuildInputs = [
    autoPatchelfHook
  ];

  buildInputs = [
    stdenv.cc.cc.lib
    zlib
    glib
    harfbuzz
    fontconfig
    freetype
    dbus
    libunwind
  ] ++ (with gst_all_1; [
    gstreamer
    gst-plugins-base
    gst-plugins-bad
  ]) ++ (with xorg; [
    libxcb
    libX11
  ]);

  runtimeDependencies = [
    libxkbcommon vulkan-loader
  ] ++ (with xorg; [
    libXcursor libXrandr libXi
  ]);

  sourceRoot = "servo";

  installPhase = ''
    runHook preInstall
    install -m755 -D servo $out/bin/._servo
    echo "WINIT_UNIX_BACKEND=x11 $out/bin/._servo" > $out/bin/servo
    chmod +x $out/bin/servo
    cp -r ./resources $out/bin/
    runHook postInstall
  '';

  meta = with lib; {
    homepage = "https://servo.org";
    description = "The embeddable, independent, memory-safe, modular, parallel web rendering engine";
    platforms = platforms.linux;
  };
}

This derivation creates a wrapper script that forces the use of X11 instead of wayland. I wasn't able to get rendering to work using wayland and it seems this is a common issue (rust-windowing/winit#305).