terraform_azure.tf

# This script is based on this base script from the Azure docs:
# https://docs.microsoft.com/en-us/azure/developer/terraform/create-linux-virtual-machine-with-infrastructure

# Configure the Microsoft Azure Provider
terraform {
  required_providers {
    azurerm = {
      source = "hashicorp/azurerm"
      version = "~>2.0"
    }
  }
}
provider "azurerm" {
  features {}
}

variable "rsa_key_location" {
    type        = string
    description = "Path to your private SSH key"
    default     = "~/.ssh/id_rsa"
}

# Create a resource group if it doesn't exist
resource "azurerm_resource_group" "montithingsgroup" {
    name     = "montithingsResourceGroup"
    location = "westeurope"

    tags = {
        environment = "MontiThings"
    }
}

# Create virtual network
resource "azurerm_virtual_network" "montithingsnetwork" {
    name                = "myVnet"
    address_space       = ["10.0.0.0/16"]
    location            = "westeurope"
    resource_group_name = azurerm_resource_group.montithingsgroup.name

    tags = {
        environment = "MontiThings"
    }
}

# Create subnet
resource "azurerm_subnet" "montithingssubnet" {
    name                 = "mySubnet"
    resource_group_name  = azurerm_resource_group.montithingsgroup.name
    virtual_network_name = azurerm_virtual_network.montithingsnetwork.name
    address_prefixes       = ["10.0.1.0/24"]
}

# Create public IPs
resource "azurerm_public_ip" "montithingspublicip" {
    name                         = "myPublicIP"
    location                     = "westeurope"
    resource_group_name          = azurerm_resource_group.montithingsgroup.name
    allocation_method            = "Dynamic"

    tags = {
        environment = "MontiThings"
    }
}

# Create Network Security Group and rule
resource "azurerm_network_security_group" "montithingsnsg" {
    name                = "myNetworkSecurityGroup"
    location            = "westeurope"
    resource_group_name = azurerm_resource_group.montithingsgroup.name

    security_rule {
        name                       = "SSH"
        priority                   = 1001
        direction                  = "Inbound"
        access                     = "Allow"
        protocol                   = "Tcp"
        source_port_range          = "*"
        destination_port_range     = "22"
        source_address_prefix      = "*"
        destination_address_prefix = "*"
    }

    tags = {
        environment = "MontiThings"
    }
}

# Create network interface
resource "azurerm_network_interface" "montithingsnic" {
    name                      = "myNIC"
    location                  = "westeurope"
    resource_group_name       = azurerm_resource_group.montithingsgroup.name

    ip_configuration {
        name                          = "myNicConfiguration"
        subnet_id                     = azurerm_subnet.montithingssubnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.montithingspublicip.id
    }

    tags = {
        environment = "MontiThings"
    }
}

# Connect the security group to the network interface
resource "azurerm_network_interface_security_group_association" "example" {
    network_interface_id      = azurerm_network_interface.montithingsnic.id
    network_security_group_id = azurerm_network_security_group.montithingsnsg.id
}

# Generate random text for a unique storage account name
resource "random_id" "randomId" {
    keepers = {
        # Generate a new ID only when a new resource group is defined
        resource_group = azurerm_resource_group.montithingsgroup.name
    }

    byte_length = 8
}

# Create storage account for boot diagnostics
resource "azurerm_storage_account" "mystorageaccount" {
    name                        = "diag${random_id.randomId.hex}"
    resource_group_name         = azurerm_resource_group.montithingsgroup.name
    location                    = "westeurope"
    account_tier                = "Standard"
    account_replication_type    = "LRS"

    tags = {
        environment = "MontiThings"
    }
}

# Create (and display) an SSH key
resource "tls_private_key" "example_ssh" {
  algorithm = "RSA"
  rsa_bits = 4096
}
output "tls_private_key" { 
    value = tls_private_key.example_ssh.private_key_pem 
    sensitive = true
}

# Create virtual machine
resource "azurerm_linux_virtual_machine" "montithingsvm" {
    name                  = "montithings"
    location              = "westeurope"
    resource_group_name   = azurerm_resource_group.montithingsgroup.name
    network_interface_ids = [azurerm_network_interface.montithingsnic.id]
    size                  = "Standard_B2s"

    os_disk {
        name              = "myOsDisk"
        caching           = "ReadWrite"
        storage_account_type = "Premium_LRS"
    }

    source_image_reference {
        publisher = "Canonical"
        offer     = "UbuntuServer"
        sku       = "18.04-LTS"
        version   = "latest"
    }

    computer_name  = "montithings"
    admin_username = "azureuser"
    disable_password_authentication = true

    admin_ssh_key {
        username       = "azureuser"
        public_key     = file("${var.rsa_key_location}.pub")
    }

    boot_diagnostics {
        storage_account_uri = azurerm_storage_account.mystorageaccount.primary_blob_endpoint
    }

    provisioner "remote-exec" {
        inline = [
            "git clone https://github.com/monticore/montithings",
            "cd montithings",
            "sudo cp docs/ascii-banner.txt /etc/motd",
            "./installLinux.sh"
        ]

        connection {
            type        = "ssh"
            user        = azurerm_linux_virtual_machine.montithingsvm.admin_username
            private_key = file(var.rsa_key_location)
            host        = azurerm_linux_virtual_machine.montithingsvm.public_ip_address
        }
    }

    tags = {
        environment = "MontiThings"
    }
}

resource "azurerm_container_group" "montithingscontainergroup" {
    name                = "montithings-containers"
    location            = azurerm_resource_group.montithingsgroup.location
    resource_group_name = azurerm_resource_group.montithingsgroup.name
    ip_address_type     = "public"
    os_type             = "Linux"
    dns_name_label      = random_id.randomId.hex

    container {
        name   = "hivemq-broker"
        image  = "hivemq/hivemq-ce"
        cpu    = "0.5"
        memory = "1.5"

        ports {
            port     = 1883
            protocol = "TCP"
        }
    }

    tags = {
        environment = "MontiThings"
    }
}

output "vm_ip_address" {
    value = azurerm_linux_virtual_machine.montithingsvm.public_ip_address
}

output "mqtt_broker_ip_address" {
    value = azurerm_container_group.montithingscontainergroup.ip_address
}