forked from intellij-rust/intellij-rust
-
Notifications
You must be signed in to change notification settings - Fork 0
/
RustParser.bnf
1264 lines (1039 loc) · 49.7 KB
/
RustParser.bnf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{
parserClass='org.rust.lang.core.parser.RustParser'
parserUtilClass='org.rust.lang.core.parser.RustParserUtil'
implements='org.rust.lang.core.psi.ext.RsElement'
extends='org.rust.lang.core.psi.ext.RsElementImpl'
elementTypeHolderClass='org.rust.lang.core.psi.RsElementTypes'
elementTypeClass='org.rust.lang.core.psi.RsElementType'
tokenTypeClass='org.rust.lang.core.psi.RsTokenType'
psiClassPrefix='Rs'
psiImplClassSuffix='Impl'
psiPackage='org.rust.lang.core.psi'
psiImplPackage='org.rust.lang.core.psi.impl'
parserImports=[
'static org.rust.lang.core.parser.RustParserUtil.PathParsingMode.*'
'static org.rust.lang.core.parser.RustParserUtil.BinaryMode.*'
]
tokens = [
LBRACE = '{'
RBRACE = '}'
LBRACK = '['
RBRACK = ']'
LPAREN = '('
RPAREN = ')'
COLON = ':'
COLONCOLON = '::'
SEMICOLON = ';'
COMMA = ','
EQ = '='
EXCLEQ = '!='
EQEQ = '=='
SHA = '#'
EXCL = '!'
PLUSEQ = '+='
PLUS = '+'
MINUSEQ = '-='
MINUS = '-'
OREQ = '|='
ANDAND = '&&'
ANDEQ = '&='
AND = '&'
OR = '|'
LT = '<'
XOREQ = '^='
XOR = '^'
MULEQ = '*='
MUL = '*'
DIVEQ = '/='
DIV = '/'
REMEQ = '%='
REM = '%'
GT = '>'
DOT = '.'
DOTDOT = '..'
DOTDOTDOT = '...'
DOTDOTEQ = '..='
FAT_ARROW = '=>'
ARROW = '->'
Q = '?'
AT = '@'
UNDERSCORE = '_'
DOLLAR = '$'
MACRO_KW = 'macro'
CSELF = 'Self'
TYPE_KW = 'type'
UNION = 'union_kw'
DEFAULT = 'default_kw'
AUTO = 'auto_kw'
DYN = 'dyn_kw'
SHEBANG_LINE = 'shebang_line'
RESERVED_KEYWORD = 'reserved_keyword'
]
elementType("(Fn|Anon|Lambda|Path)Parameter") = ValueParameter
elementType("(Fn|Lambda|Path|FnType)Parameters") = ValueParameterList
extends("(.+Expr|StructLiteral)") = Expr
elementType(".+BinExpr") = BinaryExpr
elementType(".+BinOp") = BinaryOp
extends("Pat(Wild|Ref|Tup|Vec|Macro|Struct|Enum|Ident|Range|Uniq|QualPath|Const)") = Pat
generateTokenAccessors=true
consumeTokenMethod("(.*_recover)|(.*Expr)|BinAssignOp") = "consumeTokenFast"
}
// This is the grammar of the Rust language which is used by Grammar Kit
// to generate the parser and the PSI classes. Rule `FooBar` corresponds
// to `RsFooBar` PSI class.
//
// Naming convention:
//
// * tokens are lowercase: for, if, identifier
// * rules are PascalCase: StructItem, EnumVariant
// * macro rules are snake_cased: list_item
// * recovery related rules are PascalCase_with_snake_suffix: Item_recover
File ::= [ SHEBANG_LINE ] InnerAttr* Items
///////////////////////////////////////////////////////////////////////////////////////////////////
// Attributes
///////////////////////////////////////////////////////////////////////////////////////////////////
fake Attr ::= MetaItem {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
}
InnerAttr ::= '#' '!' '[' MetaItem ']' {
extends = Attr
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
OuterAttr ::= '#' '[' MetaItem ']' {
extends = Attr
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private OuterAttr_first ::= '#'
MetaItem ::= identifier [ '=' LitExpr | MetaItemArgs ] {
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsMetaItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsMetaItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
MetaItemArgs ::= '(' [ <<comma_separated_list (MetaItem | LitExpr)>> ] ')' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Paths
///////////////////////////////////////////////////////////////////////////////////////////////////
private PathIdent ::= !("union" identifier) identifier | self | super | 'Self'
fake Path ::= (Path '::' | '::' | TypeQual)? PathIdent PathTypeArguments? {
implements = [ "org.rust.lang.core.psi.ext.RsPathReferenceElement"
"org.rust.lang.core.macros.ExpansionResult" ]
mixin = "org.rust.lang.core.psi.ext.RsPathImplMixin"
stubClass = "org.rust.lang.core.stubs.RsPathStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private Path_first ::= identifier | self | 'Self' | super | '::' | '<'
private PathImpl ::= PathStart PathSegment*
PathStart ::= ('::' | <<checkTypeQualAllowed>> TypeQual)? PathIdent PathTypeArguments? { elementType = Path }
// <T as Foo>::bar::baz::<i32>
// ^~~~~~~~~~~^ TypeQual
TypeQual ::= '<' TypeReference [ as TraitRef] '>' '::' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
left PathSegment ::= '::' PathIdent PathTypeArguments? { elementType = Path }
private PathTypeArguments ::= <<isPathMode 'COLONS'>> ColonTypeArgumentList
| <<isPathMode 'NO_COLONS '>> ( TypeArgumentList | PathParameters RetType? ) // Fn(i32) -> i32 sugar
TypeArgumentList ::= TypeArgumentListImpl {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ColonTypeArgumentList ::= '::' TypeArgumentListImpl { elementType = TypeArgumentList }
private TypeArgumentListImpl ::= '<' !'=' ( <<list_element Lifetime>>*
<<list_element (!(identifier '=') TypeReference)>>*
<<list_element AssocTypeBinding>>*) '>' { pin = 2 }
AssocTypeBinding ::= identifier '=' TypeReference {
pin = 2
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsAssocTypeBindingMixin"
stubClass = "org.rust.lang.core.stubs.RsAssocTypeBindingStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
// Paths for expressions:
// a::b::<T,U>::c
PathGenericArgsWithoutColons ::= <<typeQuals 'ON' <<pathMode 'NO_COLONS' PathImpl>>>> { elementType = Path }
PathGenericArgsWithoutColonsNoTypeQual ::= <<typeQuals 'OFF' <<pathMode 'NO_COLONS' PathImpl>>>> { elementType = Path }
// Paths without type arguments, for use declarations:
// a::b::c
PathWithoutTypes ::= <<typeQuals 'OFF' <<pathMode 'NO_TYPES' PathImpl>>>> { elementType = Path }
// Paths for types:
// a::b<T,U>::c<V,W>
// a::b<T,U>::c(V) -> W
// a::b<T,U>::c(V)
PathGenericArgsWithColons ::= <<typeQuals 'ON' <<pathMode 'COLONS' PathImpl>>>> { elementType = Path }
PathGenericArgsWithColonsNoTypeQual ::= <<typeQuals 'OFF' <<pathMode 'COLONS' PathImpl>>>> { elementType = Path }
// Path semantically constrained to resolve to a trait
TraitRef ::= PathGenericArgsWithoutColonsNoTypeQual {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Items
///////////////////////////////////////////////////////////////////////////////////////////////////
Vis ::= crate | pub VisRestriction?
VisRestriction ::= '(' ( crate | ((&(self ')' | super ')') | in) PathWithoutTypes) ) ')'
//XXX: don't use contextual keywords in recover, because they remap tokens.
private default_ ::= <<defaultKeyword>>
private union ::= <<unionKeyword>>
private auto ::= <<autoKeyword>>
private dyn ::= <<dynKeyword>>
private AttrsAndVis ::= OuterAttr* Vis?
private Item ::= Constant
| TypeAlias
| Function
| TraitItem
| ImplItem
| ModItem
| ModDeclItem
| ForeignModItem
| StructItem
| EnumItem
| UseItem
| ExternCrateItem
| MacroDefinition
| MacroCall
private Item_with_recover ::= !('}' | <<eof>>) Item {
pin = 1
recoverWhile = Item_recover
}
private Item_first ::= '#' | pub | crate | fn | const | extern | unsafe | struct | enum | use | identifier | mod | trait
| static | TYPE_KW | impl | "union" | "default" | "auto" | "dyn"
private Item_recover ::= !('}' | Item_first )
private Items ::= Item_with_recover*
Lifetime ::= QUOTE_IDENTIFIER {
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsLifetimeImplMixin"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Functions
///////////////////////////////////////////////////////////////////////////////////////////////////
// Parameters
fake ValueParameter ::= Pat? TypeReference? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsValueParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnParameter ::= [ Pat ':' ] TypeReference
private FnParameter_with_recover ::= FnParameter (',' | &')') {
pin = 1
recoverWhile = FnParameter_recover
}
private FnParameter_recover ::= !(Pat_first | ')' | '...')
LambdaParameter ::= Pat TypeAscription?
AnonParameter ::= [ RestrictedPat ':' ] TypeReference
PathParameter ::= TypeReference !'='
SelfParameter ::= [ '&' Lifetime? ] mut? self TypeAscription? {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsSelfParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsSelfParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
fake ValueParameterList ::= SelfParameter? ValueParameter* '...'? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnParameters ::= '(' !',' [ SelfParameter (',' | &')') ]
FnParameter_with_recover* ['...' ','? ]
')' { pin = 1 }
LambdaParameters ::= '|' !',' [ <<comma_separated_list LambdaParameter>> ] '|'
FnTypeParameters ::= <<variadic_params_impl AnonParameter>>
PathParameters ::= '(' [ <<comma_separated_list PathParameter>> ] ')' { pin = 1 }
private meta variadic_params_impl ::= '(' [ <<param>> (',' <<param>>)* [ ',' '...'? ] ] ')' { pin = 1 }
private RestrictedPat ::= &( [ mut | '&' '&'? ] ( identifier | '_' ) ) Pat
TypeParameterList ::= '<' <<list_element (LifetimeParameter | TypeParameter)>>* '>' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private LifetimesParams ::= <<list_element LifetimeParameter>>*
LifetimeParameter ::= OuterAttr* QUOTE_IDENTIFIER LifetimeParamBounds? {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsLifetimeParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsLifetimeParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
LifetimeParamBounds ::= ':' Lifetime ('+' Lifetime)*
TypeParameter ::= OuterAttr* identifier TypeParamBounds? [ '=' TypeReference ] {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsTypeParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsTypeParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TypeParamBounds ::= ':' [ Polybound ('+' Polybound)* '+'? ] {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
Polybound ::= [ ForLifetimes | '?' ] Bound {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
WhereClause ::= where <<comma_separated_list WherePred>>? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
WherePred ::= Lifetime LifetimeParamBounds | ForLifetimes? TypeReference TypeParamBounds {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForLifetimes ::= for '<' LifetimesParams '>'
ExternAbi ::= extern STRING_LITERAL?
RetType ::= '->' TypeReference {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
Function ::= OuterAttr*
default_?
Vis?
const? unsafe? ExternAbi?
fn identifier
TypeParameterList?
FnParameters
RetType?
WhereClause?
(';' | InnerAttrsAndBlock)
{
pin = 'identifier'
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsGenericDeclaration"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsInferenceContextOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsFunctionImplMixin"
stubClass = "org.rust.lang.core.stubs.RsFunctionStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
}
Pat ::= PatWild
| PatRef
| PatTup
| PatVec
| PatMacro
| PatStruct
| PatEnum
| PatIdent
| (PatConst !('..' | '...' | '..='))
| PatRange
| PatUniq
private Pat_first ::= '_' | '&' | '(' | '[' | Path_first | LitExpr | box | '-' | ref | mut
PatUniq ::= box Pat
// XXX(matklad): it is impossible to distinguish between nullary enum variants
// and identifiers during parsing.
//
// match x {
// None => { } // match enum variant
// Name => { } // bind Name to x
// }
PatIdent ::= PatBinding [ '@' Pat ]
PatStruct ::= PathGenericArgsWithColonsNoTypeQual '{' PatField_with_recover* '..'? '}'
PatEnum ::= PathGenericArgsWithColonsNoTypeQual '(' SeqPat ')'
// TODO: actual recover
private Pat_with_recover ::= Pat (',' | &(')' | ']' | '..'))
private PatField_with_recover ::= PatField (',' | & '}')
PatConst ::= PathExpr | LitExpr | &('-' LitExpr) UnaryExpr
PatRange ::= PatConst ('..' | '...' | '..=') PatConst { pin = 2 }
PatTup ::= '(' SeqPat ')'
PatVec ::= '[' SeqPat ']'
// NB: there are `[x, .. , y]` and `[x, z.. , y]`
private SeqPat ::= Pat_with_recover* ['..' [',' Pat_with_recover+] ]
PatRef ::= '&' mut? Pat
PatWild ::= '_'
PatBinding ::= BindingMode? identifier !'...' !'::' {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsPatBindingImplMixin"
}
PatField ::= identifier ':' Pat | box? PatBinding
BindingMode ::= ref mut? | mut
Constant ::= OuterAttr* default_? Vis? (static mut? | const) identifier TypeAscription [ '=' AnyExpr ] ';' {
pin = 'identifier'
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsInferenceContextOwner"
"org.rust.lang.core.macros.ExpansionResult" ]
mixin = "org.rust.lang.core.psi.ext.RsConstantImplMixin"
stubClass = "org.rust.lang.core.stubs.RsConstantStub"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
UseItem ::= AttrsAndVis use UseSpeck ';' {
pin = "use"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsUseItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsUseItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
// You can see the following after the `use`:
// ::{};
// {foo, bar};
// foo::bar as baz;
// foo::bar::{self, foo};
// foo::{};
// ::foo::*;
UseSpeck ::= PathWithoutTypes [ Alias | '::' UseSpeckProjection ]
| '::'? UseSpeckProjection {
extends = "org.rust.lang.core.psi.ext.RsUseSpeckImplMixin"
stubClass = "org.rust.lang.core.stubs.RsUseSpeckStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private UseSpeckProjection ::= '*' | UseGroup
UseGroup ::= '{' UseSpeck_with_recover* '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private UseSpeck_with_recover ::= !'}' UseSpeck (','|&'}') {
pin = 1
recoverWhile = UseSpeck_recover
}
private UseSpeck_recover ::= !('}' | self | identifier | '::' | '*' )
Alias ::= as identifier {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedNamedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsAliasStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ExternCrateItem ::= AttrsAndVis extern crate identifier Alias? ';' {
pin = "identifier"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsExternCrateItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsExternCrateItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ModItem ::= AttrsAndVis mod identifier '{' InnerAttr* Items '}' {
pin = 4
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsMod"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsModItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsModItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ModDeclItem ::= AttrsAndVis mod identifier ';' {
pin = 'identifier' // make sure `ModDeclItem` goes **after** `ModItem`
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsModDeclItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsModDeclItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForeignModItem ::= AttrsAndVis ExternAbi '{' InnerAttr* ForeignDecl* '}' {
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsForeignModItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private ForeignDecl ::= Constant | Function
///////////////////////////////////////////////////////////////////////////////////////////////////
// Struct & Enums
///////////////////////////////////////////////////////////////////////////////////////////////////
StructItem ::= AttrsAndVis (struct | union) identifier TypeParameterList?
( TupleStructTail | BlockStructTail | UnitStructTail ) {
pin = 2
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsStructOrEnumItemElement"
"org.rust.lang.core.psi.ext.RsFieldsOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsStructItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsStructItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TupleStructTail ::= TupleFields WhereClause? ';' { pin = 1 }
private UnitStructTail ::= WhereClause? ';'
private BlockStructTail ::= WhereClause? BlockFields
EnumItem ::= AttrsAndVis enum identifier TypeParameterList? WhereClause? EnumBody {
pin = "enum"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = "org.rust.lang.core.psi.ext.RsStructOrEnumItemElement"
mixin = "org.rust.lang.core.psi.ext.RsEnumItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsEnumItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
EnumBody ::= '{' [ <<comma_separated_list EnumVariant>> ] '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
EnumVariant ::= OuterAttr* identifier VariantArgs? {
pin = 2
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner"
"org.rust.lang.core.psi.ext.RsFieldsOwner"
"org.rust.lang.core.psi.ext.RsVisible" ]
mixin = "org.rust.lang.core.psi.ext.RsEnumVariantImplMixin"
stubClass = "org.rust.lang.core.stubs.RsEnumVariantStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private VariantArgs ::= BlockFields | TupleFields | VariantDiscriminant
BlockFields ::= '{' (FieldDecl (',' | &'}'))* '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TupleFields ::= '(' (TupleFieldDecl (',' | &')'))* ')' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
VariantDiscriminant ::= '=' AnyExpr {
pin = 1
implements = "org.rust.lang.core.psi.ext.RsInferenceContextOwner"
}
FieldDecl ::= AttrsAndVis identifier TypeAscription {
pin = 2
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsOuterAttributeOwner"
"org.rust.lang.core.psi.ext.RsVisibilityOwner"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsFieldDeclImplMixin"
stubClass = "org.rust.lang.core.stubs.RsFieldDeclStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
recoverWhile = Field_recover
}
private Field_recover ::= !('}' | ',')
TupleFieldDecl ::= AttrsAndVis TypeReference {
implements = [ "org.rust.lang.core.psi.ext.RsOuterAttributeOwner"
"org.rust.lang.core.psi.ext.RsVisibilityOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsTupleFieldDeclImplMixin"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
recoverWhile = TupleField_recover
}
private TupleField_recover ::= !(')' | ',')
///////////////////////////////////////////////////////////////////////////////////////////////////
// Trait & Impl
///////////////////////////////////////////////////////////////////////////////////////////////////
TraitItem ::= AttrsAndVis unsafe? auto? trait identifier TypeParameterList? TypeParamBounds? WhereClause? Members {
pin = "trait"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsTraitOrImpl"
"org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]
mixin = "org.rust.lang.core.psi.ext.RsTraitItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsTraitItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ImplItem ::= AttrsAndVis default_? unsafe? impl TypeParameterList? ( TraitImpl | InherentImpl ) WhereClause? Members {
pin = "impl"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsTraitOrImpl"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]
mixin = "org.rust.lang.core.psi.ext.RsImplItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsImplItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TraitImpl ::= '!'? TraitRef for ('..' | TypeReference) { pin = 3 }
private InherentImpl ::= TypeReference !for
Members ::= '{' InnerAttr* Member* '}' {
pin = 1
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private Member ::= !'}' ( Function | Constant | TypeAlias | MacroCall ) {
pin = 1
recoverWhile = Member_recover
}
private Member_recover ::= !('#' | Vis | extern | const | static | unsafe | fn | (identifier '!') | TYPE_KW | "default" | '}')
///////////////////////////////////////////////////////////////////////////////////////////////////
// Types
///////////////////////////////////////////////////////////////////////////////////////////////////
private TypeAscription ::= ':' TypeReference
private TypeReferenceInner ::= ArrayType
| RefLikeType
| FnPointerType
// External rule to find the difference between `(T)` and `(T,)`
| <<tupleOrParenType TypeReferenceInner TupleType_upper>>
| ExplicitTraitType
// External rule to find the difference between `T` and `T+T`
| <<baseOrTraitType BaseTypeInner ImplicitTraitType TraitType_upper>>
| ForInType // FIXME O(2^n) for types like `for<'a> A<for<'b> B<for<'c> C<...>>>`
private ScalarTypeReferenceInner ::= ArrayType
| RefLikeType
| FnPointerType
| BaseType
| <<tupleOrParenType ScalarTypeReferenceInner TupleType_upper>>
| ForInType
TypeReference ::= TypeReferenceInner {
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ScalarTypeReference ::= ScalarTypeReferenceInner { elementType = TypeReference }
ArrayType ::= '[' TypeReference [';' AnyExpr] ']' {
implements = [ "org.rust.lang.core.psi.ext.RsTypeElement" "org.rust.lang.core.psi.ext.RsInferenceContextOwner" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsArrayTypeStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
RefLikeType ::= ( '&' Lifetime? mut? | '*' [ const | mut ] ) TypeReference {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsRefLikeTypeStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnPointerType ::= [ unsafe? ExternAbi? ] fn FnTypeParameters RetType? {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TupleType ::= '(' [ <<comma_separated_list TypeReference>> ] ')' {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TupleType_upper ::= (',' TypeReference)* ','? ')'
Bound ::= Lifetime | TraitRef {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForInType ::= ForLifetimes (FnPointerType | TraitRef) {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
BaseType ::= BaseTypeInner {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsBaseTypeStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private BaseTypeInner ::= '(' ')' | '_' | '!' | PathGenericArgsWithoutColons
// `impl Trait` or `dyn Trait` or `Trait+'a`
fake TraitType ::= ExplicitTraitTypeInner | ImplicitTraitTypeInner {
implements = "org.rust.lang.core.psi.ext.RsTypeElement"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsTraitTypeStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ExplicitTraitType ::= ExplicitTraitTypeInner { elementType = TraitType }
private ExplicitTraitTypeInner ::= (impl | dyn) Polybound ('+' Polybound)*
ImplicitTraitType ::= ImplicitTraitTypeInner { elementType = TraitType }
private ImplicitTraitTypeInner ::= Polybound ('+' Polybound)+
private TraitType_upper ::= ('+' Polybound)+
TypeAlias ::= OuterAttr* default_? Vis? TYPE_KW identifier
[ TypeParameterList WhereClause? | WhereClause | TypeParamBounds ]
[ '=' TypeReference ] ';' {
pin = 'identifier'
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsGenericDeclaration"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]
mixin = "org.rust.lang.core.psi.ext.RsTypeAliasImplMixin"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
stubClass = "org.rust.lang.core.stubs.RsTypeAliasStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Expressions
///////////////////////////////////////////////////////////////////////////////////////////////////
// https://doc.rust-lang.org/reference.html#operator-precedence
// https://github.com/JetBrains/Grammar-Kit/blob/master/HOWTO.md#24-compact-expression-parsing-with-priorities
//
// Rust expression grammar allows or forbids struct literals depending on context.
// There are `no_struct_lit_expr` and `any_expr` productions for this two cases.
// `expr` production is an implementation detail. It passes the context information to the child expressions.
Expr ::= RetExpr
| LambdaExpr
| AssignBinExpr
| WhileExpr
| IfExpr
| ForExpr
| LoopExpr
| MatchExpr
| BlockExpr
| ContExpr
| BreakExpr
| FullRangeExpr
| OpenRangeExpr
| BoolOrBinExpr
| BoolAndBinExpr
| CompBinExpr
| RelCompBinExpr
| BitOrBinExpr
| BitXorBinExpr
| BitAndBinExpr
| BitShiftBinExpr
| AddBinExpr
| MulBinExpr
| CastExpr
| UnaryExpr
| TryExpr
| AtomExpr {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
}
private Expr_first ::= return | '|' | Path_first | '{' | '[' | '(' | '..' | '...' | '..=' | true | false | box | QUOTE_IDENTIFIER
| '-' | '*' | '!' | '&' | move | LitExpr | while | if | for | continue | break | loop | match | unsafe
// https://github.com/rust-lang/rfcs/blob/master/text/0092-struct-grammar.md
NoStructLitExpr ::= <<structLiterals 'OFF' <<stmtMode 'OFF' Expr>> >> { elementType = Expr }
AnyExpr ::= <<structLiterals 'ON' <<stmtMode 'OFF' Expr>> >> { elementType = Expr }
StmtModeExpr ::= <<structLiterals 'ON' <<stmtMode 'ON' Expr>> >> { elementType = Expr }
StmtModeExprOff ::= <<stmtMode 'OFF' Expr>> { elementType = Expr }
BlockExpr ::= OuterAttr* [ unsafe &'{' ] SimpleBlock {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private AtomExpr ::= LitExpr
| MacroExpr
| StructLiteral
| DotExpr
| IndexExpr
| PathExpr !'('
| CallExpr
| ArrayExpr
| UnitExpr
| TupleOrParenExpr
fake BinaryExpr ::= Expr BinaryOp Expr {
methods=[
left="/Expr[0]"
right="/Expr[1]"
]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
fake BinaryOp ::= gtgteq | ltlteq | '|=' | '^=' | '&=' | '=' | '+=' | '-=' | '*=' | '/=' | '%='
| '==' | '!='
| '<' | '>' | lteq | gteq
| ltlt | gtgt
| '+' | '-' | '*' | '/' | '%'
| oror | andand | '|' | '&' | '^' {
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsBinaryOpImplMixin"
stubClass = "org.rust.lang.core.stubs.RsBinaryOpStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
AssignBinExpr ::= Expr AssignBinOp Expr { rightAssociative = true }
AssignBinOp ::= gtgteq | ltlteq | '|=' | '^=' | '&=' | '=' | '+=' | '-=' | '*=' | '/=' | '%='
CompBinExpr ::= Expr !<<isCompleteBlockExpr>> CompBinOp StmtModeExprOff
RelCompBinExpr ::= Expr !<<isCompleteBlockExpr>> RelCompBinOp StmtModeExprOff
BitShiftBinExpr ::= Expr !<<isCompleteBlockExpr>> BitShiftBinOp StmtModeExprOff
AddBinExpr ::= Expr !<<isCompleteBlockExpr>> AddBinOp StmtModeExprOff
MulBinExpr ::= Expr !<<isCompleteBlockExpr>> MulBinOp StmtModeExprOff
CompBinOp ::= '==' | '!='
RelCompBinOp ::= (!('<<' | '<=') '<' | !('>>' | '>=') '>' | lteq | gteq)
BitShiftBinOp ::= ltlt | gtgt
AddBinOp ::= '+' | '-'
MulBinOp ::= '*' | '/' | '%'
// <expr> | <expr> has higher priority than <expr> || <expr>
BoolOrBinExpr ::= Expr !<<isCompleteBlockExpr>> BoolOrBinOp StmtModeExprOff
BoolAndBinExpr ::= Expr !<<isCompleteBlockExpr>> BoolAndBinOp StmtModeExprOff
BitOrBinExpr ::= Expr !(<<isCompleteBlockExpr>> | oror) BitOrBinOp StmtModeExprOff
BitAndBinExpr ::= Expr !(<<isCompleteBlockExpr>> | andand) BitAndBinOp StmtModeExprOff
BitXorBinExpr ::= Expr !<<isCompleteBlockExpr>> BitXorBinOp StmtModeExprOff
BoolOrBinOp ::= oror
BoolAndBinOp ::= andand
BitOrBinOp ::= '|'
BitAndBinOp ::= '&'
BitXorBinOp ::= '^'
CastExpr ::= Expr (as | ':') ScalarTypeReference {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TryExpr ::= Expr '?' {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
UnaryExpr ::= OuterAttr* (box | '-' | '*' | '!' | '&' mut?) Expr {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
LambdaExpr ::= OuterAttr* move? LambdaParameters RetType? AnyExpr {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
StructLiteral ::= <<checkStructAllowed>> OuterAttr* PathGenericArgsWithColonsNoTypeQual StructLiteralBody {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
StructLiteralBody ::= '{' StructLiteralField_with_recover* ('..' AnyExpr)? '}' { pin = 1 }
StructLiteralField ::= OuterAttr* identifier [ ':' AnyExpr ] {
pin = 2
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsStructLiteralFieldImplMixin"
}
private StructLiteralField_with_recover ::= StructLiteralField (',' | &'}') {
pin = 1
recoverWhile = StructLiteralField_recover
}
private StructLiteralField_recover ::= !(identifier | ',' | '}' | '..' | '#')
PathExpr ::= OuterAttr* PathGenericArgsWithColons {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
WhileExpr ::= OuterAttr* LabelDecl? while Condition SimpleBlock {
pin = 'while'
implements = [ "org.rust.lang.core.psi.ext.RsLabeledExpression" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
Condition ::= [ let Pat '=' ] NoStructLitExpr
LoopExpr ::= OuterAttr* LabelDecl? loop SimpleBlock {
pin = 'loop'
implements = [ "org.rust.lang.core.psi.ext.RsLabeledExpression" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ContExpr ::= OuterAttr* continue Label? {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
BreakExpr ::= OuterAttr* break Label? AnyExpr? {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForExpr ::= OuterAttr* LabelDecl? for Pat in NoStructLitExpr SimpleBlock {
pin = 'for'
implements = [ "org.rust.lang.core.psi.ext.RsLabeledExpression" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
LabelDecl ::= QUOTE_IDENTIFIER ':' {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsLabelDeclImplMixin"
}
Label ::= QUOTE_IDENTIFIER {
implements = [ "org.rust.lang.core.psi.ext.RsReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsLabelImplMixin"
}
MatchExpr ::= OuterAttr* match NoStructLitExpr MatchBody {
pin = 'match'