/
SourceMap.pro
47 lines (39 loc) · 1.7 KB
/
SourceMap.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Twofold-Qt
# (C) Copyright 2014 HicknHack Software GmbH
#
# The original code can be found at:
# https://github.com/hicknhack-software/Twofold-Qt
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
TEMPLATE = aux
include(../build/qmake/_common.pri)
TARGET_NAME = SourceMap
win32:!win32-g++: TARGET = SourceMap.lib
else: TARGET = libSourceMap.a
CONFIG(debug, debug|release): QMAKE_OPTIONS += CONFIG+=debug
else: QMAKE_OPTIONS += CONFIG+=release
QMAKE_OPTIONS += CONFIG+=NoTest
QMAKE_OPTIONS += INSTALL_PREFIX=$$SOURCEMAP_LIB
QMAKE_OPTIONS += INSTALL_HEADERS_PREFIX=$$SOURCEMAP_INCLUDES
QMAKE_OPTIONS += $$PWD/SourceMap
makeBuildFolder.commands = $$QMAKE_MKDIR $$TARGET_NAME || echo.
makeBuildFolder.target = $$TARGET_NAME
prepareBuild.commands = cd $$TARGET_NAME && $$QMAKE_QMAKE $$QMAKE_OPTIONS
prepareBuild.target = $$TARGET_NAME/Makefile
buildInstall.commands = cd $$TARGET_NAME && $(MAKE) clean install
buildInstall.target = $$SOURCEMAP_LIB/$$TARGET
compiler_clean.commands = -$(DEL_FILE) $$shell_path($$TARGET_NAME/Makefile)
prepareBuild.depends = makeBuildFolder
buildInstall.depends = prepareBuild
install.depends = $(DESTDIR_TARGET) $(TARGET)
QMAKE_EXTRA_TARGETS += makeBuildFolder prepareBuild buildInstall install compiler_clean