build.gradle

apply plugin: 'com.android.application'
apply plugin: 'com.github.ben-manes.versions'

android {
    compileSdkVersion 22
    buildToolsVersion "22.0.1"

    defaultConfig {
        applicationId "com.lewisjuggins.miband"
        versionCode 3
        versionName "1.2"
        minSdkVersion 21
        targetSdkVersion 22
    }

    signingConfigs {
        release {
            def Properties localProps = new Properties()
            localProps.load(new FileInputStream(file('local.properties')))
            def Properties keyProps = new Properties()
            if (localProps['keystore.props.file'] != null) {
                keyProps.load(new FileInputStream(file(localProps['keystore.props.file'])))
            }
            storeFile keyProps["store"] != null ? file(keyProps["store"]) : null
            keyAlias keyProps["alias"]
            storePassword keyProps["storePass"]
            keyPassword keyProps["pass"]
        }
    }

    lintOptions {
        abortOnError false
    }

    buildTypes {
        release {
            shrinkResources true
            zipAlignEnabled true
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
            signingConfig signingConfigs.release
        }
    }
}

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.2.3'
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.10.1'
    }
}

repositories {
    mavenCentral()
}

dependencies {
    repositories {
        mavenCentral()
        maven {
            url 'https://oss.sonatype.org/content/repositories/snapshots/'
        }
    }
    compile('com.google.android.gms:play-services:7.0.0')
    compile('com.android.support:palette-v7:22.0.+')
    compile('com.google.code.gson:gson:2.3.1')
    compile('com.melnykov:floatingactionbutton:1.3.0')
    compile project(":localeapi")
    androidTestCompile('junit:junit:4.12')
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.5'
}