/
CMakeLists.txt
272 lines (211 loc) · 10.5 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
cmake_minimum_required(VERSION 3.21)
project(saucer LANGUAGES CXX VERSION 2.3.0)
# --------------------------------------------------------------------------------------------------------
# Check requirements
# --------------------------------------------------------------------------------------------------------
if (MSVC AND MSVC_TOOLSET_VERSION LESS 143)
message(WARNING "[saucer] MSVC Toolsets below 14.3 are not supported")
endif()
# --------------------------------------------------------------------------------------------------------
# Library switches
# --------------------------------------------------------------------------------------------------------
option(saucer_modules "Enable smartview modules" ON)
option(saucer_package_all "Add all required dependencies to install target" OFF)
option(saucer_prefer_remote "Prefer remote packages over local packages" ON)
option(saucer_tests "Build tests" OFF)
option(saucer_examples "Build examples" OFF)
# --------------------------------------------------------------------------------------------------------
# Library options
# --------------------------------------------------------------------------------------------------------
set(saucer_webview2_version "1.0.1901.177" CACHE STRING "The WebView2 version to use (Ignored when using offline packages)")
set(saucer_backend "Default" CACHE STRING "The backend to use, will use the most appropiate one for the current platform by default")
# --------------------------------------------------------------------------------------------------------
# Set "saucer_prefer_remote" and "CPM_USE_LOCAL_PACKAGES" to equal values
# --------------------------------------------------------------------------------------------------------
if (saucer_prefer_remote)
message(STATUS "[saucer] Avoiding local packages as 'saucer_prefer_remote' is ON")
endif()
set(CPM_DOWNLOAD_ALL ${saucer_prefer_remote})
# --------------------------------------------------------------------------------------------------------
# Ensure valid library options
# --------------------------------------------------------------------------------------------------------
set(saucer_valid_backends Qt5 Qt6 WebView2 Default)
set_property(CACHE saucer_backend PROPERTY STRINGS ${saucer_valid_backends})
if (NOT saucer_backend IN_LIST saucer_valid_backends)
message(FATAL_ERROR "Bad Backend, expected one of ${saucer_valid_backends}")
endif()
# --------------------------------------------------------------------------------------------------------
# Determine appropiate default backend
# --------------------------------------------------------------------------------------------------------
if (saucer_backend STREQUAL "Default")
if (WIN32)
set(saucer_backend WebView2)
else()
set(saucer_backend Qt6)
endif()
message(STATUS "[saucer] Backend is 'Defaut', using ${saucer_backend}")
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Library
# --------------------------------------------------------------------------------------------------------
add_library(${PROJECT_NAME} STATIC)
add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS saucer)
target_compile_features(${PROJECT_NAME} PRIVATE cxx_std_20)
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_STANDARD 20 CXX_EXTENSIONS OFF CXX_STANDARD_REQUIRED ON)
if (NOT MSVC)
if (PROJECT_IS_TOP_LEVEL AND NOT CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
target_compile_options(${PROJECT_NAME} PRIVATE -Wall -Wextra -Wpedantic -Werror -pedantic -pedantic-errors -Wfatal-errors)
endif()
if (CMAKE_CXX_COMPILER_ID MATCHES "GNU")
target_compile_options(${PROJECT_NAME} PUBLIC -Wno-attributes=sc::)
else()
target_compile_options(${PROJECT_NAME} PUBLIC -Wno-unknown-attributes)
endif()
target_compile_options(${PROJECT_NAME} PRIVATE -Wno-unknown-warning-option -Wno-missing-field-initializers -Wno-cast-function-type)
endif()
# --------------------------------------------------------------------------------------------------------
# Include directories
# --------------------------------------------------------------------------------------------------------
target_include_directories(${PROJECT_NAME} PUBLIC "include")
target_include_directories(${PROJECT_NAME} PRIVATE "include/saucer" "private")
# --------------------------------------------------------------------------------------------------------
# Setup feature macros
# --------------------------------------------------------------------------------------------------------
if (saucer_tests)
target_compile_definitions(${PROJECT_NAME} PUBLIC SAUCER_TESTS)
endif()
if (saucer_backend MATCHES "^Qt.$")
string(REGEX REPLACE "[a-zA-Z]+" "" QT_VERSION "${saucer_backend}")
target_compile_definitions(${PROJECT_NAME} PUBLIC SAUCER_QT${QT_VERSION})
endif()
if (saucer_backend STREQUAL "WebView2")
target_compile_definitions(${PROJECT_NAME} PUBLIC SAUCER_WEBVIEW2)
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Sources
# --------------------------------------------------------------------------------------------------------
target_sources(${PROJECT_NAME} PRIVATE
"src/smartview.cpp"
"src/serializer.glaze.cpp"
"src/error.bad_type.cpp"
"src/error.serialize.cpp"
"src/error.bad_function.cpp"
)
if (saucer_modules)
target_sources(${PROJECT_NAME} PRIVATE "src/module.cpp")
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Dependencies
# --------------------------------------------------------------------------------------------------------
include("cmake/cpm.cmake")
include("cmake/nuget.cmake")
CPMFindPackage(
NAME lockpp
VERSION 2.8
GIT_REPOSITORY "https://github.com/Curve/lockpp"
)
CPMFindPackage(
NAME boost_callable_traits
GIT_TAG boost-1.85.0
GIT_REPOSITORY "https://github.com/boostorg/callable_traits"
)
CPMFindPackage(
NAME tl-expected
VERSION 1.1.0
GIT_REPOSITORY "https://github.com/TartanLlama/expected"
OPTIONS "EXPECTED_BUILD_TESTS OFF"
)
CPMFindPackage(
NAME ereignis
VERSION 3.1
GIT_REPOSITORY "https://github.com/Soundux/ereignis"
)
CPMFindPackage(
NAME fmt
GIT_TAG 10.2.1
GIT_REPOSITORY "https://github.com/fmtlib/fmt"
)
CPMFindPackage(
NAME glaze
VERSION 2.6.2
GIT_REPOSITORY "https://github.com/stephenberry/glaze"
)
CPMFindPackage(
NAME flagpp
VERSION 2.1
GIT_REPOSITORY "https://github.com/Curve/flagpp"
)
CPMFindPackage(
NAME boost_preprocessor
GIT_TAG boost-1.85.0
GIT_REPOSITORY "https://github.com/boostorg/preprocessor"
)
target_link_libraries(${PROJECT_NAME} PRIVATE boost_preprocessor cr::flagpp)
target_link_libraries(${PROJECT_NAME} PUBLIC boost_callable_traits cr::lockpp tl::expected glaze::glaze cr::ereignis fmt::fmt)
# --------------------------------------------------------------------------------------------------------
# Setup Linkage
# └ we use conditional linkage, because we want to publicly link against qt/webview2 when module support
# is enabled, so that consumers of the library can easily use the undlerying API for their modules
# without having to link qt/webview2 themselves.
# --------------------------------------------------------------------------------------------------------
set(saucer_linkage PRIVATE)
if (saucer_modules)
set(saucer_linkage PUBLIC)
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Backends
# --------------------------------------------------------------------------------------------------------
if (saucer_backend MATCHES "^Qt.$")
file(GLOB qt_sources
"src/*.qt.*cpp"
"private/*.qt.*hpp"
"src/*.qt${QT_VERSION}.*cpp"
)
target_sources(${PROJECT_NAME} PRIVATE ${qt_sources})
set_target_properties(${PROJECT_NAME} PROPERTIES AUTOMOC ON)
find_package(Qt${QT_VERSION} COMPONENTS Widgets WebEngineWidgets WebChannel REQUIRED)
target_link_libraries(${PROJECT_NAME} ${saucer_linkage} Qt${QT_VERSION}::Widgets Qt${QT_VERSION}::WebChannel Qt${QT_VERSION}::WebEngineWidgets)
endif()
if (saucer_backend STREQUAL "WebView2")
file(GLOB win_sources
"src/*.win32.*cpp"
"src/*.webview2.*cpp"
)
target_sources(${PROJECT_NAME} PRIVATE ${win_sources})
target_compile_definitions(${PROJECT_NAME} PRIVATE UNICODE=1 _UNICODE=1 NOMINMAX=1)
include("cmake/webview2.cmake")
target_link_libraries(${PROJECT_NAME} ${saucer_linkage} Shlwapi webview2::webview2)
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Tests
# --------------------------------------------------------------------------------------------------------
if (saucer_tests)
message(STATUS "[saucer] Building Tests")
add_subdirectory(tests)
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Examples
# --------------------------------------------------------------------------------------------------------
if (saucer_examples)
message(STATUS "[saucer] Building Examples")
add_subdirectory("examples/json-bridge")
add_subdirectory("examples/embedding")
endif()
# --------------------------------------------------------------------------------------------------------
# Setup Packaging Target
# └ We build this artifact so that people who don't use CMake can manually include all required headers
# of our dependencies and link against our static-lib.
# --------------------------------------------------------------------------------------------------------
install(TARGETS ${PROJECT_NAME}
EXPORT ${PROJECT_NAME}-artifact
LIBRARY DESTINATION lib
ARCHIVE DESTINATION lib
RUNTIME DESTINATION bin
)
if (saucer_prefer_remote AND saucer_backend STREQUAL "WebView2")
install(FILES ${webview2_lib_path} DESTINATION lib)
endif()
install(DIRECTORY "include/saucer" TYPE INCLUDE)
install(DIRECTORY "$<TARGET_PROPERTY:fmt,INTERFACE_INCLUDE_DIRECTORIES>/fmt" TYPE INCLUDE)
install(DIRECTORY "$<TARGET_PROPERTY:glaze_glaze,INTERFACE_INCLUDE_DIRECTORIES>/glaze" TYPE INCLUDE)
install(DIRECTORY "$<TARGET_PROPERTY:boost_callable_traits,INTERFACE_INCLUDE_DIRECTORIES>/boost" TYPE INCLUDE)