/
xstructural8-web-multi.xsl
181 lines (148 loc) · 6.56 KB
/
xstructural8-web-multi.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
<?xml version="1.0" encoding="UTF-8" ?>
<!--
Copyright © 2021 Mark Raynsford <code@io7m.com> https://www.io7m.com
Permission to use, copy, modify, and/or distribute this software for any
purpose with or without fee is hereby granted, provided that the above
copyright notice and this permission notice appear in all copies.
THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR
IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xsd="http://www.w3.org/2001/XMLSchema"
xmlns:xdoc="http://www.pnp-software.com/XSLTdoc"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:s="urn:com.io7m.structural:8:0"
xmlns="http://www.w3.org/1999/xhtml"
exclude-result-prefixes="#all"
version="2.0">
<xsl:import href="xstructural8-links.xsl"/>
<xsl:import href="xstructural8-branding.xsl"/>
<xsl:import href="xstructural8-navigation.xsl"/>
<xsl:import href="xstructural8-outputs.xsl"/>
<xsl:import href="xstructural8-blocks-web-multi.xsl"/>
<xsl:template match="@*|node()">
<xsl:message terminate="yes"
select="concat('Unexpectedly reached catch-all template: ', namespace-uri(.), ':', node-name(.))"/>
</xsl:template>
<xsl:template match="comment()"/>
<!-- -->
<!-- Top-level web multi templates. -->
<!-- -->
<xsl:template name="xstructural.fileOf"
as="xsd:string">
<xsl:param name="target"
as="element()"/>
<xsl:variable name="targetOwner"
as="element()">
<xsl:choose>
<xsl:when test="count($target/ancestor-or-self::s:Section) > 0">
<xsl:sequence select="$target/ancestor-or-self::s:Section[1]"/>
</xsl:when>
<xsl:when test="count($target/ancestor-or-self::s:Document) > 0">
<xsl:sequence select="$target/ancestor-or-self::s:Document[1]"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:value-of select="concat(generate-id($targetOwner), '.xhtml')"/>
</xsl:template>
<xdoc:doc>
An override of the anchorOf function that works for multi-page XHTML files.
</xdoc:doc>
<xsl:template name="xstructural.links.anchorOf"
as="xsd:string">
<xsl:param name="target"
as="element()"/>
<xsl:message select="concat('anchorOf: ', local-name($target))"/>
<xsl:variable name="owningFile"
as="xsd:string">
<xsl:choose>
<xsl:when test="$target/ancestor-or-self::s:Section[1]">
<xsl:variable name="owningSection"
as="element()">
<xsl:sequence select="$target/ancestor-or-self::s:Section[1]"/>
</xsl:variable>
<xsl:value-of select="concat(generate-id($owningSection),'.xhtml')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$xstructural.web.indexMulti"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="completeHref">
<xsl:choose>
<xsl:when test="$target/attribute::id">
<xsl:value-of select="concat($owningFile,'#id_',$target/attribute::id[1])"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat($owningFile,'#',generate-id($target))"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:value-of select="$completeHref"/>
</xsl:template>
<xsl:template match="s:Document">
<xsl:message select="concat('Processing document ', generate-id(.))"/>
<xsl:variable name="file"
as="xsd:string"
select="concat($xstructural.outputDirectory,'/index-m.xhtml')"/>
<xsl:message select="concat('create ', $file)"/>
<xsl:result-document href="{$file}"
doctype-public="-//W3C//DTD XHTML 1.1//EN"
doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd"
exclude-result-prefixes="#all"
method="xhtml"
include-content-type="no"
indent="true">
<xsl:text>
</xsl:text>
<html xml:lang="en">
<head>
<meta name="generator"
content="${project.groupId}/${project.version}"/>
<link rel="stylesheet"
type="text/css"
href="reset.css"/>
<link rel="stylesheet"
type="text/css"
href="structural.css"/>
<link rel="stylesheet"
type="text/css"
href="document.css"/>
<xsl:apply-templates select="s:Metadata"
mode="xstructural.metadata.header"/>
<title>
<xsl:value-of select="s:Metadata/dc:title"/>
</title>
</head>
<body>
<xsl:apply-templates select="s:Metadata/*"
mode="xstructural.web.branding.header"/>
<xsl:apply-templates select="."
mode="xstructural.navigation.header"/>
<div class="stMain">
<xsl:apply-templates select="."
mode="xstructural.titleElement"/>
<xsl:apply-templates select="s:Metadata"
mode="xstructural.metadata.table"/>
<xsl:apply-templates select="."
mode="xstructural.tableOfContentsOptional">
<xsl:with-param name="withTitle"
select="true()"/>
</xsl:apply-templates>
<xsl:apply-templates select="s:Section|s:Subsection|s:Paragraph|s:FormalItem"
mode="xstructural.blocks"/>
<xsl:call-template name="xstructural.blocks.footnotesOptional"/>
</div>
<xsl:apply-templates select="."
mode="xstructural.navigation.footer"/>
<xsl:apply-templates select="s:Metadata/*"
mode="xstructural.web.branding.footer"/>
</body>
</html>
</xsl:result-document>
</xsl:template>
</xsl:stylesheet>