Windows Batch script to trim unprocessed images based on processed ones? (auto-trim)

[YutMarma]

ImageMagick version

7.x

Operating system, version and so on

Windows 10

Description

I have a fair amount of files which need to be auto-cropped. -trim and -fuzz and -shave alone don't work due to dust on the scanner platen.

-statistic mean kinda works, but I'm left with an ugly, blurry image with a bit of a border around it. If the image wasn't blurry it'd be simple to just add a followup -shave.

I'm not terribly fluent in batch scripting to begin with. I can imagine what I want to do in terms of image editing: Copy current layer to new layer, do filters on new layer, use new layer as a reference while performing operations on all layers, delete new layer.

In vague pseudocode I have:
take original image
make copy of image
apply disgusting filters to copy as needed to make machine-readable
trim original image using results from processed copy

Could someone take that and put it into good ol' FOR /r %a IN (*.png) blah blah blah for me?

(There seem to be a couple bash scripts which are geared towards what I'm looking for, but the current Ubuntu LTS only provides ImageMagick 6.x, attempting to manually install 7.x left me in dependency hell, and every time I've tried cygwin/MinGW/etc on Windows it's ended up in unbelievable frustration, so I'm going to stick with crappy old Windows batch until the "user-friendly" Linux distro finds a way to handle dependencies at least as gracefully as DirectX on Windows 95 did thirty years ago)

[fmw42]

Can you post an example image? One often can either use other noise filters (see sequence of multiple -enhance filters) or threshold the image and remove items smaller than some area. Then find the crop values (see %@ string format). The crop the original with those crop values.

[YutMarma]

Here's a link to an example image (40MB .PNG). Note that when resizing to something more web-friendly (1175x1600, for instance) it ends up working great in ImageMagick, probably because some of the dust is smoothed out during the resampling. Hence the gigantic image.

One often can either use other noise filters (see sequence of multiple -enhance filters) or threshold the image and remove items smaller than some area. Then find the crop values (see %@ string format). The crop the original with those crop values.

This sounds sensible, but again, I simply don't know the batch + magick commands to take an output (such as from a trailing -format %@ info:) and use it as an input. In fishing terms, I already know what sort of fish are in the lake and am happy to experiment with various recipes until I find something delicious, I just need to understand how to crank the little wheel on the rod that drags the fish towards me. :)

[fmw42]

If you want to trim to the black and red area and remove the white, do what I suggested above. I can't help you as I do not code on Windows. But threshold, remove the black spots at the corners and use %@ to get the crop box or use connected components to remove areas smaller than some size. Then get the largest area region and its bounding box. Then in either case crop the original with the crop box/bounding box. See https://imagemagick.org/script/connected-components.php and https://imagemagick.org/script/escape.php

[YutMarma]

Thanks for helping, I really appreciate taking the time to type that up.

That having been said, I hope you won't take it personally if I leave this thread open/unresolved, since my question is more of a "how" than a "what/which". I've already found what works perfectly (-statistics mean 20x20 or thereabouts), I just don't know the syntax/grammar to automagically perform the -trim from that file on the original, un-blurred image.

Manually finding bounding boxes and entering them one at a time in command line just isn't much better than manually cropping by hand in an image editor, and in some regards a step or two backwards.

[fmw42]

I was not suggesting manually finding crop boxes. I outlined how to do it automatically above.

I assumed a Windows user would come to your rescue. But if you want commands (not script), you can try

1. Threshold the image so that white is white and most of the rest if not all is black.

magick image.png -theshold XX% threshold.png

Where XX is say 50% as first try and adjust as needed or

magick image.png -auto-threshold otsu threshold.png

2. Do your -statistic processing on the threshold image saving as stats.png or any other method of removing the small noise including -connected-components processing

3. Get the crop box parameters

magick stats.png -format %@ info:

returns crop WxH+X+Y

4. Crop the original

magick image.png -crop WxH+X+Y +repage image_crop.png

[snibgo]

In vague pseudocode I have: ...
Could someone take that and put it into good ol' FOR /r %a IN (*.png) blah blah blah for me?

for /F "usebackq" %A in (`magick YourFile.png *YourDisgustingFilters* -format %@ info:`) do set MYTRIM=%A

magick YourFile.png -crop %MYTRIM% +repage YourOutFile.png

If doing this in a BAT file, double % to %% in %%A and %@, but not in %MYTRIM%.

You can put those commands in a for loop to process all PNG files in the current directory like this:

for %F in (*.png) do (
  for /F "usebackq" %A in (`magick "%~nF" *YourDisgustingFilters* -format %@ info:`) do set MYTRIM=%A

  magick "%~nF" -crop %MYTRIM% +repage "someNewDirectory\%~nF.png"
)

Note that I put the output files in a different directory, which must already exist. If I put them in the same directory then the output files would also be processed as input files.

EDIT: The two commands can be combined into one, like this:

magick YourFile.png ( +clone *YourDisgustingFilters* -set option:MYTRIM %@ +delete ) -crop %[MYTRIM] +repage YourOutFile.png

[YutMarma]

Thanks! This was a start in the right direction. I had to clean up some formatting on the batch file (namely "%%~nxF" instead of "%%~nF"), but I've hit a roadblock now.

Current batch file:

for %%F in (*.png) do (
  for /F "usebackq" %%A in (`magick "%%~nxF" -shave 200x200 -bordercolor White -border 200x200x200x200 -statistic mean 10x10 -fuzz 50%% -trim -format %%@ info:`) do set MYTRIM=%%A
	
  magick "%%~nxF" -gravity Center -crop %MYTRIM% +repage "output\%%~nF.png"
)

(so in plain English, shave off edges to remove artifacts left over from deskewing, add blank edges to preserve dimensions, blur image, find trim dimensions, output trim dimensions to %MYTRIM%, crop original image to %MYTRIM%)

However, what seems to be happening now is that the "current" value of %MYTRIM% - whatever it happens to be at the start of execution (so either 0 or the values from the last file in the previous run) is used for all the images.

Here's the output:
sample output.txt

All output images are cropped to 2764x3559.

In BASIC terms, it's running something like:

10: FOR A = 1 TO 10
20: PRINT N
30: NEXT A
40: N=A

When it should be:

10: FOR A = 1 TO 10
15: N = A
20: PRINT N
30: NEXT A

It's probably something really obvious to anyone who's even slightly fluent in Windows Batch, but I'm at the level where I still pat myself on the back for five minutes for figuring out how to add "~x" for file extensions :)

[snibgo]

Yeah, my fault, I got it a bit wrong. I had a nagging feeling something was wrong, but couldn't see what.

setlocal enabledelayedexpansion

for %F in (*.png) do (
  for /F "usebackq" %A in (`magick "%~nF" *YourDisgustingFilters* -format %@ info:`) do set MYTRIM=%A

  magick "%~nF" -crop !MYTRIM! +repage "someNewDirectory\%~nF.png"
)

Note the new first line and the change to !MYTRIM!.

The problem is that the Windows interpreter only translates %MYTRIM% once, so the value isn't updated in the loop. !MYTRIM! is re-translated every time in the loop, aka "delayed expansion".

Sorry. (Still no guarantees I've now got it right.)

[YutMarma]

I was poking around independently and actually came across this probably while you were writing that post up!

But it's, unbelievably, still not working - for some reason it interprets !MYTRIM! literally, and so the second line ends up being magick -crop !MYTRIM! blahblah.

setlocal EnableDelayedExpansion

for %%F in (*.png) do (
  for /F "usebackq" %%A in (`magick "%%~nxF" -shave 200x200x200x200 -bordercolor White -border 200x200x200x200 -statistic mean 5x5 -fuzz 50%% -trim -format %%@ info:`) do set MYTRIM=%%A
	
  magick "%%~nxF" -gravity Center -crop !MYTRIM! +repage "output\%%~nF.png"
)

(just copy-pasting for sanity's sake in case I screwed something up and am blind to it)

Maybe I need a SetLocal or EndLocal?

(also, I can palpably sense all the bash guys laughing at this whole exchange between us - "there but for the grace of GNU go we..." - thank you again for your patience here, I'm sorry to keep coming back for hand-holding)

[YutMarma]

Ah, figured it - needed carets: (EDIT: Well, not exactly - doesn't need carets, I was just thrown off by the ECHO'd output being literally !MYTRIM! whereas the previous ECHO'd output was the actual value of %MYTRIM% - but carets don't break anything)

setlocal EnableDelayedExpansion

for %%F in (*.png) do (
  for /F "usebackq" %%A in (`magick "%%~nxF" -shave 200x200x200x200 -bordercolor White -border 200x200x200x200 -statistic mean 5x5 -fuzz 50%% -trim -format %%@ info:`) do set MYTRIM=%%A
	
  magick "%%~nxF" -gravity Center -crop ^!MYTRIM!^ +repage "output\%%~nF.png"
)

Now it seems to be mostly working as expected, aside from outputting a final line that seems to be the sum of all the previous values (set MYTRIM=18446744073709551616x18446744073709551616+3241+6621), but it's just cosmetic. All that's left now is fine-tuning stuff on my end. Thank you so much for leading me to water on this one.