configure.ac

#*****************************************************************************
#       Copyright (C) 2005-2007 William Stein
#       Copyright (C) 2009-2011 David Kirkby
#       Copyright (C) 2012-2016 Jeroen Demeyer
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 2 of the License, or
# (at your option) any later version.
#                  http://www.gnu.org/licenses/
#*****************************************************************************

dnl If you are going to update this, please stick the recommended layout
dnl in the autoconf manual - i.e.

dnl First check for programs
dnl Next check for libraries
dnl Next check for header files
dnl Next check for types
dnl Next check for structures
dnl Next check compiler characteristics
dnl Next check for library functions
dnl Next check for system services

dnl Older versions do not support $GFC
AC_PREREQ([2.69])

AC_DEFUN([SAGE_VERSION], m4_esyscmd_s([. src/bin/sage-version.sh && echo $SAGE_VERSION]))
AC_INIT([Sage], SAGE_VERSION, [sage-devel@googlegroups.com])

# The following needs to be immediately after calling AC_INIT
#------------------------------------------------------------
# We need to run this configure script with bash
if test -z "$BASH_VERSION"
then
    CONFIG_SHELL=`command -v bash`
    export CONFIG_SHELL
    if $CONFIG_SHELL -c "exit 0"
    then
        exec $CONFIG_SHELL $0 "$@"
    else
        AC_MSG_NOTICE([The 'bash' shell is needed to build AC_PACKAGE_NAME])
        AC_MSG_NOTICE([All modern systems will have the 'bash' shell installed somewhere])
        if test -d /opt/OpenSource/bin
        then
           AC_MSG_NOTICE([On HP-UX you may try adding /opt/OpenSource/bin to your path])
        fi
        if test -d /opt/pware/bin
        then
           AC_MSG_NOTICE([On AIX you may try adding /opt/pware/bin to your path])
        fi
        AC_MSG_ERROR(['bash' not found])
    fi
fi


AC_COPYRIGHT([GPL version 3])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_AUX_DIR([config])

dnl This is the hierarchy where everything gets installed (SAGE_LOCAL).
dnl By default, it is the subdirectory local, but the user
dnl can override it by supplying --prefix=....
AC_PREFIX_DEFAULT(`pwd -P`/local)

dnl We don't really use automake, but configure needs aclocal and the
dnl automake library files (like config.guess).
AM_INIT_AUTOMAKE([1.9.6 foreign])

# Allow "configure --disable-maintainer-mode" to disable timestamp checking
AM_MAINTAINER_MODE([enable])

dnl Make sure the path to our own m4 macros is always properly set
dnl and doesn't depend on how autoconf is called.
AC_CONFIG_MACRO_DIR([m4])

#---------------------------------------------------------
#
# This is essentially the configure part of the old "install" file.
# Over time, this should be changed to proper autoconf style with
# configure options.
#

########################################################################
# Set various environment variables (needed at configure time)
########################################################################

# Assume current directory is SAGE_ROOT.
SAGE_ROOT=`pwd -P`

SAGE_LOCAL="$prefix"
# The following line is necessary because the code below
# inspects stuff in the installation prefix at configure time.
# This is nonstandard.
if test "$SAGE_LOCAL" = NONE; then
    SAGE_LOCAL=local
fi
SAGE_SRC="$SAGE_ROOT/src"
SAGE_SPKG_INST="$SAGE_LOCAL/var/lib/sage/installed"

#---------------------------------------------------------
AX_CHECK_ROOT([AC_MSG_ERROR([You cannot build Sage as root, switch to an unpriviledged user])], [])

# Check whether we are on a supported platform
AC_CANONICAL_BUILD()
AC_CANONICAL_HOST()

case $host in
*-*-sunos*|*-*-solaris2.[1-9])
AC_MSG_ERROR([[
Sage is not supported on any version of Solaris earlier than 10.
Sage has been tested on the first release of Solaris 10
(03/2005) and works on that. Sage may or may not work with
your version of Solaris.

More information can be found about Sage on Solaris
on the Wiki at http://wiki.sagemath.org/solaris]]);;

*-*-darwin[1-7].*)
AC_MSG_ERROR([[
Sage has never been built on OS X 10.3 (Panther)
or earlier. The oldest version of OS X successfully used
is OS X version 10.4 (Tiger). You might consider updating
your version of OS X if your hardware permits this, but
Apple charges for upgrades of OS X]]);;

*-*-hpux*)
AC_MSG_ERROR([[
You are attempting to build Sage on HP's HP-UX operating system,
which is not a supported platform for Sage yet though
some work has been done on HP-UX. A port does not look to
be particularly difficult. Some information can be
found on the Sage Wiki at http://wiki.sagemath.org/HP-UX

If you would like to help port Sage to HP-UX,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;

*-*-aix*)
AC_MSG_ERROR([[
You are attempting to build Sage on IBM's AIX operating system,
which is not a supported platform for Sage yet. Things may or
may not work. If you would like to help port Sage to AIX,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;

*-*-irix*)
AC_MSG_ERROR([[
You are attempting to build Sage on SGI's IRIX operating system,
which is not a supported platform for Sage yet. Things may or
may not work. If you would like to help port Sage to IRIX,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;

*-*-osf*)
AC_MSG_ERROR([[
You are attempting to build Sage on HP's Tru64 operating system,
which is not a supported platform for Sage yet. Things may or
may not work. If you would like to help port Sage to Tru64,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;

*-*-freebsd*)
AC_MSG_ERROR([[
You are attempting to build Sage on the FreeBSD operating system,
which is not a supported platform for Sage yet, though
developers are working on adding FreeBSD support. Things may or
may not work. If you would like to help port Sage to FreeBSD,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;

# The following are all supported platforms.
*-*-linux*);;
*-*-darwin*);;
*-*-solaris*);;
*-*-cygwin*);;

# Wildcard for other unsupported platforms
*)
AC_MSG_ERROR([[
You are attempting to build Sage on $host,
which is not a supported platform for Sage yet. Things may or
may not work. If you would like to help port Sage to $host,
please join the sage-devel discussion list - see
http://groups.google.com/group/sage-devel
The Sage community would also appreciate any patches you submit]]);;
esac


###############################################################################
# Check general programs
###############################################################################

AC_CHECK_PROG(found_ar, ar, yes, no)
if test x$found_ar != xyes
then
    AC_MSG_NOTICE([Sorry, the 'ar' command must be in the path to build AC_PACKAGE_NAME])
    AC_MSG_NOTICE([On some systems it can be found in /usr/ccs/bin ])
    AC_MSG_NOTICE(['ar' is also part of the GNU 'binutils' package.])
    AC_MSG_ERROR([Exiting, as the archiver 'ar' can not be found.])
fi

AC_CHECK_PROG(found_m4, m4, yes, no)
if test x$found_m4 != xyes
then
    AC_MSG_NOTICE([Sorry, the 'm4' command must be in the path to build AC_PACKAGE_NAME])
    AC_MSG_NOTICE([On some systems it can be found in /usr/ccs/bin])
    AC_MSG_NOTICE([See also http://www.gnu.org/software/m4/])
    AC_MSG_ERROR([Exiting, as the macro processor 'm4' can not be found.])
fi

AC_CHECK_PROG(found_ranlib, ranlib, yes, no)
if test x$found_ranlib != xyes
then
    AC_MSG_NOTICE([Sorry, the 'ranlib' command must be in the path to build AC_PACKAGE_NAME])
    AC_MSG_NOTICE([On some systems it can be found in /usr/ccs/bin ])
    AC_MSG_NOTICE(['ranlib' is also part of the GNU 'binutils' package.])
    AC_MSG_ERROR([Exiting, as 'ranlib' can not be found.])
fi

AC_CHECK_PROG(found_strip, strip, yes, no)
if test x$found_strip != xyes
then
    AC_MSG_NOTICE([Sorry, the 'strip' command must be in the path to build AC_PACKAGE_NAME])
    AC_MSG_NOTICE([On some systems 'strip' can be found in /usr/ccs/bin ])
    AC_MSG_NOTICE(['strip' is also part of the GNU 'binutils' package.])
    AC_MSG_ERROR([Exiting, as 'strip' can not be found.])
fi

# Check tar
AC_CACHE_CHECK([for GNU or BSD tar], [ac_cv_path_TAR], [
AC_PATH_PROGS_FEATURE_CHECK(TAR, [tar gtar], [[
ac_version_TAR=`$ac_path_TAR --version 2>&1`
if echo "$ac_version_TAR" | grep >/dev/null GNU; then
    ac_cv_path_TAR=$ac_path_TAR
    if test $ac_prog = tar; then
        ac_path_TAR_found=:
    fi
fi
if echo "$ac_version_TAR" | grep >/dev/null bsdtar; then
    ac_cv_path_TAR=$ac_path_TAR
    if test $ac_prog = tar; then
        ac_path_TAR_found=:
    fi
fi
]],
[AC_MSG_ERROR([could not find either a GNU or BSD version of tar])],
[$PATH:/usr/sfw/bin])
])

command_TAR=`command -v tar 2>/dev/null`
AS_IF([test x$command_TAR != x$ac_cv_path_TAR],
      [AC_MSG_ERROR([[found a good version of tar in $ac_cv_path_TAR, but it's not the first "tar" program in your PATH]])]
)

# Check make (unless MAKE is set)
if test -z "$MAKE"; then
    AC_CACHE_CHECK([for GNU make], [ac_cv_path_MAKE], [
    AC_PATH_PROGS_FEATURE_CHECK(MAKE, [make gmake], [[
    ac_version_MAKE=`$ac_path_MAKE --version 2>&1`
    if echo "$ac_version_MAKE" | grep >/dev/null GNU; then
        ac_cv_path_MAKE=$ac_path_MAKE
        if test $ac_prog = make; then
            ac_path_MAKE_found=:
        fi
    fi
    ]],
    [AC_MSG_ERROR([could not find a GNU version of make])],
    [$PATH:/usr/sfw/bin])
    ])

    command_MAKE=`command -v make 2>/dev/null`
    AS_IF([test x$command_MAKE != x$ac_cv_path_MAKE],
          [AC_MSG_ERROR([[found GNU make in $ac_cv_path_MAKE, but it's not the first "make" program in your PATH]])])
fi

# Check for Latex, the use of which is less important in Sage than
# it used to be, as it was at one time required to build any documentation
# but this is no longer so.
AC_CHECK_PROG(found_latex, latex, yes, no)
if test x$found_latex != xyes
then
    AC_MSG_WARN([You do not have 'latex', which is recommended, but not])
    AC_MSG_WARN([required. Latex is only really used for building pdf])
    AC_MSG_WARN([documents and for %latex mode in the AC_PACKAGE_NAME notebook.])
fi

# Check that perl is available, with version 5.8.0 or later.
# Some packages need perl, however it is not clear whether Sage really
# requires version >= 5.8.0.  The R package *used* to require it, but
# not anymore. -- Jeroen Demeyer
AC_PATH_PROG([PERL],[perl])
AX_PROG_PERL_VERSION([5.8.0],[],[
    AC_MSG_ERROR([Exiting, since AC_PACKAGE_NAME requires perl-5.8.0 or later])
])

# Check whether git works by executing "git --version"
need_to_install_git=no
AC_CACHE_CHECK([for git], [ac_cv_path_GIT], [
    AC_PATH_PROGS_FEATURE_CHECK([GIT], [git],
    [${ac_path_GIT} --version >/dev/null 2>/dev/null && ac_cv_path_GIT=${ac_path_GIT}],
    [need_to_install_git=yes; ac_cv_path_GIT=no])])

# Yasm is only needed on x86(_64) systems; check also for system yasm
# which must support "adox" (new Skylake instruction)
need_to_install_yasm=no
AC_CACHE_CHECK([for yasm], [ac_cv_path_YASM],
    AS_CASE("$host_cpu",
        [i@<:@0-9@:>@86|x86_64], [
        AC_PATH_PROGS_FEATURE_CHECK([YASM], [yasm],
        [[{ echo "BITS 64"; echo "adox rax, rax"; } | ${ac_path_YASM} - -o /dev/null >/dev/null 2>/dev/null && ac_cv_path_YASM=${ac_path_YASM}]],
        [need_to_install_yasm=yes; ac_cv_path_YASM=no])],
        [ac_cv_path_YASM="not needed for $host_cpu"]))

###############################################################################
# Check C/C++/Fortran compilers
###############################################################################

dnl Usage: SAGE_SHOULD_INSTALL_GCC(reason)
dnl
dnl Use this macro to indicate that we SHOULD install GCC.
dnl In this case, GCC will be installed unless SAGE_INSTALL_GCC=no.
dnl In the latter case, a warning is given.
AC_DEFUN([SAGE_SHOULD_INSTALL_GCC], [
    if test x$SAGE_INSTALL_GCC = xexists; then
        true  # Do nothing if already installed
    elif test x$SAGE_INSTALL_GCC = xno; then
        AC_MSG_WARN([$1])
    else
        AC_MSG_NOTICE([Installing GCC because $1])
        need_to_install_gcc=yes
    fi
])

dnl Usage: SAGE_MUST_INSTALL_GCC(reason)
dnl
dnl Use this macro to indicate that we MUST install GCC.
dnl In this case, it is an error if SAGE_INSTALL_GCC=no.
AC_DEFUN([SAGE_MUST_INSTALL_GCC], [
    if test x$SAGE_INSTALL_GCC = xexists; then
        true  # Do nothing if already installed
    elif test x$SAGE_INSTALL_GCC = xno; then
        AC_MSG_ERROR([SAGE_INSTALL_GCC is set to 'no', but $1])
    else
        AC_MSG_NOTICE([Installing GCC because $1])
        need_to_install_gcc=yes
    fi
])


# By default, do not install GCC
need_to_install_gcc=no
# or GFORTRAN
need_to_install_gfortran=no

if test -f "$SAGE_LOCAL/bin/gcc"; then
    # Special value for SAGE_INSTALL_GCC if GCC is already installed
    SAGE_INSTALL_GCC=exists

    # Check whether it actually works...
    # See https://trac.sagemath.org/ticket/24599
    if test -x "$SAGE_LOCAL/bin/g++"; then
        echo '#include <complex>' >conftest.cpp
        echo 'auto inf = 1.0 / std::complex<double>();' >>conftest.cpp

        if ! bash -c "source '$SAGE_SRC/bin/sage-env' && g++ -O3 -c -o conftest.o conftest.cpp"; then
            # Pretend that GCC is not installed: remove the gcc and g++
            # binaries and remove the "installed" file such that GCC
            # will be built as if it was never installed before.
            rm -f "$SAGE_LOCAL"/bin/gcc
            rm -f "$SAGE_LOCAL"/bin/g++
            rm -f "$SAGE_SPKG_INST"/gcc-*
            SAGE_INSTALL_GCC=yes
            SAGE_MUST_INSTALL_GCC([installed g++ is broken])
        fi
        rm -f conftest.*
    fi
elif test -n "$SAGE_INSTALL_GCC"; then
    # Check the value of the environment variable SAGE_INSTALL_GCC
    case "$SAGE_INSTALL_GCC" in
        yes)
            SAGE_MUST_INSTALL_GCC([SAGE_INSTALL_GCC is set to 'yes']);;
        no)
            true;;
        *)
            AC_MSG_ERROR([SAGE_INSTALL_GCC should be set to 'yes' or 'no'. You can also leave it unset to install GCC when needed]);;
    esac
fi


AC_PROG_CC()
AC_PROG_CPP()
AC_PROG_CXX()
AC_PROG_FC()

AC_SUBST(CC)
AC_SUBST(CXX)
AC_SUBST(FC)

# Figuring out if we are using clang instead of gcc.
AX_COMPILER_VENDOR()
IS_REALLY_GCC=no
if test "x$ax_cv_c_compiler_vendor" = xgnu ; then
    IS_REALLY_GCC=yes
fi

# On darwin, also set the objective C/C++ compilers
# Checking on all platforms doesn't hurt and stops
# configure from sending an error when run on non-darwin.
AC_PROG_OBJC()
AC_PROG_OBJCXX()
AC_SUBST(OBJC)
AC_SUBST(OBJCXX)

if test "x$CXX" = x
then
    AC_MSG_ERROR([a C++ compiler is missing])
fi

###############################################################################
# Check libraries
###############################################################################

# Only install curl (and libcurl) if we cannot find version 7.22 or
# later, since that is what R needs.
need_to_install_curl=no
AC_CACHE_CHECK([for curl 7.22], [ac_cv_path_CURL], [
    AC_PATH_PROGS_FEATURE_CHECK(CURL, [curl],
    [${ac_path_CURL}-config --checkfor 7.22 >/dev/null 2>/dev/null && ac_cv_path_CURL=${ac_path_CURL}],
    [need_to_install_curl=yes; ac_cv_path_CURL=no])])


###############################################################################
# Check header files
###############################################################################

# If (lib)curl is installed, we need to check for the curl header
# file, too.
if test $need_to_install_curl = no;
then
    AC_CHECK_HEADER([curl/curl.h], [], [need_to_install_curl=yes])
fi

# complex.h is one that might not exist on older systems.
AC_LANG(C++)
AC_CHECK_HEADER([complex.h],[],[
    AC_MSG_ERROR([Exiting, since you do not have the 'complex.h' header file.])
])


###############################################################################
# Check types/structures
###############################################################################

# None needed


###############################################################################
# Check compiler characteristics
###############################################################################

AX_CXX_COMPILE_STDCXX_11([], optional)
if test $HAVE_CXX11 != 1; then
    SAGE_MUST_INSTALL_GCC([your C++ compiler does not support C++11])
fi

AC_LANG(C)
if test -z "$CC"; then
    SAGE_MUST_INSTALL_GCC([a C compiler is missing])
else
    # Save compiler before checking for C99 support
    save_CC=$CC
    # Check that we can compile C99 code
    AC_PROG_CC_C99()
    if test "x$ac_cv_prog_cc_c99" = xno
    then
        SAGE_MUST_INSTALL_GCC([your C compiler cannot compile C99 code])
    fi
    # restore original CC
    CC=$save_CC
fi

# Check that the Fortran compiler accepts free-format source code
# (as opposed to the older fixed-format style from Fortran 77).
# This helps verify the compiler works too, so if some idiot
# sets FC to /usr/bin/ls, we will at least know it's
# not a working Fortran compiler.
AC_LANG(Fortran)
if test -z "$FC"; then
    need_to_install_gfortran=yes
else
   # see http://www.gnu.org/software/hello/manual/autoconf/Fortran-Compiler.html
   AC_FC_FREEFORM([],
   [
   AC_MSG_NOTICE([Your Fortran compiler does not accept free-format source code])
   AC_MSG_NOTICE([which means the compiler is either seriously broken, or])
   AC_MSG_NOTICE([is too old to build Sage.])
   need_to_install_gfortran=yes
   ])
fi


# Check compiler versions

if test x$GXX != xyes; then
    SAGE_SHOULD_INSTALL_GCC([your C++ compiler isn't GCC (GNU C++)])
elif test $need_to_install_gcc = yes; then
    # If we're installing GCC anyway, skip the rest of these version
    # checks.
    true
elif test x$GCC != xyes; then
    SAGE_SHOULD_INSTALL_GCC([your C compiler isn't GCC (GNU C)])
elif test x$GFC != xyes; then
    need_to_install_gfortran=yes
else
    # Since need_to_install_gcc is "no", we know that
    # at least C, C++ and Fortran compilers are available.
    # We also know that all compilers are GCC.

    # Find out the compiler versions:
    AX_GCC_VERSION()
    AX_GXX_VERSION()

    if test $IS_REALLY_GCC = yes ; then
        # Add the .0 because Debian/Ubuntu gives version numbers like
        # 4.6 instead of 4.6.4 (Trac #18885)
        case "$GXX_VERSION.0" in
            [[0-3]].*|4.[[0-7]].*)
                # Install our own GCC if the system-provided one is older than gcc-4.8.
                SAGE_SHOULD_INSTALL_GCC([you have $CXX version $GXX_VERSION, which is quite old]);;
        esac
    fi

    # The following tests check that the version of the compilers
    # are all the same.
    if test "$GCC_VERSION" != "$GXX_VERSION"; then
        SAGE_SHOULD_INSTALL_GCC([$CC ($GCC_VERSION) and $CXX ($GXX_VERSION) are not the same version])
    fi

    # assuming gfortran does work.
fi


# Check that the assembler and linker used by $CXX match $AS and $LD.
# See http://trac.sagemath.org/sage_trac/ticket/14296
if test -n "$AS"; then
    CXX_as=`$CXX -print-file-name=as 2>/dev/null`
    CXX_as=`command -v $CXX_as 2>/dev/null`
    cmd_AS=`command -v $AS`

    if test "$CXX_as" != "" -a "$CXX_as" != "$cmd_AS"; then
        SAGE_SHOULD_INSTALL_GCC([there is a mismatch of assemblers])
        AC_MSG_NOTICE([  $CXX uses $CXX_as])
        AC_MSG_NOTICE([  \$AS equal to $AS])
    fi
fi
if test -n "$LD"; then
    CXX_ld=`$CXX -print-file-name=ld 2>/dev/null`
    CXX_ld=`command -v $CXX_ld 2>/dev/null`
    cmd_LD=`command -v $LD`

    if test "$CXX_ld" != "" -a "$CXX_ld" != "$cmd_LD"; then
        SAGE_SHOULD_INSTALL_GCC([there is a mismatch of linkers])
        AC_MSG_NOTICE([  $CXX uses $CXX_ld])
        AC_MSG_NOTICE([  \$LD equal to $LD])
    fi
fi


###############################################################################
# Check libraries
###############################################################################

# First check for something that should be in any maths library (sqrt).
AC_LANG(C++)
AC_CHECK_LIB(m,sqrt,[],[
                       AC_MSG_NOTICE([This system has no maths library installed.])
                       # On AIX this is not installed by default - strange as that might seem.
                       # but is in a fileset bos.adt.libm. However, the fileset bos.adt
                       # includes other things that are probably useful.
                       if test "x`uname`" = 'xAIX'
                       then
                          AC_MSG_NOTICE([On AIX, libm is contained in the bos.adt.libm fileset.])
                          AC_MSG_NOTICE([Actually, we recommend to install the complete bos.adt fileset.])
                          AC_MSG_NOTICE([This needs to be performed by a system administrator.])
                       fi
                       AC_MSG_ERROR([Exiting, since a maths library was not found.])
                       ])

# Check for system services

# Check that we are not building in a directory containing spaces
AS_IF([echo "$ac_pwd" |grep " " >/dev/null],
      AC_MSG_ERROR([the path to the Sage root directory ($ac_pwd) contains a space. Sage will not build correctly in this case])
)


if test x`uname` = xDarwin; then
[
    # Warning: xcodebuild does not seem to be maintained in Xcode 4.3
    # or later, so do not rely on the variable XCODE_VERS with OS X
    # 10.7 or later.
    XCODE_VERS=`xcodebuild -version 2> /dev/null | grep Xcode | sed -e 's/[A-Za-z ]//g'`
    if [ -z $XCODE_VERS ]; then
        XCODE_VERS="2"
    fi
    XCODE_VERS_MAJOR=`echo $XCODE_VERS | cut '-d.' -f1`
    DARWIN_VERSION=`uname -r | cut '-d.' -f1`
    echo "***************************************************"
    echo "***************************************************"
    if [ $DARWIN_VERSION -gt 10 ]; then
        echo "You are using OS X Lion (or later)."
        echo "You are strongly advised to install Apple's latest Xcode"
        echo "unless you already have it. You can install this using"
        echo "the App Store. Also, make sure you install Xcode's"
        echo "Command Line Tools -- see Sage's README.txt."
    elif [ $XCODE_VERS_MAJOR -gt 2 ]; then
        echo "You are using Xcode version $XCODE_VERS."
        echo "You are strongly advised to install Apple's latest Xcode"
        echo "unless you already have it. You can download this from"
        echo "http://developer.apple.com/downloads/."
        echo "If using Xcode 4.3 or later, make sure you install Xcode's"
        echo "Command Line Tools -- see Sage's README.txt."
    else
        echo "You are using Xcode version 1 or 2"
        echo "WARNING: You are strongly advised to install the"
        echo "latest version of Apple's Xcode for your platform,"
        echo "unless you already have it."
        if [ $DARWIN_VERSION -eq 10 ]; then
           echo "Probably you need Xcode 3.2.6"
        elif [ $DARWIN_VERSION -eq 9 ]; then
           echo "Probably you need Xcode 3.1.4"
        elif [ $DARWIN_VERSION -lt 9 ]; then
           echo "Probably you need Xcode 2.5"
        fi
    fi
]

###########################################################################
# (OS X only)
# Sage will probably not build at all if either Fink or MacPorts can be
# found, and the error messages can be extremely confusing.  Even if it does
# build, the product will probably be wrong.  This runs a basic check to
# find them. Once the Sage build process is perfected, this won't be necessary.
# dphilp 15/9/2008
###########################################################################
    PORTS_PATH=`which port`
    if test -f "$PORTS_PATH"; then
AC_MSG_ERROR([["found MacPorts in $PORTS_PATH. Either:
(1) rename /opt/local and /sw, or
(2) change PATH and DYLD_LIBRARY_PATH
(Once Sage is built, you can restore them.)]])
    fi

    FINK_PATH=`which fink`
    if test -f "$FINK_PATH"; then
AC_MSG_ERROR([["found Fink in $FINK_PATH. Either:
(1) rename /opt/local and /sw, or
(2) change PATH and DYLD_LIBRARY_PATH
(Once Sage is built, you can restore them.)]])
    fi
fi

# if GCC needs to be installed GFORTRAN shouldn't be installed.
# if GCC is already installed GFORTRAN shouldn't be installed either.
# GCC will provide GFORTRAN in both cases.
if test x$need_to_install_gcc = xyes -o x$SAGE_INSTALL_GCC = xexists ; then
    need_to_install_gfortran=no
fi

###############################################################################
# Collect substitutions for build/make/Makefile.in
###############################################################################

# Python version
AC_MSG_CHECKING([Python version to install])
AC_ARG_WITH([python],
[AS_HELP_STRING([--with-python=2],
    [build and use Python 2 (default)])]
[AS_HELP_STRING([--with-python=3],
    [build and use Python 3])])

case "$with_python" in
    2*) SAGE_PYTHON_VERSION=2;;
    3*) SAGE_PYTHON_VERSION=3;;
    "") SAGE_PYTHON_VERSION=2;;
    *)
        AC_MSG_ERROR([allowed values for --with-python are 2 and 3]);;
esac

AC_MSG_RESULT([$SAGE_PYTHON_VERSION])
AC_SUBST(SAGE_PYTHON_VERSION)


# Sage MP library
AC_MSG_CHECKING([multiprecision library])
AC_ARG_WITH([mp],
[AS_HELP_STRING([--with-mp=mpir],
    [use MPIR as multiprecision library (default)])]
[AS_HELP_STRING([--with-mp=gmp],
    [use GMP as multiprecision library])])

case "$with_mp" in
    MPIR|mpir) with_mp=MPIR;;
    GMP|gmp) with_mp=GMP;;
    "") with_mp=${SAGE_MP_LIBRARY:-MPIR};;
    *)
        AC_MSG_ERROR([allowed values for --with-mp are MPIR and GMP]) ;;
esac

AC_MSG_RESULT([$with_mp])

if test $with_mp = MPIR; then
    AC_SUBST([SAGE_MP_LIBRARY], [mpir])
else
    AC_SUBST([SAGE_MP_LIBRARY], [gmp])
fi

# BLAS library
AC_MSG_CHECKING([BLAS library])
AC_ARG_WITH([blas],
[AS_HELP_STRING([--with-blas=openblas],
    [use OpenBLAS as BLAS library (default)])]
[AS_HELP_STRING([--with-blas=atlas],
    [use ATLAS as BLAS library])],,
    [with_blas=openblas]  # default
)

case "$with_blas" in
    openblas) true;;
    atlas) need_to_install_openblas=no;;
    *) AC_MSG_ERROR([allowed values for --with-blas are 'atlas' and 'openblas']);;
esac

AC_MSG_RESULT([$with_blas])
AC_SUBST([SAGE_BLAS], [$with_blas])

# $(TOOLCHAIN) variable containing prerequisites for the build
SAGE_TOOLCHAIN=gcc
if test "$SAGE_INSTALL_CCACHE" = yes ; then
    SAGE_TOOLCHAIN="$SAGE_TOOLCHAIN ccache"
fi
AC_SUBST([SAGE_TOOLCHAIN])

SAGE_SPKG_COLLECT()

# We need sage-env-config to exist before running this.
# TODO: fix this in Trac #21524
touch "$SAGE_SRC/bin/sage-env-config"

SAGE_SCRIPTS='\
'
for file in "$SAGE_SRC/bin/"*; do
    # Skip files with ".in" extension
    ext=${file##*.}
    if test "$ext" != in; then
        SAGE_SCRIPTS+="    \$(SAGE_LOCAL)${file#$SAGE_SRC} \\"$'\n'
    fi
done

AC_SUBST([SAGE_SCRIPTS])

SAGE_EXTCODE='\
'
for file in `find "$SAGE_SRC"/ext -type f`; do
    SAGE_EXTCODE+="    \$(SAGE_EXTCODE)${file#$SAGE_SRC/ext} \\"$'\n'
done

AC_SUBST([SAGE_EXTCODE])

SAGE_MAKE_DEPS="$SAGE_ROOT/build/make/deps"
AC_SUBST_FILE([SAGE_MAKE_DEPS])


dnl AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([build/make/Makefile-auto build/make/Makefile src/Makefile])
AC_CONFIG_FILES([src/bin/sage-env-config])

dnl Create basic directories needed for Sage
AC_CONFIG_COMMANDS(mkdirs,
    [
        for d in "$SAGE_LOGS" "$SAGE_LOCAL" \
            "$SAGE_LOCAL/bin" "$SAGE_LOCAL/etc" \
            "$SAGE_LOCAL/include" "$SAGE_LOCAL/lib" \
            "$SAGE_SHARE" "$SAGE_INST"; do
                AC_MSG_NOTICE([creating directory $d])
                mkdir -p "$d" || AC_MSG_ERROR(could not create $d)
        done

        if test -d "$SAGE_LOCAL/lib64"; then
            if test ! -L "$SAGE_LOCAL/lib64"; then
                AC_MSG_NOTICE([[$SAGE_LOCAL/lib64 is not a symlink, see Trac #19782]])
                AC_MSG_ERROR([[Cannot perform incremental update, run "make distclean && make"]])
            fi
        else
            AC_MSG_NOTICE([[creating symbolic link lib64 -> lib]])
            ln -s lib "$SAGE_LOCAL/lib64"
        fi
    ],
    [
        SAGE_LOGS="$SAGE_ROOT/logs/pkgs"
        SAGE_LOCAL="$SAGE_LOCAL"
        SAGE_SHARE="$SAGE_LOCAL/share"
        SAGE_INST="$SAGE_SPKG_INST"
    ])

AC_OUTPUT()

dnl vim:syntax=m4