STM32 SleepMethod

[dani68k]

Hello everyone!
I'm trying to add sleep method on a STM32L476RG NUCLEO that I'm working on, using PlatformIO and Arduino framework.

1. I could make a simple example of blink with the LowPower.h to check LowPower and it is working:

#include <Arduino.h>
#include "STM32LowPower.h"

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  // Configure low power
  LowPower.begin();
}

void loop() {
  digitalWrite(LED_BUILTIN, HIGH);
  LowPower.sleep(5000);
  digitalWrite(LED_BUILTIN, LOW);
  LowPower.sleep(5000);
}

2. Then I make a simple example of blink with TaskScheduler and works too:

#include <Arduino.h>
// #define _TASK_SLEEP_ON_IDLE_RUN
#include <TaskScheduler.h>
#include <STM32LowPower.h>

Scheduler ts;

void BlinkLED();

// Tasks
Task blink(2000, TASK_FOREVER, &BlinkLED);

void setup() {

  // put your setup code here, to run once:
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
#if defined (ARDUINO_NUCLEO_L476RG)  
  Serial.println("NUCLEO STM32L476RG!");
  Serial.flush();
#endif
  ts.addTask(blink);
  blink.enable();
  LowPower.begin();
}

void BlinkLED() {
  static bool state;
  digitalWrite(LED_BUILTIN, state);
  state = !state;
}


void loop() {
  ts.execute();
}

3. Then I added this lines into TaskSchedulerSleepMethods.h

#elif defined(ARDUINO_NUCLEO_L476RG) 

#include <STM32LowPower.h>

void SleepMethod(unsigned long aDuration ) {
    LowPower.sleep(1);
}

and main program:

#include <Arduino.h>
#define _TASK_SLEEP_ON_IDLE_RUN
#include <TaskScheduler.h>
#include <STM32LowPower.h>

Scheduler ts;

void BlinkLED();

// Tasks
Task blink(2000, TASK_FOREVER, &BlinkLED);

void setup() {

  // put your setup code here, to run once:
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
#if defined (ARDUINO_NUCLEO_L476RG)  
  Serial.println("NUCLEO STM32L476RG!");
  Serial.flush();
#endif
  ts.addTask(blink);
  blink.enable();
  LowPower.begin();
}

void BlinkLED() {
  static bool state;
  digitalWrite(LED_BUILTIN, state);
  state = !state;
}


void loop() {
  ts.execute();
}

But it seems the CPU goes to sleep but never wake up... I've been diving into the code but i could not find any clue why CPU doesn't wake up. I missing something definitely.

Any suggestions??

Thank you.
Best regards,
daniel

[arkhipenko]

Hi @dani68k
You do not need to modify TaskSchedulerSleepMethods.h

here is a quick way how I did it. You should be able to do the same.

void setupTS() {
  Log.trace("setupTS()" CR);

  ts.setSleepMethod( &nrf52sleep );
  enableSleep();
}

void enableSleep() {
  Log.trace("enableSleep()" CR);
  
  ts.allowSleep(true);
}

void nrf52sleep( unsigned long aDuration ) {
   // Log.trace("nrf52sleep()" CR);

  // there was some other processing here
 
  sleep();   // this is what puts chip to sleep - your implementation
}

STM32 sleep (or rather many quick naps) is already implemented. but it seems you want a longer sleep method than wfi

#elif defined( ARDUINO_ARCH_STM32F1 )

#include <libmaple/pwr.h>
#include <libmaple/scb.h>

void SleepMethod( unsigned long aDuration ) {
	  // Now go into stop mode, wake up on interrupt.
	  // Systick interrupt will run every 1 milliseconds.
	  asm("    wfi");
}
// ARDUINO_ARCH_STM32

Also, please make sure there is something (like a timer interrupt) that wakes stm32 up - TS does not control that aspect.

And the last thing - a new version (still in testing) can report how much time is left until next task has to run - you can use that for sleeping longer.
Check here:
https://github.com/arkhipenko/TaskScheduler/tree/testing/examples/Scheduler_example28_Tickless

Hope it helps.

[dani68k]

Hi @arkhipenko,

Ok, thank you for your fast reply.
I will check your suggested code, and try to get more information from your link.
I may want to change the tick time to longer one so I can profit long sleeps. As you guessed I want long sleeps because my tasks runs over tens of seconds, even in minutes, so 1ms tick can be so short.

Thank you again and congratulations for the TaskScheduler library. :)

Regards.
daniel

[arkhipenko]

If you need longer sleeps, you definitely want to try the tickles mode.

[dani68k]

Ok. I will go further on tickless. :)
Thank you.
BR,
daniel

[Nacapak]

Hello @dani68k,

I'm trying to get in touch with you because I'm very interested in discussing your experience using the AS3933 device. Could you please provide me with a contact method? Thank you!