build.gradle

// Credits to UpcraftLP for the base build script

plugins {
    alias(libs.plugins.chenille)
}

group = rootProject.maven_group
archivesBaseName = rootProject.name

allprojects {
    apply plugin: 'maven-publish'
    apply plugin: 'io.github.ladysnake.chenille'

    version = project.mod_version

    chenille {
        license = 'GPL_WITH_MC_EXCEPTION'
        displayName = 'Requiem'
        owners = 'Ladysnake'
    }

    license {
        exclude '**/package-info.java'
    }

    repositories {
        chenille.repositories {
            cotton()
            jamieswhiteshirt()
            cursemaven()
            shedaniel()
            lucko()
            modrinth()
            jitpack()
        }
        maven {
            name = 'Quilt'
            url = 'https://maven.quiltmc.org/repository/snapshot'
        }
        maven { repo ->
            repo.name = "Ladysnake Mods"
            repo.setUrl("https://ladysnake.jfrog.io/artifactory/mods")
            repo.content {
                it.includeGroupByRegex("dev\\.emi.*")
                it.includeGroup("io.github.ladysnake")
                it.includeGroupByRegex("(dev|io\\.github)\\.onyxstudios.*")
                it.includeGroupByRegex("org.quiltmc.*")
            }
        }
        maven {
            url = 'https://maven.willbl.dev/releases'
            content {
                includeGroupByRegex 'com\\.williambl.*'
            }
        }
        maven {
            name = "Appleskin"
            url = "https://maven.ryanliptak.com/"
            content {
                includeGroup 'squeek.appleskin'
            }
        }
        maven {
            url = 'https://maven.cafeteria.dev'
            content {
                includeGroup 'net.adriantodt.fabricmc'
            }
        }
        maven {
            url 'https://maven.blamejared.com'
            content {
                includeGroupByRegex 'vazkii\\..*'
            }
        }
        maven {
            url = "https://maven.theillusivec4.top"
            content {
                includeGroupByRegex 'top\\.theillusivec4\\..*'
            }
        }
        maven {
            url = "https://maven.siphalor.de"
            content {
                includeGroup 'de.siphalor'
            }
        }
        maven {
            name = "TerraformersMC"
            url = "https://maven.terraformersmc.com/releases"
            content {
                includeGroupByRegex 'com.terraformersmc.*'
                includeGroup 'dev.emi'
            }
        }
        mavenLocal()
    }

    processResources {
        inputs.property "version", project.version

        filesMatching("quilt.mod.json") {
            expand "version": project.version
        }
    }

    java {
        withSourcesJar()
    }

    dependencies {
        //to change the versions see the gradle.properties file
        minecraft "com.mojang:minecraft:${project.minecraft_version}"
        mappings "org.quiltmc:quilt-mappings:${minecraft_version}+build.${quilt_mappings}:intermediary-v2"
        modImplementation "org.quiltmc:quilt-loader:${project.loader_version}"
        modImplementation "org.quiltmc:qsl:${qsl_version}+${minecraft_version}"
        modImplementation "org.quiltmc.quilted-fabric-api:quilted-fabric-api:${quilted_fabric_api_version}-${minecraft_version}"

        compileOnly metaLibs.bundles.devAnnotations
    }
}

chenille {
    configureTestmod()
    configurePublishing {
        mainArtifact = remapJar.archiveFile
        withArtifactory()
        withCurseforgeRelease()
        withGithubRelease()
        withModrinthRelease()
    }
}

license {
    exclude '**/model/lib/**.java'
    exclude '**/RayHelper.java'
}

dependencies {
    // Looking for version definitions? see https://docs.gradle.org/7.4-rc-1/userguide/platforms.html

    // Required dependencies
    api include(project(path: ":requiem-api", configuration: "namedElements")) { transitive = false }
    api include(project(path: ":requiem-core", configuration: "namedElements")) { transitive = false }
    modImplementation libs.bundles.requiredLibraries
    include libs.bundles.requiredLibraries

    // Test dependencies
    testImplementation testLibs.junit
    testImplementation testLibs.mockito
    testmodImplementation testLibs.mockito
    modLocalImplementation testLibs.elmendorf

    // Optional dependencies
    modCompileOnly libs.modmenu
    modLocalRuntime libs.modmenu
    modCompileOnly (libs.bundles.cloth) { transitive = false }
    modLocalRuntime (libs.bundles.cloth) { transitive = false }
    include libs.fiberToCloth

    // Extra compatibility dependencies
//    modLocalRuntime compatLibs.mobz
    modCompileOnly (compatLibs.betterGraves) { transitive = false }
//    modLocalRuntime compatLibs.betterGraves
//    modCompileOnly compatLibs.biomeMakeover
//    modLocalRuntime compatLibs.biomeMakeover
    modCompileOnly (compatLibs.trinkets) { transitive = false }
//    modLocalRuntime compatLibs.trinkets
    modCompileOnly (compatLibs.pehkui) { transitive = false }
//    modLocalRuntime compatLibs.pehkui
    modCompileOnly (compatLibs.snowmercy) { transitive = false }
//    modLocalRuntime compatLibs.snowmercy
    modCompileOnly (compatLibs.bundles.origins) { transitive = false }
    modLocalRuntime (compatLibs.bundles.origins)
    modLocalImplementation (compatLibs.additionalEntityAttributes)

    modCompileOnly (compatLibs.eldritchMobs) { transitive = false }
//    modLocalRuntime compatLibs.eldritchMobs
    modCompileOnly (compatLibs.haema) { transitive = false }
//    modLocalRuntime compatLibs.bundles.haema
    modCompileOnly (compatLibs.golemsGalore) { transitive = false }
//    modLocalRuntime compatLibs.bundles.golemsGalore
    modCompileOnly (compatLibs.bumblezone) { transitive = false }
//    modLocalRuntime compatLibs.bumblezone
    modCompileOnly (compatLibs.bewitchment) { transitive = false }
//    modLocalRuntime compatLibs.bundles.bewitchment
    modLocalImplementation (compatLibs.trinkets)
    modLocalRuntime compatLibs.collective
}

remapJar.dependsOn(project(":requiem-core").tasks.remapJar)

jar {
    from 'LICENSE-CODE'
    from 'LICENSE-ART'
}