Plug-in specific xsl:message has been changed in 4.2

[ToshihikoMakita]

Last day I've noticed that my PDF plug-in specific message submitted via xsl:message has been changed when I update DITA-OT from 4.1.2 to 4.2.
DITA-OT 4.1.2
[xslt] [WARNING][General 001W] No template is defined for this element. element=indexterm file=file:/C:/Users/Toshihiko%20Makita/OneDrive%20-%20アンテナハウス株式会社/ドキュメント/User/acme/sample-data/Rxx_jigyo/basedesign/pg-x/topics/ジョブ.dita
DITA-OT 4.2
[WARNING] No template is defined for this element. element=indexterm file=file:/C:/Users/Toshihiko%20Makita/OneDrive%20-%20アンテナハウス株式会社/ドキュメント/User/acme/sample-data/Rxx_jigyo/basedesign/pg-x/topics/ジョブ.dita

The word "[General 001W]" means related template name and message number. It is indispensable for stylesheet developers to debug XSLT stylesheet.
How to avoid this message modification in DITA-OT 4.2?

[jelovirt]

You can either use a custom logger or then it may be a bug in the code.

See https://github.com/orgs/dita-ot/discussions/4340 for related discussion.

[jelovirt]

The root cause for this change is https://github.com/dita-ot/dita-ot/blob/develop/src/main/java/org/dita/dost/log/AbstractLogger.java#L273 that assumes the order of ID and level. I should fix this to only strip the level if the text matches the known level names like ERROR or WARN

[jelovirt]

Could you share exactly what XSLT you use to throw that message?

[ToshihikoMakita]

Here are all of the XSLT templates and functions used to output.

    <xsl:variable name="stMes001" as="xs:string">
        <xsl:text>[General 001W] No template is defined for this element. element=%elem file=%file</xsl:text>
    </xsl:variable>

    <!-- 
     function:	General template for debug
     param:	    
     return:	debug message
     note:		
     -->
    <xsl:template match="*" priority="-5">
        <xsl:call-template name="warningContinue">
            <xsl:with-param name="prmMes"
             select="ahf:replace($stMes001,('%elem','%file'),(name(.),string(@xtrf)))"/>
        </xsl:call-template>
        <xsl:apply-templates/>
    </xsl:template>

    <!-- Error message prefixes -->
    <xsl:variable name="fatalErrorPrefixStr" as="xs:string" select="'[FATAL ERROR]'"/>
    <xsl:variable name="errorPrefixStr" as="xs:string" select="'[ERROR]'"/>
    <xsl:variable name="warningPrefixStr" as="xs:string" select="'[WARNING]'"/>

    <!-- 
     function:  Warning display routine
     param:     prmMes: message body
     return:    none
     note:      none
    -->
    <xsl:template name="warningContinue">
    	<xsl:param name="prmMes" required="yes" as="xs:string"/>
        <xsl:message terminate="no" select="concat($warningPrefixStr,$prmMes)"/>
    </xsl:template>

    <!--
        function: Multiple replace function
        param: prmStr,prmSrc,prmDst
        note: Result string
    -->
    <xsl:function name="ahf:replace" as="xs:string">
        <xsl:param name="prmStr" as="xs:string"/>
        <xsl:param name="prmSrc" as="xs:string+"/>
        <xsl:param name="prmDst" as="xs:string+"/>
    
        <xsl:variable name="firstResult" select="ahf:safeReplace($prmStr,$prmSrc[1],$prmDst[1])" as="xs:string"/>
        <xsl:choose>
            <xsl:when test="exists($prmSrc[2]) and exists($prmDst[2])">
                <xsl:sequence select="ahf:replace($firstResult,subsequence($prmSrc,2),subsequence($prmDst,2))"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:sequence select="$firstResult"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:function>

    <!--
        function: Safe replace function
        param: prmStr,prmSrc,prmDst
        note: Result string
    -->
    <xsl:function name="ahf:safeReplace" as="xs:string">
        <xsl:param name="prmStr" as="xs:string"/>
        <xsl:param name="prmSrc" as="xs:string"/>
        <xsl:param name="prmDst" as="xs:string"/>
        <xsl:sequence select="replace($prmStr,ahf:escapeForRegxSrc($prmSrc),ahf:escapeForRegxDst($prmDst))"/>
    </xsl:function>

    <!--
     function: escapeForRegx
     param:    prmSrcString
     return:   Escaped xs:string
     note:     Original code by Priscilla Walmsley.
               http://www.xsltfunctions.com/xsl/functx_escape-for-regex.html
    -->
    <xsl:function name="ahf:escapeForRegxDst" as="xs:string">
        <xsl:param name="prmSrcString" as="xs:string"/>
        <xsl:sequence select="replace($prmSrcString,'(\\|\$)','\\$1')"/>
    </xsl:function>
    
    <xsl:function name="ahf:escapeForRegxSrc" as="xs:string">
        <xsl:param name="prmSrcString" as="xs:string"/>
        <xsl:sequence select="replace($prmSrcString,'(\.|\[|\]|\\|\||\-|\^|\$|\?|\*|\+|\{|\}|\(|\))','\\$1')"/>
    </xsl:function>

[jelovirt]

Try to change the log message prefix from [WARNING][General 001W] to [General 001W][WARNING] or better yet [General 001W][WARN] because WARN is the supported logging level in our loggers, not WARNING. I think that will fix your issue for now, before we release #4416 in 4.2.1.

In addition, if you're using plain <xsl:message> to log messages, you should use

<xsl:processing-instruction name="error-code" select="'General 001W'"/>
<xsl:processing-instruction name="level" select="'WARN'"/>

In the message body. These are processing-instructions that DITA-OT's logging code from XSLT uses to pass the error code and logging level.