/
CMakeLists.txt
executable file
·192 lines (176 loc) · 5.54 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
# CMake version < 3.14, could not use option BUILD_DEPENDENCIES
cmake_minimum_required(VERSION 3.10)
project(trantor)
add_library(${PROJECT_NAME})
# C++ standard
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_STANDARD 14)
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_STANDARD_REQUIRED ON)
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_EXTENSIONS OFF)
# Build options
option(BUILD_SHARED_LIBS "Build Trantor as a shared lib" OFF)
option(BUILD_TESTING "Build tests" OFF)
option(BUILD_DOC "Build Doxygen documentation" OFF)
option(BUILD_DEPENDENCIES "Fetch and build dependencies" OFF)
option(TRANTOR_USE_SPDLOG "Allow using the spdlog logging library" ON)
option(TRANTOR_USE_C-ARES "Allow using C-ARES" ON)
set(TRANTOR_TLS_PROVIDER
"auto"
CACHE STRING "TLS(Transport Layer Security) provider for trantor. Valid options are
'none', 'openssl', 'botan-3', 'auto'."
)
# Version
set(TRANTOR_MAJOR_VERSION 1)
set(TRANTOR_MINOR_VERSION 5)
set(TRANTOR_PATCH_VERSION 17)
set(TRANTOR_VERSION ${TRANTOR_MAJOR_VERSION}.${TRANTOR_MINOR_VERSION}.${TRANTOR_PATCH_VERSION})
if(BUILD_SHARED_LIBS)
set_target_properties(
${PROJECT_NAME}
PROPERTIES VERSION
${TRANTOR_VERSION}
SOVERSION
${TRANTOR_MAJOR_VERSION}
)
endif()
# CMake modules
list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake_modules/)
# Common settings
include(cmake/SetBuildOutput.cmake)
include(cmake/SetSystemAndCompiler.cmake)
include(cmake/SetThreads.cmake)
include(cmake/TestAtomic.cmake)
# Sources and headers
set(TRANTOR_SOURCES
# cmake-format: sortable
trantor/net/Channel.cc
trantor/net/EventLoop.cc
trantor/net/EventLoopThread.cc
trantor/net/EventLoopThreadPool.cc
trantor/net/InetAddress.cc
trantor/net/inner/Acceptor.cc
trantor/net/inner/AsyncStreamBufferNode.cc
trantor/net/inner/Connector.cc
trantor/net/inner/MemBufferNode.cc
trantor/net/inner/Poller.cc
trantor/net/inner/poller/EpollPoller.cc
trantor/net/inner/poller/KQueue.cc
trantor/net/inner/poller/PollPoller.cc
trantor/net/inner/Socket.cc
trantor/net/inner/StreamBufferNode.cc
trantor/net/inner/TcpConnectionImpl.cc
trantor/net/inner/Timer.cc
trantor/net/inner/TimerQueue.cc
trantor/net/TcpClient.cc
trantor/net/TcpServer.cc
trantor/utils/AsyncFileLogger.cc
trantor/utils/ConcurrentTaskQueue.cc
trantor/utils/Date.cc
trantor/utils/Logger.cc
trantor/utils/LogStream.cc
trantor/utils/MsgBuffer.cc
trantor/utils/SerialTaskQueue.cc
trantor/utils/TimingWheel.cc
trantor/utils/Utilities.cc
)
set(PRIVATE_HEADERS
# cmake-format: sortable
trantor/net/inner/Acceptor.h
trantor/net/inner/Connector.h
trantor/net/inner/Poller.h
trantor/net/inner/poller/EpollPoller.h
trantor/net/inner/poller/KQueue.h
trantor/net/inner/poller/PollPoller.h
trantor/net/inner/Socket.h
trantor/net/inner/TcpConnectionImpl.h
trantor/net/inner/Timer.h
trantor/net/inner/TimerQueue.h
)
if(WIN32)
list(
APPEND
TRANTOR_SOURCES
# cmake-format: sortable
third_party/wepoll/Wepoll.c
trantor/utils/WindowsSupport.cc
trantor/net/inner/FileBufferNodeWin.cc
)
list(
APPEND
PRIVATE_HEADERS
# cmake-format: sortable
third_party/wepoll/Wepoll.h
trantor/utils/WindowsSupport.h
)
else()
list(APPEND TRANTOR_SOURCES trantor/net/inner/FileBufferNodeUnix.cc)
endif()
set(PUBLIC_NET_HEADERS
# cmake-format: sortable
trantor/net/AsyncStream.h
trantor/net/callbacks.h
trantor/net/Certificate.h
trantor/net/Channel.h
trantor/net/EventLoop.h
trantor/net/EventLoopThread.h
trantor/net/EventLoopThreadPool.h
trantor/net/InetAddress.h
trantor/net/Resolver.h
trantor/net/TcpClient.h
trantor/net/TcpConnection.h
trantor/net/TcpServer.h
trantor/net/TLSPolicy.h
)
set(PUBLIC_UTILS_HEADERS
# cmake-format: sortable
trantor/utils/AsyncFileLogger.h
trantor/utils/ConcurrentTaskQueue.h
trantor/utils/Date.h
trantor/utils/Funcs.h
trantor/utils/LockFreeQueue.h
trantor/utils/Logger.h
trantor/utils/LogStream.h
trantor/utils/MsgBuffer.h
trantor/utils/NonCopyable.h
trantor/utils/ObjectPool.h
trantor/utils/SerialTaskQueue.h
trantor/utils/TaskQueue.h
trantor/utils/TimingWheel.h
trantor/utils/Utilities.h
)
# Build Dependencies
include(cmake/SetInstallDirs.cmake)
include(cmake/BuildDependencies.cmake)
# Set options
include(cmake/SetCAres.cmake)
include(cmake/SetSpdlog.cmake)
include(cmake/SetTlsProvider.cmake)
include(cmake/SetTesting.cmake)
# Export header
include(cmake/SetExportHeader.cmake)
# Group sources
source_group("Public API" FILES ${PUBLIC_NET_HEADERS} ${PUBLIC_UTILS_HEADERS} ${TRANTOR_EXPORT_HEADER})
source_group("Private Headers" FILES ${PRIVATE_HEADERS})
# Target sources
target_sources(
${PROJECT_NAME}
PRIVATE ${TRANTOR_SOURCES}
${PRIVATE_HEADERS}
${PUBLIC_NET_HEADERS}
${PUBLIC_UTILS_HEADERS}
${TRANTOR_EXPORT_HEADER}
)
# Target include directories
target_include_directories(
${PROJECT_NAME}
PUBLIC $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}> $<INSTALL_INTERFACE:${INSTALL_INCLUDE_DIR}>
$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/exports>
PRIVATE ${PROJECT_SOURCE_DIR}
${PROJECT_SOURCE_DIR}/trantor/utils
${PROJECT_SOURCE_DIR}/trantor/net
${PROJECT_SOURCE_DIR}/trantor/net/inner
$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/third_party/wepoll>
)
# Set additional
include(cmake/SetDoxygen.cmake)
include(cmake/SetPackageConfig.cmake)
include(cmake/SetInstall.cmake)