Add Visible bookmarks (bm.el) in Emacs Dashboard

[jeff-phil]

Requires package Visible Bookmarks (bm) is installed.

Add this to the :config section for dashboard's use-package:

  (defun my/show-bm-dash-action ()
    (interactive)
    (let ((file (get-text-property (point) 'file))
          (position (get-text-property (point) 'position)))
      (if (not file)
          (message "No bookmark at this line."))
      (let ((buffer (find-file-noselect file)))
        (with-current-buffer buffer
          (pop-to-buffer buffer)
          (goto-char position)))))

  (defun my/dashboard-insert-bm (list-size)
    (let ((bms '()))
      ;; Ensure we're fresh and synced by save and then load fresh, suppressing messages
      (cl-letf (((symbol-function 'message) #'ignore))
        (bm-buffer-save-all)
        (bm-repository-save)
        (bm-repository-load))
      (cl-loop for entry in bm-repository
               do
               (let* ((file (car entry))
                      (filename (f-filename file))
                      (buffer-data (assoc file bm-repository))
                      (bookmarks (cdr (assoc 'bookmarks buffer-data)))
                      (new-keymap (make-sparse-keymap "+my/dashboard-actions")))
                 (keymap-set new-keymap "RET" #'my/show-bm-dash-action)
                 (keymap-set new-keymap "<mouse-1>" #'my/show-bm-dash-action)
                 (cl-loop for bookmark in bookmarks
                          do
                          (let* ((pos (cdr (assoc 'position bookmark)))
                                 (time (cdr (assoc 'time bookmark)))
                                 (annotation (cdr (assoc 'annotation bookmark)))
                                 (context-string
                                  (concat (cdr (assoc 'before-context-string bookmark))
                                          (cdr (assoc 'after-context-string bookmark))))
                                 (line
                                  (propertize
                                   (concat
                                    (dashboard-icon-for-file filename)
                                    (format " %-25s %-15s %s"
                                            (format "%s:%s"
                                                    (propertize filename 'face
                                                                'dashboard-items-face)
                                                    pos)
                                            (s-left 15 (or annotation ""))
                                            (replace-regexp-in-string
                                             "\n" " " context-string)))
                                   'mouse-face 'highlight
                                   'help-echo "Jump to bookmark"))
                                 (start 0)
                                 (end (length line)))
                            (add-text-properties start end `(keymap ,new-keymap
                                                                    file ,file
                                                                    position ,pos)
                                                 line)
                            (push (cons time line) bms)))))
      (let ((section-name "BM's:")
            (shortcut "b")
            (icon (all-the-icons-faicon
                   "bookmark-o" :height 1.2 :v-adjust 0.0 :face 'dashboard-heading)))
        (if (= (length bms) 0)
            (progn
              ;; Empty section, so no shortcut needed
              (keymap-unset dashboard-mode-map "b")
              (dashboard-insert-shortcut 'bm "" nil)
              (dashboard-insert-heading section-name nil icon)
              (insert "\n    "
                      (propertize "--- No items ---" 'face 'dashboard-no-items-face)))
          (let* ((size (min list-size (length bms)))
                 (sorted (sort bms (lambda (a b) (time-less-p (car b) (car a))))))
            (dashboard-insert-shortcut 'bm "b" "BM's")
            (dashboard-insert-heading section-name shortcut icon)
            (insert "\n    " (mapconcat 'cdr (cl-subseq sorted 0 size) "\n    ")))))))

  (when (featurep 'bm)
    (add-to-list 'dashboard-item-generators  '(bm . my/dashboard-insert-bm))
    (dashboard-modify-heading-icons '((bm . "bookmark-o"))))

  (setq dashboard-items (if (featurep 'bm)
                            '((projects . 5)
                              (recents  . 10)
                              (bm . 10)
                              (bookmarks . 5)
                              (agenda . 5)
                              (registers . 5))
                          '((projects . 5)
                            (recents  . 10)
                            (bookmarks . 5)
                            (agenda . 5)
                            (registers . 5))))

BM's section will show up on the Emacs Dashboard similar to:

b to get to the BM's section, and can jump to each bm location with mouse click or hitting RET on the line.

Note: The bm bookmarks are different than the emacs bookmark built-in package bookmarks.

[ricardoricho]

Hi @jeff-phil great work. For me, it could be a package emacs-dashboard/dashboard-bm, this code could be the initial commit and we adjust it. What do you think @jcs090218 ?

[jcs090218]

Sorry for the late reply. We generally try to keep the core dashboard small so we can keep up our load time fast.

Hi @jeff-phil great work. For me, it could be a package emacs-dashboard/dashboard-bm, this code could be the initial commit and we adjust it. What do you think @jcs090218 ?

I agree, that's a good approach. :)

[ricardoricho]

I created dashboard-bm
@jcs090218 Would you please create the README, license, and Eask files?

@jeff-phil Feel free to create your PR and close this discussion.

[jcs090218]

@ricardoricho Thank you!

@jeff-phil I have added everything you need for elisp package development. Feel free to change anything you like, including the license, etc. I've also added this package to JCS-ELPA so you can install and test it immediately. You can consider adding this package to MELPA as well.

[jeff-phil]

Wow, you all move fast! 🏎️💨 Thank you @ricardoricho and @jcs090218!

[jcs090218]

I've added your as the project's collaborator! :)