-
-
Notifications
You must be signed in to change notification settings - Fork 11
/
ExTools.avsi
11196 lines (10271 loc) · 691 KB
/
ExTools.avsi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
###########################################################
### ##
### ##
### ExTools v10.4 (19-02-2024) ##
### ##
### by Dogway (Jose Linares) ##
### ##
### https://forum.doom9.org/showthread.php?t=182881 ##
### ##
###########################################################
###
### Pack of masktools2/removegrain replacement functions with...
### internal Expr() and many extra features.
### Generally works faster* than masktools2 counterparts for any given bitdepth.
### See performance notes (benchmarks over 1080p@16-bit).
###
### *Convolutions are slower than in masktools2/removegrain (SSSE3 vs AVX2)
###
### UV setting works similarly as in masktools2:
###
### 1: garbage
### 2: copy first
### 3: process
### 4: copy second
### 6: copy third (differs with masktools2's '5')
### 128: range_half
### x: custom value in 8-bit (bitdepth autoscaled) (1, 2, 3, 4, and 6 not available)
###
### fulls: Defines the source bitdepth scale (full/bitshift range) when converting from/to integer HBD formats (10, 12, 14, 16)
### ConvertBits() defaults to false for YUV, same in ExTools if frame properties are not present.
###
### Dependencies: AviSynth+ 3.7.3+ (https://forum.doom9.org/showthread.php?t=181351)
###
### Credits: Thanks to wonkey_monkey (David Horman) for Expr optimization tips
### and pinterf for Expr's pixel addressing feature and his continued efforts on AVS+ development
###
###########################################################
### ##
### EXPRESSIONS: ##
### ex_lut ##
### ex_lutxy ##
### ex_lutxyz ##
### ex_lutxyza ##
### ex_makediff ##
### ex_adddiff ##
### ex_makeadddiff ##
### ex_logic ##
### ex_merge ##
### ex_clamp ##
### ex_binarize ##
### ex_athres ##
### ex_invert ##
### ex_lutspa ##
### ex_motion ##
### ex_hysteresis ##
### BLURS: ##
### ex_boxblur ##
### ex_blur ##
### ex_blur3D ##
### ex_bilateral ##
### ex_smartblur ##
### ex_smooth ##
### ex_kawase ##
### ex_GaussianBlur ##
### ex_LFR ##
### ex_MFR ##
### ex_FluxSmoothT ##
### ex_FluxSmoothST ##
### STTWM ##
### ex_median ##
### ex_repair ##
### MORPHOLOGICAL: ##
### ex_expand ##
### ex_inpand ##
### ex_deflate ##
### ex_inflate ##
### ex_hitormiss ##
### ex_dedither ##
### ex_edge ##
### ex_luts ##
### ex_shape ##
### HELPERS: ##
### clamp ##
### isRunTime ##
### DivideStr ##
### FindStrInstance ##
### pixel_parser ##
### ex_UVexpr ##
### ex_Yexpr ##
### ex_UVf ##
### ex_bs ##
### ex_dlut ##
### mskY_to_YYY ##
### ARRAY HELPERS: ##
### ArrayOp ##
### ArrayInv ##
### ArrayZip ##
### ArraySym ##
### ArrayAppend ##
### ArrayDelVal ##
### ArrayFind ##
### ArrayPrint ##
### ArrayEval ##
### ArrayMedian ##
### ArrayIQM ##
### FUNCTION APPROXIMATIONS: ##
### atanT ##
### atan2T ##
### tanhT ##
### atanhT ##
### expT ##
### cosT ##
### sinT ##
### ##
###########################################################
function ex_lut(clip a, string "str", string "cstr", int "Y", int "UV", string "scale_inputs", bool "clamp_float", bool "fulls") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
isc = Defined(cstr)
str = Default(str, "")
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : isc || Y!=3 ? 3 : 1)
fs = Default(fulls, fs)
cf = Default(clamp_float, false)
si = Default(scale_inputs, ex_UVf(rgb, bi))
# Overall 1D LUT calculations work when input bitdepth is < 32, regardless of internal expression bitdepth scaling.
# In practice enabling LUT causes a slight (~7%) slowdown. But this has to be fixed upstream, not here.
# Supporting LUT calculations when internal bitdepth scaling might allow it (ie. Expr(32f_src,"i8 x 1 -", scale_inputs="all", lut=1) ) would also be a great addition to Expr().
px = FindStr(str, "[") > 0 || (isc ? FindStr(cstr, "[") > 0 : false)
lut = px || bi == 32 || isRunTime(a,rgb) ? 0 : 1
cstr = !isc && Y!=3 ? str : isc && UV==3 ? cstr : str # Evaluate str as cstr if Y!=3 and cstr is not defined
ystr = ex_Yexpr ( str, Y, bi, rgb, fs, si)
cstr = rgb ? ex_dlut(str, bi, fs) : ex_UVexpr(cstr, UV, bi, rgb, fs, si, isc)
isy ? Expr(a, ystr, scale_inputs=si, clamp_float=cf, lut=lut) : \
UV == 1 ? Expr(a, ystr, "", scale_inputs=si, clamp_float=cf, lut=lut) : \
Expr(a, ystr, cstr, scale_inputs=si, clamp_float=cf, lut=lut) }
function ex_lutxy(clip a, clip b, string str, string "cstr", int "Y", int "UV", string "scale_inputs", bool "clamp_float", bool "fulls") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
isc = Defined(cstr)
str = Default(str, "")
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : isc || Y!=3 ? 3 : 1)
fs = Default(fulls, fs)
cf = Default(clamp_float, false)
si = Default(scale_inputs, ex_UVf(rgb, bi))
px = FindStr(str, "[") > 0 || (isc ? FindStr(cstr, "[") > 0 : false)
lut = px || bi > 12 || isRunTime(a,rgb) ? 0 : 2 # Technically 14-bit supports LUT calcs but in practice depends on cache size which most not-too-recent (pre-2021) CPUs lack
cstr = !isc && Y!=3 ? str : isc && UV==3 ? cstr : str
ystr = ex_Yexpr ( str, Y, bi, rgb, fs, si)
cstr = rgb ? ex_dlut(str, bi, fs) : ex_UVexpr(cstr, UV, bi, rgb, fs, si, isc)
isy ? Expr(a, b, ystr, scale_inputs=si, clamp_float=cf, lut=lut) : \
UV == 1 ? Expr(a, b, ystr, "", scale_inputs=si, clamp_float=cf, lut=lut) : \
Expr(a, b, ystr, cstr, scale_inputs=si, clamp_float=cf, lut=lut) }
function ex_lutxyz(clip a, clip b, clip c, string str, string "cstr", int "Y", int "UV", string "scale_inputs", bool "clamp_float", bool "opt", bool "fulls") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
isc = Defined(cstr)
str = Default(str, "")
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : isc || Y!=3 ? 3 : 1)
fs = Default(fulls, fs)
cf = Default(clamp_float, false)
op = Default(opt, false)
si = Default(scale_inputs, ex_UVf(rgb, bi))
cstr = !isc && Y!=3 ? str : isc && UV==3 ? cstr : str
ystr = ex_Yexpr ( str, Y, bi, rgb, fs, si)
cstr = rgb ? ex_dlut(str, bi, fs) : ex_UVexpr(cstr, UV, bi, rgb, fs, si, isc)
isy ? Expr(a, b, c, ystr, scale_inputs=si, clamp_float=cf, optSingleMode=op) : \
UV == 1 ? Expr(a, b, c, ystr, "", scale_inputs=si, clamp_float=cf, optSingleMode=op) : \
Expr(a, b, c, ystr, cstr, scale_inputs=si, clamp_float=cf, optSingleMode=op) }
function ex_lutxyza(clip a, clip b, clip c, clip d, string str, string "cstr", int "Y", int "UV", string "scale_inputs", bool "clamp_float", bool "opt", bool "fulls") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
isc = Defined(cstr)
str = Default(str, "")
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : isc || Y!=3 ? 3 : 1)
fs = Default(fulls, fs)
cf = Default(clamp_float, false)
op = Default(opt, false)
si = Default(scale_inputs, ex_UVf(rgb, bi))
cstr = !isc && Y!=3 ? str : isc && UV==3 ? cstr : str
ystr = ex_Yexpr ( str, Y, bi, rgb, fs, si)
cstr = rgb ? ex_dlut(str, bi, fs) : ex_UVexpr(cstr, UV, bi, rgb, fs, si, isc)
isy ? Expr(a, b, c, d, ystr, scale_inputs=si, clamp_float=cf, optSingleMode=op) : \
UV == 1 ? Expr(a, b, c, d, ystr, "", scale_inputs=si, clamp_float=cf, optSingleMode=op) : \
Expr(a, b, c, d, ystr, cstr, scale_inputs=si, clamp_float=cf, optSingleMode=op) }
# mt_makediff() is 5% slower
#
# Use aug=n to augment difference map
# Use metric="metric_name" to write/show metric(s) to frame properties (check dependencies below)
# Use 'show' to choose output; 0: clip 'a' 1: clip 'b' 2: diff 3: diff subtitled (no frameprops)
#
# Dependencies:
# SimilarityMetrics (for HD inputs when metric: ALL or simply metric: SSIM, BSSIM, GMSD or MDSI)
# fmtconv
# TransformsPack (for metric: RedMean or OkMSE)
# VMAF (for metric: MS-SSIM, CAMBI or CIEDE2000)
# Butteraugli (for metric: Butteraugli)
#
# Function Definition:
# (
# clip a,
# clip b,
# string "metric"="none" ("none"/ "ALL"/ "--"/ "ME"/ "MAE"/ "SMAE"/ "MAD"/ "MAD2"/ "MSE"/ "MSLE"/ "RMSE"/ "CHAR"/ "--"/ "OkMSE"/ "RedMe"/ "CIEDE2000"/ "R2"/ "ZTest"/ "CAMBI"/ "--"/ "PSNR"/ "SSIM"/ "MS_SSIM"/ "BSSIM"/ "SSIMU"/ "SSIMU2"/ "GMSD"/ "MDSI"/ "BUTT"),
# bool "aug"=false,
# bool "dif"=false,
# int "show"=2 (0 to 3)
# )
#
# modes:
# error = e = (predicted - observed) or (distorted - reference) = x - y
# ME - Mean Error or Bias. M(e). Measures additive bias in the error
# MAE - Mean Absolute Error -Manhattan or L1 norm-. M(|e|). Measures additive bias in the error but in a magnitude scale without sign
# PAE - Percentage of Absolute Error (not implemented)
# SMAE - Smooth Mean Absolute Error or Huber Loss. Same as MAE but less sensitive to outliers. It performs like MAE with low error and like MSE with high error
# MAD - Mean Absolute Deviation
# MAD2 - Median Absolute Deviation. median(|e-median(|e|)|). Similar to a standard deviation but more robust to outliers by replacing the means of squares with median of absolutes
# MSE - Mean Square Error / SSR / Quadratic Loss. Sometimes also erroneously labeled L2 norm. M(e^2) Gives more weight to large deviations or outliers
# MSLE - Mean Square Log Error. Gives less weight to large deviations or outliers. Useful when dealing with right skewed references
# RMSLE - Not implemented
# RMSE - Root Mean Squared Error / Standard Error / SRSS -Euclidean or L2 norm-. sqrt(M(e^2)). Gives more weight to large deviations or outliers. Same as MSE but rooted to normalize the units
# PSNR - Peak Signal-to-Noise Ratio
# CHAR - Charbonnier -L1-L2 loss-
# OkMSE - Euclidean Distance -RMSE- in OkLab
# RedMean - RedMean -sRGB fast metric-
# R2 - Coefficient of determination. Measure of the ratio of variability between the distorted and the reference
# ZTest - Two Sample Z-Test / Z-Score -Difference of Means of Distributions-
# SSIM - Structural SIMilarity
# MS-SSIM - Structural SIMilarity for Multi-Scale
# SSIMU - SSIMULACRA - Structural SIMilarity Unveiling Local And Compression Related Artifacts
# SSIMU2 - SSIMULACRA2 - Structural SIMilarity Unveiling Local And Compression Related Artifacts, Version 2 (https://github.com/cloudinary/ssimulacra2)
# BSSIM - Structural SIMilarity for Blurred
# GMSD - Gradient Magnitude Similarity Deviation
# BUTT - Butteraugli psychovisual similarity index for DCT compression. Google's open source image metric tool tuned to high quality content (mainly between -q 90 to 95 in JPEG scale)
# MDSI - Mean Deviation Similarity Index. IQA model that utilizes gradient similarity (GS), chromaticity similarity (CS), and deviation pooling (DP)
# CAMBI - Contrast-Aware Multiscale Banding Index
# CIEDE2000-CIE Delta-E 2000
function ex_makediff(clip a, clip b, bool "dif", val "aug", bool "tv_range", string "metric", int "show", int "Y", int "UV", bool "fulls", bool "clamp_float", string "scale_inputs") {
rgb = isRGB(a)
isy = isy (a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
lut = bi > 12 || isRunTime(a,rgb) ? 0 : 2
Daug = Defined(aug) Baug = isBool(aug)
met = Daug && !Baug ? aug == -1 ? "ALL" : "none" : "none"
tv = Default(tv_range, false) # Enable to mimic Subtract(), "ygrey" centered instead of "range_half" (only applies to luma plane)
dif = Default(dif, tv || bi!=32)
fs = Default(fulls, fs) # Only used for 'metric' to properly convert to PC range
cf = Default(clamp_float, false)
mcf = Default(metric, met) # "ALL", "none" or "metric_name".
mcf = mcf=="--" || mcf=="" ? "none" : mcf
sh = Default(show, 2) # Output clip to return when 'metric' is defined. 0: clip 'a' 1: clip 'b' 2: diff 3: diff subtitled (no frameprops)
aug = Daug ? Baug ? aug ? 50 :-1 : aug == -1 ? 50 : aug : mcf == "none" ? 0 : 50
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : aug > 0 ? 128 : 1)
si = Default(scale_inputs, ex_UVf(rgb, bi))
gr = tv ? "ygrey" : "range_half"
str = Format(aug > 0 ? "x y - abs {aug} *" : \
dif ? "x y - "+gr+" +" : \
"x y -")
ystr = ex_Yexpr ( str, Y, bi, rgb, fs, si)
cstr = ex_UVexpr(ReplaceStr(str,"ygrey","range_half"), UV, bi, rgb, fs, si)
isy ? Expr(a, b, ystr , scale_inputs=si, clamp_float=cf, lut=lut) : \
UV == 1 ? Expr(a, b, ystr, "" , scale_inputs=si, clamp_float=cf, lut=lut) : \
Expr(a, b, ystr, cstr, scale_inputs=si, clamp_float=cf, lut=lut)
if (!tv) {
prop = ["_Matrix","_Primaries","_Transfer","_PictType"]
propDelete(UV<5?prop:ArrayAdd(prop,"_ChromaLocation"))
propSet("_ColorRange", 0) }
# Cost Functions for Similarity Index Metric Distances (Residuals)
if (mcf != "none") {
fc = FrameCount() < 2
mcf = mcf == "Butteraugli" ? "BUTT" : \
mcf == "Charbonnier" ? "CHAR" : \
mcf == "stderr" ? "RMSE" : \
mcf == "L1" ? "MAE" : \
mcf == "L2" ? "MSE" : \
mcf == "SSR" ? "MSE" : \
mcf == "RedMean" ? "rMEA" : \
mcf == "SSIMULACRA" ? "SSIMU" : \
mcf == "SSIMULACRA2" ? "SSIMU2" : \
mcf == "OkLab" ? "OkMSE" : UCase(mcf)
mcfa = mcf == "ALL"
mPLUG = (mcf == "BSSIM" || mcf == "GMSD" || mcf == "MDSI" || mcf == "SSIM")
mVMAF = mcf == "MS_SSIM" || mcf == "CIEDE2000"
RGBm = mcf == "OkMSE" || mcf == "CIEDE2000" || mcf == "rMEA" || mcf == "MDSI" || mcf == "BUTT"
isy && !mcfa ? Assert(!RGBm, "ex_makediff: Unsupported mode for greyscale clips") : nop()
w = a.width()
h = a.height()
pd = max(w,h)/(w/144.)
isUHD = (w > 2599 || h > 1499)
isHD = (w > 1099 || h > 599)
matA = isUHD ? "2020:f" : isHD ? "709:f" : "170m:f"
a1 = mcfa && sh < 2 ? a.propClearAll() :a
a1 = mcfa || mcf == "CAMBI" || mVMAF ? mcfa && isHD ? _IQA_downsample(a1, fulls=fs, fulld=true).ConvertBits(10,dither=-1,fulls=true) : a1.ConvertBits(10,dither=-1,fulls=fs,fulld=true) : a1.ConvertBits(32,fulls=fs,fulld=true) # _IQA_downsample() is not much better than bicubic(b=-0.5,c=0.3), but better in any case.
b1 = mcfa || mcf == "CAMBI" || mVMAF ? mcfa && isHD ? _IQA_downsample(b, fulls=fs, fulld=true).ConvertBits(10,dither=-1,fulls=true) : b. ConvertBits(10,dither=-1,fulls=fs,fulld=true) : b. ConvertBits(32,fulls=fs,fulld=true)
a1 = rgb && (mcfa || mcf != "MDSI" && mcf != "BUTT" && mcf != "rMEA" && mcf != "OkMSE") ? a1.ConvertToYUV420(matrix=matA) : a1
b1 = rgb && (mcfa || mcf != "MDSI" && mcf != "BUTT" && mcf != "rMEA" && mcf != "OkMSE") ? b1.ConvertToYUV420(matrix=matA) : b1
a1 = mcfa || mcf == "CAMBI" || mVMAF ? isy ? CombinePlanes(a1, planes="YUV", source_planes="YYY", pixel_type="YUV444"+(BitsPerComponent(a1)==32?"PS":"P10")) : a1 : a1
b1 = mcfa || mcf == "CAMBI" || mVMAF ? isy ? CombinePlanes(b1, planes="YUV", source_planes="YYY", pixel_type="YUV444"+(BitsPerComponent(b1)==32?"PS":"P10")) : b1 : b1
# y = mcfa || mcf == "VMAF" ? VMAF (a1, b1,"",log_format=2,model=0) : a1 # VMAF is not supported as it requires writing to disk
y = mcfa || mVMAF ? VMAF2 (a1, b1, feature=mcfa?isy?[3]:[3,4]:mcf=="MS_SSIM"?3:4) : a1 # Requires 8-10-bit input, YCbCr 3 planes (feature: 1: PSNR-HSV 3: MS-SSIM 4: CIEDE2000 5: CAMBI)
y = mcfa || mcf == "CAMBI" ? VMAF2 (y, b1, feature=5, cambi_opt=Format("enc_width={w} enc_height={h}")) : y
y = mcfa || mcf == "CAMBI" || mVMAF ? y.ConvertBits(32,fulls=true) : y
a1 = mcfa && sh < 2 ? y.propClearAll() : isHD ? a1.ConvertBits(32,fulls=true) : a.ConvertBits(32,fulls=fs,fulld=true)
b1 = mcfa || mcf == "CAMBI" || mVMAF ? isHD ? b1.ConvertBits(32,fulls=true) : b.ConvertBits(32,fulls=fs,fulld=true) : b1
b2 = rgb || isy || is444(b1) ? b1.ConvertToPlanarRGB(matrix=matA) : b1.ConvertToPlanarRGB(matrix=matA,chromaresample="bicubic",param1=0,param2=0.5)
y = mcfa || mcf == "SSIM" || mcf == "BSSIM" ? \
vsSSIM(b1, y, show=1, fulls=true) : y
y = mcfa || mcf == "BSSIM" ? BSSIM (b1, y, show=1, fulls=true) : y
y = mcfa ? rgb || isy ? GMSD(b1, y, show=1, fulls=true).ConvertToPlanarRGB(matrix=matA) : is444(b1) ? GMSD(b1, y, show=1, fulls=true).ConvertToPlanarRGB(matrix=matA) : GMSD(b1, y, show=1, fulls=true).ConvertToPlanarRGB(matrix=matA,chromaresample="bicubic",param1=0,param2=0.5) : \
mcf == "GMSD" ? GMSD(b1, y, show=1, fulls=true) : mcf=="SSIMU" || mcf=="SSIMU2" || mcf=="MDSI" || mcf=="BUTT" || mcf=="rMEA" || mcf=="OkMSE" ? is444(y) ? y.ConvertToPlanarRGB(matrix=matA) : y.ConvertToPlanarRGB(matrix=matA,chromaresample="bicubic",param1=0,param2=0.5) : y
y = mcfa || mcf == "MDSI" ? !isy ? MDSI (b2, y, show=1, fulls=true) : y : y
y = mcfa || FindStr(UCase(mcf),"SSIMU")>0 ? !isy ? ssimulacra(y, b2, feature=mcfa?2:mcf=="SSIMU"?0:1) : y : y
b3 = mcfa || mcf == "BUTT" ? !isy ? Butteraugli(y, b2) : y : y # Very slow filter ~3fps
z1 = mcfa || mcf == "ME" || mcf == "MAE" || mcf == "SMAE" ? ex_lutxy(a1,b1,"x y -" ,UV=1,fulls=true) : nop()
z2 = mcfa || mcf == "MSE" || mcf == "CHAR" || mcf == "RMSE" || mcf == "PSNR" ? ex_lutxy(a1,b1,"x y - dup *" ,UV=1,fulls=true) : nop()
z3 = mcfa || mcf == "MSLE" ? ex_lutxy(a1,b1,"x 1 + log y 1 + log - dup *",UV=1,fulls=true) : nop()
# RedMean
yA = mcfa || mcf == "rMEA" ? !isy ? y.ExtractClip() : nop() : nop()
bA = mcfa || mcf == "rMEA" ? !isy ? b2.ExtractClip() : nop() : nop()
z4 = mcfa || mcf == "rMEA" ? !isy ? Expr(yA[0],yA[1],yA[2],bA[0],bA[1],bA[2],"x a + 0.5 * R@ 0.00390625 * 2 + x a - dup * * y b - dup * 4 * + 255 R - 0.00390625 * 2 + z c - dup * * + sqrt") : nop() : nop()
# OkLab
oky = mcfa || mcf == "OkMSE" ? !isy ? y.CCTF(fc?"sRGB":"1886",true,false,false).RGB_to_Oklab(matrix=matA).ExtractClip() : nop() : nop()
okb = mcfa || mcf == "OkMSE" ? !isy ? b2.CCTF(fc?"sRGB":"1886",true,false,false).RGB_to_Oklab(matrix=matA).ExtractClip() : nop() : nop()
OkD = mcfa || mcf == "OkMSE" ? !isy ? Expr(oky[0],oky[1],oky[2],okb[0],okb[1],okb[2],"x a - dup * y b - dup * z c - dup * + + sqrt") : nop() : nop() # RMSE (Euclidean Distance) over OkLab
ScriptClip (sh>1?last:sh==1?b:a, function [y,a,b,z1,z2,z3,z4,a1,b1,b3,OkD,pd,mcf,mcfa,mPLUG,isy,sh,fs] () {
Ava = AverageLuma (a1)
Avb = AverageLuma (b1)
VARa = mcfa || mcf == "ZTest" ? AverageLuma(ex_lut(a1,Format("x {Ava} - dup *"),UV=1,fulls=true)) : nop()
VARb = mcfa || mcf == "ZTest" ? AverageLuma(ex_lut(b1,Format("x {Avb} - dup *"),UV=1,fulls=true)) : nop()
ZTest= mcfa || mcf == "ZTest" ? abs(Ava - Avb) / sqrt(VARa + VARb) : nop() # Difference of means / stderr
Mea = mcfa || mcf == "MAD2" ? YPlaneMedian(a1) : nop()
Meb = mcfa || mcf == "MAD2" ? YPlaneMedian(b1) : nop()
MAD = mcfa || mcf == "MAD" ? AverageLuma (ex_lutxy(a1,b1,Format("{Ava} x - abs {Avb} y - abs - abs"),UV=1,fulls=true)) : nop()
MAD2 = mcfa || mcf == "MAD2" ? YPlaneMedian(ex_lutxy(a1,b1,Format("{Mea} x - abs {Meb} y - abs - abs"),UV=1,fulls=true)) : nop()
ME = mcfa || mcf == "ME" || \
mcf == "MAE" || \
mcf == "SMAE" ? AverageLuma(z1) : nop()
MAE = mcfa || mcf == "MAE" || \
mcf == "SMAE" ? abs(ME) : nop()
SMAE = mcfa || mcf == "SMAE" ? MAE < 1. ? pow(MAE,2)/2. : MAE - 0.5 : nop()
MSE = mcfa || mcf == "MSE" || \
mcf == "CHAR" || \
mcf == "RMSE" || \
mcf == "PSNR" ? AverageLuma(z2) : nop()
MSLE = mcfa || mcf == "CHI" ? AverageLuma(z3) : nop()
MSLE = mcfa || mcf == "MSLE" ? AverageLuma(z3) : nop()
RedMean=mcfa|| mcf == "rMEA" ? !isy ? AverageLuma(z4) : nop() : nop()
CHAR = mcfa || mcf == "CHAR" ? sqrt(MSE+pow(0.001,2)) : nop()
RMSE = mcfa || mcf == "RMSE" || \
mcf == "PSNR" ? sqrt(MSE) : nop() # Technically should be first sqrt(loss) and then Mean but in practice a close match
PSNR = mcfa || mcf == "PSNR" ? 20*log10(1./RMSE) : nop() # 20*log10() to convert to dB
R2 = mcfa || mcf == "R2" ? AverageLuma(ex_lutxy(a1,b1,Format("{Ava} dup x - swap dup * swap y - swap dup * swap / 1 swap -"),UV=1,fulls=true)) : nop()
OkMSE= mcfa || mcf == "OkMSE" ? !isy ? AverageLuma(OkD) : nop() : nop()
BUTT = mcfa || mcf == "BUTT" ? !isy ? propGetFloat(b3,"_FrameButteraugli") : nop() : nop()
SSIMU= mcfa || FindStr(UCase(mcf),"SSIMU") >0? !isy ? mcfa ? [propGetFloat(y,"SSIMULACRA"),propGetFloat(y,"SSIMULACRA2")] : propGetFloat(y,mcf=="SSIMU"?"SSIMULACRA":"SSIMULACRA2") : "" : ""
SSIMU2= SSIMU
CAMBI= mcfa || mcf == "CAMBI" ? propGetFloat(y,"cambi") : nop()
MS_SSIM= mcfa||mcf == "MS_SSIM"? propGetFloat(y,"float_ms_ssim") : nop()
CIEDe2000=mcfa||mcf=="CIEDE2000"?!isy ? propGetFloat(y,"ciede2000") : nop() : nop()
if (!mcfa && mPLUG) {
y = propCopy(last,y,true,props=["_Plane"+MCF])
} else if (mcfa) {
y = propCopy(last,y,true,props=["_PlaneSSIM","_PlaneBSSIM","_PlaneGMSD","_PlaneMDSI"])
} else {
y = last
}
if (mcfa) {
y = propSet(y,"_PlaneME" , ME , 0)
y = propSet(y,"_PlaneMAE" , MAE, 0)
y = propSet(y,"_PlaneSMAE", SMAE, 0)
y = propSet(y,"_PlaneMAD" , MAD, 0)
y = propSet(y,"_PlaneMAD2", MAD2, 0)
y = propSet(y,"_PlaneMSE" , MSE, 0)
y = propSet(y,"_PlaneMSLE", MSLE, 0)
y = propSet(y,"_PlaneRMSE", RMSE, 0)
y = propSet(y,"_PlaneCHAR", CHAR, 0)
y = propSet(y,"_PlaneOkMSE", OkMSE, 0)
y = propSet(y,"_PlaneRedMean",RedMean, 0)
y = propSet(y,"_PlaneR2" , R2 , 0)
y = propSet(y,"_PlaneSSIMU", SSIMU[0], 0)
y = propSet(y,"_PlaneSSIMU2",SSIMU[1], 0)
y = propSet(y,"_PlaneZTest", ZTest, 0)
y = propSet(y,"_PlaneBUTT", BUTT, 0)
y = propSet(y,"_PlanePSNR", PSNR, 0)
y = propSet(y,"_PlaneMS_SSIM",MS_SSIM, 0)
y = propSet(y,"_PlaneCIEDE2000",CIEDe2000,0)
y = propSet(y,"_PlaneCAMBI", CAMBI, 0)
} else {
MCF = ReplaceStr(MCF,"rMEA","RedMean" )
y = !mPLUG ? propSet(y,"_Plane"+MCF, Eval(MCF), 0) : y
Subtitle(y, "Plane"+MCF+": "+String(mPLUG ? propGetFloat(y,"_Plane"+MCF ) : Eval(MCF)))
}
if (sh != 3) { y } else if (!mcfa) { last } else {
NaN = "NaN "
Subtitle(last,\
"PlaneME:\n" \
+"PlaneMAE:\n" \
+"PlaneSMAE:\n" \
+"PlaneMAD:\n" \
+"PlaneMAD2:\n" \
+"PlaneMSE:\n" \
+"PlaneMSLE:\n" \
+"PlaneRMSE:\n" \
+"PlanePSNR:\n" \
+"PlaneCHAR:\n" \
+"PlaneOkMSE:\n" \
+"PlaneRedMean:\n"\
+"PlaneR2:\n" \
+"PlaneZTest:\n" \
+"PlaneSSIM:\n" \
+"PlaneSSIMU:\n" \
+"PlaneSSIMU2:\n" \
+"PlaneBSSIM:\n" \
+"PlaneGMSD:\n" \
+"PlaneBUTT:\n" \
+"PlaneMDSI:\n" \
+"PlaneMS_SSIM:\n"\
+"PlaneCIEDE2000:\n"\
+"PlaneCAMBI:\n",lsp=4)
Subtitle( String( propGetFloat(y,"_PlaneME" )) +" (Mean Error or Bias)\n" \
+ String( propGetFloat(y,"_PlaneMAE" )) +" (Mean Absolute Error -Manhattan or L1 norm-)\n" \
+ String( propGetFloat(y,"_PlaneSMAE" )) +" (Smooth Mean Absolute Error -Huber Loss-)\n" \
+ String( propGetFloat(y,"_PlaneMAD" )) +" (Mean Absolute Deviation)\n" \
+ String( propGetFloat(y,"_PlaneMAD2" )) +" (Median Absolute Deviation)\n" \
+ String( propGetFloat(y,"_PlaneMSE" )) +" (Mean Square Error / SSR)\n" \
+ String( propGetFloat(y,"_PlaneMSLE" )) +" (Mean Square Log Error)\n" \
+ String( propGetFloat(y,"_PlaneRMSE" )) +" (Root Mean Squared Error / Standard Error / SRSS -Euclidean or L2 norm-)\n"\
+ String( propGetFloat(y,"_PlanePSNR" ),"%3.5f")+" (Peak Signal-to-Noise Ratio)\n" \
+ String( propGetFloat(y,"_PlaneCHAR" )) +" (Charbonnier -L1-L2 loss-)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneOkMSE")) +" (Euclidean Distance -RMSE- in OkLab)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneRedMean"))+" (RedMean -sRGB fast metric-)\n" \
+ String( propGetFloat(y,"_PlaneR2" )) +" (Coefficient of determination)\n" \
+ String( propGetFloat(y,"_PlaneZTest")) +" (Two Sample Z-Test / Z-Score -Difference of Means of Distributions-)\n"\
+ String( propGetFloat(y,"_PlaneSSIM" )) +" (Structural SIMilarity)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneSSIMU" )) + " (Structural SIMilarity Unveiling Local And Compression Related Artifacts)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneSSIMU2"),"%3.5f")+" (Structural SIMilarity Unveiling Local And Compression Related Artifacts v2)\n" \
+ String( propGetFloat(y,"_PlaneBSSIM")) +" (Structural SIMilarity for Blurred)\n" \
+ String( propGetFloat(y,"_PlaneGMSD" )) +" (Gradient Magnitude Similarity Deviation)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneBUTT" )) +" (Butteraugli psychovisual similarity index for DCT compression)\n"\
+ String(isy?NaN:propGetFloat(y,"_PlaneMDSI" )) +" (Mean Deviation Similarity Index)\n" \
+ String( propGetFloat(y,"_PlaneMS_SSIM"))+" (Multi-Scale SSIM)\n" \
+ String(isy?NaN:propGetFloat(y,"_PlaneCIEDE2000"),"%3.5f")+" (CIE Delta-E 2000)\n" \
+ String( propGetFloat(y,"_PlaneCAMBI")) +" (Contrast-Aware Multiscale Banding Index)",x=pd,lsp=4)
} } )
sh < 2 && !fs && mcfa ? propSet("_ColorRange", 1) : last
} }
# mt_adddiff() is 5% slower
function ex_adddiff(clip a, clip b, int "Y", int "UV", bool "dif", bool "tv_range", bool "fulls", string "scale_inputs") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
lut = bi > 12 || isRunTime(a,rgb) ? 0 : 2
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : 1)
dif = Default(dif, bi!=32)
fs = Default(fulls, Defined(tv_range) ? tv_range ? false : fs : fs)
tv = Default(tv_range, false)
si = Default(scale_inputs, ex_UVf(rgb, bi))
gr = tv ? "ygrey" : "range_half"
str = dif ? "x y + "+gr+" -" : \
"x y +"
ystr = ex_Yexpr (str, Y, bi, rgb, fs, si)
cstr = ex_UVexpr(str, UV, bi, rgb, fs, si)
isy ? Expr(a, b, ystr , scale_inputs=si, lut=lut) : \
UV == 1 ? Expr(a, b, ystr, "" , scale_inputs=si, lut=lut) : \
Expr(a, b, ystr, cstr, scale_inputs=si, lut=lut) }
function ex_makeadddiff(clip a, clip b, clip "c", int "Y", int "UV", string "scale_inputs", bool "clamp_float") {
rgb = isRGB(a)
isy = isy(a)
isc = Defined(c)
bi = BitsPerComponent(a)
lut = bi > 12 || isRunTime(a,rgb) ? 0 : 2
Y = Default(Y, 3)
UV = Default(UV, rgb ? 3 : 1)
un = Undefined()
cf = Default(clamp_float, false) # Works two ways. Not only it will clamp floats output, but also the first in-expression differential
si = Default(scale_inputs, ex_UVf(rgb, bi))
str = cf ? "0 max" : ""
str = isc ? "x y - "+str+" z +" : "x y - "+str+" x +"
ystr = ex_Yexpr (str, Y, bi, rgb, un, si)
cstr = ex_UVexpr(str, UV, bi, rgb, un, si)
isc ? \
isy ? Expr(a, b, c, ystr , scale_inputs=si, clamp_float=cf ) : \
UV == 1 ? Expr(a, b, c, ystr, "" , scale_inputs=si, clamp_float=cf ) : \
Expr(a, b, c, ystr, cstr, scale_inputs=si, clamp_float=cf ) : \
isy ? Expr(a, b, ystr , scale_inputs=si, clamp_float=cf, lut=lut ) : \
UV == 1 ? Expr(a, b, ystr, "" , scale_inputs=si, clamp_float=cf, lut=lut ) : \
Expr(a, b, ystr, cstr, scale_inputs=si, clamp_float=cf, lut=lut ) }
# mt_logic(mode="and") is 6% slower
#
# AND : if both pixels in a pair have the value of 255, you'll get 255 in a result clip, otherwise 0.
# OR : if any of pixels in a pair has the value of 255, you'l get 255, otherwise 0.
# XOR : if both pixels have the value of 255 or 0, you'l get 0, otherwise (if only one of the pixels is 255) 255.
# ANDN : you'll get 255 if and only if the first pixel is 255 and the second is 0.
#
#
# Function Definition:
# (
# clip a,
# clip b,
# string "mode"="and" ("and"/ "andn"/ "or"/ "xor"/ "min"/ "max")
# )
#
function ex_logic(clip a, clip b, string "mode", int "thx", int "thy", int "UV") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : true
bi32 = bi == 32
lut = bi > 12 || isRunTime(a,rgb) ? 0 : 2
mode = Default(mode, "and")
th1 = Default(thx, 0 ) # threshold for clip x in modes 'min' or 'max'
th2 = Default(thy, 0 ) # threshold for clip y in modes 'min' or 'max'
UV = Default(UV, rgb ? 3 : 1)
si = ex_UVf(rgb, bi)
th1 = th1 != 0 ? string(ex_bs(th1, 8, bi, fulls=fs))+" + " : ""
th2 = th2 != 0 ? string(ex_bs(th2, 8, bi, fulls=fs))+" + " : ""
str = \
mode == "and" ? bi32 ? "x y *" : "x y * range_max /" : \
mode == "or" ? "x y + range_min range_max clip" : \
mode == "xor" ? "x y - abs" : \
mode == "andn" ? bi32 ? "1 x - y *" : "range_max x - y * range_max /" : \
mode == "andnot"? bi32 ? "1 x - y *" : "range_max x - y * range_max /" : \
mode == "min" ? "x "+th1+" y "+th2+" min" : \
mode == "max" ? "x "+th1+" y "+th2+" max" : \
Assert (false, "ex_logic: Unsupported logic mode.")
cstr = ex_UVexpr(str, UV, bi, rgb, fs, si)
str = ex_dlut (str, bi, fs)
isy ? Expr(a, b, str , lut=lut) : \
UV == 1 ? Expr(a, b, str, "" , lut=lut) : \
Expr(a, b, str, cstr, scale_inputs=si, lut=lut) }
# The higher the mask value the more the second clip merges into the first (mask bitdepth scale should always saturate full range -ie. 65535 for 16-bit int-)
# mt_merge() is 5% slower on Y clips / masks
# 5% slower on luma=false for YUV clips / masks
# 8% faster on luma=true for YUV clips / masks
# 13% faster on luma=true for YUV clips Y masks
# 8% faster on luma=false for YUV clips Y masks
function ex_merge(clip a, clip b, clip msk, bool "luma", int "Y", int "UV") {
rgb = isRGB(a)
isya = isy(a)
isyb = isy(b)
isym = isy(msk)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
lm = Default(luma, isym && rgb)
Y = Default(Y, 3)
UV = Default(UV, isya ? 1 : rgb || lm ? 3 : 2)
si = ex_UVf(rgb, bi)
isRGB(msk) ? Assert (!lm, "ex_merge: 'luma=true' unsupported for RGB masks.") : nop()
b = isya && !isyb ? b.ExtractY() : \
!isya && isyb ? mskY_to_YYY(a, b, false, rgb, UV, bi) : b
msk = isya ? isym ? msk : \
ExtractY(msk) : \
lm || isym || \
width (msk)!=width (a) || \
height(msk)!=height(a) ? \
mskY_to_YYY(a, msk, lm, rgb, UV, bi) : msk
mr = bi > 14 ? "range_max /" : string(1. / Eval(ex_dlut("range_max", bi, true))) + " *"
str = bi == 32 ? "x dup y - z * -" : "x dup y - z "+mr+" * -"
cstr = ex_UVexpr( str, UV, bi, rgb, !(UV!=3 && !fs), si)
ystr = ex_Yexpr ( str, Y, bi, rgb, true , si)
isya ? Expr(a, b, msk, ystr, optSingleMode=false) : \
UV == 1 ? Expr(a, b, msk, ystr, "", optSingleMode=false) : \
Expr(a, b, msk, ystr, cstr, scale_inputs=si, optSingleMode=false) }
# mt_clamp() is 6% slower
function ex_clamp(clip a, clip hi, clip lo, int "overshoot", int "undershoot", int "UV") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
os = Default(overshoot, 0)
us = Default(undershoot, 0)
UV = Default(UV, rgb ? 3 : 1)
si = ex_UVf(rgb, bi)
os = ex_bs(os, 8, bi, fulls=fs)
us = ex_bs(us, 8, bi, fulls=fs)
str = (os == 0) && (us == 0) ? "x y min z max" : \
Format("x y {os} + min z {us} - max")
cstr = ex_UVexpr( str, UV, bi, rgb, fs, si)
isy ? Expr(a, hi, lo, str, optSingleMode=false) : \
UV == 1 ? Expr(a, hi, lo, str, "", optSingleMode=false) : \
Expr(a, hi, lo, str, cstr, scale_inputs=si, optSingleMode=false) }
# mt_binarize() is 12% slower than ex_binarize()
# mt_binarize() is 17% faster than ex_binarize(smooth=true)
# lo=-1 | hi=-1 replaces lo|hi with source "x"
#
# Dependencies:
# ResizersPack ('dynamic' and 'otsu' modes)
# TransformsPack (for RGB inputs)
#
# modes:
# simple - fixed static threshold
# dynamic - temporal stable dynamic threshold.
# otsu - simplified Otsu's method with 10 histogram bins
#
# Example:
# ex_binarize(10,hi=-1) # Cleaning/clamping faint values. Same as: "x < 10 ? 0 : x"
#
# Function Definition:
# (
# clip,
# float thres=115.0 (0.0 to 255.0 by 1),
# string "mode"="simple" ("simple"/ "dynamic"/ "otsu"),
# bool "smooth"=false,
# bool "invert"=false
# )
#
function ex_binarize(clip a, float "thres", bool "invert", bool "smooth", string "mode", int "lo", int "hi", int "UV", bool "fulls") {
w = width (a)
h = height(a)
rgb = isRGB (a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
lut = isRunTime (a,rgb) || bi==32 ? 0 : 1
isHD = (w > 1099 || h > 599 ) && !isy
isUHD= (w > 2599 || h > 1499) && !isy
th = Default(thres, 115)
lo = Default(lo, 0) # Value for under threshold (set to -1 to passthrough clip values)
hi = Default(hi, 255) # Value for above threshold (set to -1 to passthrough clip values)
in = Default(invert, false) # Use this for invert instead of lo=255 and hi=0
sm = Default(smooth, false)
md = Default(mode, "simple") # 'simple', 'dynamic' or 'otsu'
UV = Default(UV, 128) # Currently this is noop as chroma thresholding makes no sense
fs = Default(fulls, fs)
si = ex_UVf(rgb, bi)
th = ex_bs(th, 8, bi, fulls=fs, flt=true)
lox = lo < 0 hix = hi < 0
lox && hix ? Assert (false, "ex_binarize: 'lo' or 'hi': At least one bound should be binarized.") : nop()
bs = a. ConvertBits(8,dither=-1,fulls=fs) # Matrix assumed by dimensions
bs = rgb ? isUHD ? bs.DotClip([0.262372,0.678464,0.059164]) : \
isHD ? bs.DotClip([0.212600,0.715179,0.072221]) : \
bs.DotClip([0.298912,0.586603,0.114485]) : \
a. ConvertBits(8,dither=-1,fulls=fs)
a = rgb ? bs.ConvertBits(bi,fulls=fs) : a
br = w > 720 ? bs.RatioResize(720., "adjust2w", kernel="bilinear") : bs
isy = rgb || isy
if (md=="otsu") {
# Assumes TV range for YUV
bnth = (fs ? 255 : 219) / 10.
off = fs ? 0 : 16
rnm = 1. / 255
ScriptClip(a, function [br,bnth,off,rnm,in,sm,lo,hi,UV,fs] () {
thr1 =br.ex_binarize(bnth+off,true,UV=UV,fulls=fs)
bin1 =thr1.AverageLuma()
thr2 =bnth * 2 + off
thr2 =ex_lutxy(thr1,br,Format("range_max x - y {thr2} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin2 =thr2.AverageLuma()
thr3 =bnth * 3 + off
thr3 =ex_lutxy(thr2,br,Format("range_max x - y {thr3} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin3 =thr3.AverageLuma()
thr4 =bnth * 4 + off
thr4 =ex_lutxy(thr3,br,Format("range_max x - y {thr4} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin4 =thr4.AverageLuma()
thr5 =bnth * 5 + off
thr5 =ex_lutxy(thr4,br,Format("range_max x - y {thr5} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin5 =thr5.AverageLuma()
thr6 =bnth * 6 + off
thr6 =ex_lutxy(thr5,br,Format("range_max x - y {thr6} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin6 =thr6.AverageLuma()
thr7 =bnth * 7 + off
thr7 =ex_lutxy(thr6,br,Format("range_max x - y {thr7} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin7 =thr7.AverageLuma()
thr8 =bnth * 8 + off
thr8 =ex_lutxy(thr7,br,Format("range_max x - y {thr8} < range_max 0 ? {rnm} * *"), UV=1, fulls=true)
bin8 =thr8.AverageLuma()
thr9 =bnth * 9 + off
thr10=br.ex_lut(Format("x {thr9} > range_max 0 ?"), UV=1, fulls=true)
thr9 =ex_lutxy(thr8,thr10,Format("range_max x - range_max y - * {rnm} *"), UV=1, fulls=true)
bin9 =thr9.AverageLuma()
bin10=thr10.AverageLuma()
hist = [bin1, bin2, bin3, bin4, bin5, bin6, bin7, bin8, bin9, bin10]
for (t = 0, 9, 1) {
B = 0 F = 0 Mb = 0 Mf = 0
for (i = 0, t, 1) {
B = B + hist[i]
Mb = Mb + hist[i] * i
}
Mb = B != 0 ? Mb / B : 0
for (i = t+1, 9, 1) {
F = F + hist[i]
Mf = Mf + hist[i] * i
}
Mf = F != 0 ? Mf / F : 0
# Between class variance for each 't'
Eval(Format("th{t} = ((B * F)/pow(B+F,2)) * pow(Mb - Mf, 2) "))
}
th = max(max(max(max(max(max(max(max(max(th0,th1),th2),th3),th4),th5),th6),th7),th8),th9)
th = th == th0 ? 1 : th == th1 ? 2 : th == th2 ? 3 : th == th3 ? 4 : th == th4 ? 5 : th == th5 ? 6 : th == th6 ? 7 : th == th7 ? 8 : th == th8 ? 9 : 10
th = (th*bnth+off)-bnth*0.5
ex_binarize(th,in,sm,"simple",lo,hi,UV,fs)
} )
rgb ? CombinePlanes(last, planes="RGB") : last
} else if (md=="dynamic") {
ScriptClip(a, function [br,in,sm,lo,hi,UV,fs] () {
th = (AverageLuma(br,-2)+AverageLuma(br,0)+AverageLuma(br,2))*0.333333333
ex_binarize(th,in,sm,"simple",lo,hi,UV,fs)
} )
rgb ? CombinePlanes(last, planes="RGB") : last
} else {
if (sm) {
# same output than smoothstep but faster
bi32 = bi == 32
mx = ex_bs(255, 8, bi, fulls=fs, fulld=true)
thl = th * 0.9 thl = bi32 ? thl : round(thl)
thh = th * 1.1 thh = bi32 ? thh : round(thh)
thm = 1./(thh - thl)
lob = lox ? 0 : ex_bs(lo, 8, bi, fulls=fs, fulld=true)
hib = hix ? mx : ex_bs(hi, 8, bi, fulls=fs, fulld=true)
msk = Format("x {thl} - {thm} * 0 1 clip")
msk = in ? "1 "+msk+" -" : msk
str = Format( lox ? "x dup {hib} - "+msk+" * -" : \
hix ? "{lob} dup x - "+msk+" * -" : \
(in ? "1" : "")+" x {thl} - {thm} * 0 max "+(in?"-":"")+" range_max *" )
} else {
lob = lox ? "x" : string(ex_bs(lo, 8, bi, fulls=fs, fulld=true))
hib = hix ? "x" : string(ex_bs(hi, 8, bi, fulls=fs, fulld=true))
str = Format(in ? "x {th} < "+hib+" "+lob+" ?" : \
"x {th} > "+hib+" "+lob+" ?")
}
cstr = ex_UVexpr( str, UV, bi, rgb, fs, si)
isy ? Expr(a, str , lut=lut, clamp_float=sm && bi32 ) : \
UV == 1 ? Expr(a, str, "" , lut=lut, clamp_float=sm && bi32 ) : \
Expr(a, str, cstr, scale_inputs=si, lut=lut, clamp_float=sm && bi32 )
if (lo == 0 && hi == 255) {
prop = ["_Matrix","_Primaries","_Transfer","_PictType"]
propDelete(UV<4?prop:ArrayAdd(prop,"_ChromaLocation"))
propSet("_ColorRange", 0) }
sm ? ex_boxblur(0.5, mode="weighted", UV=1) : last } }
# Adaptive Threshold
#
# Useful for binary feature extraction under luminosity changes (ie. fonts in page scans)
# If you are not getting satisfactory results, try to upscale by 2
#
# modes:
# mean - Normally the default in most solutions, good for fonts or geometric shapes.
# gaussian - Cleaner output. Uses a gaussian approximation so it's faster than 'mean' (Default)
function ex_athres(clip a, float "th", float "sigma", bool "invert", string "mode", int "UV") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
lut = bi > 12 || isRunTime(a,rgb) ? 0 : 2
th = Default(th, 40)
sg = Default(sigma, 6) # sigma=6 is default for 1080p inputs
in = Default(invert, false)
md = Default(mode, "gaussian") # 'mean' or 'gaussian'
UV = Default(UV, rgb ? 3 : 128)
un = Undefined()
si = ex_UVf(rgb, bi)
sg = max(sg,0)
th = 1 - (th / 1000.)
# INTEGRAL
str = "x[-2,-2] x[-1,-2] x[0,-2] x[1,-2] + + + A@ x[2,-2] + B^
x[-2,-1] x[-1,-1] x[0,-1] x[1,-1] A + + + + C@ x[2,-1] B + + A - D^
x[-2,0] x[-1,0] x[0,0] x[1,0] C + + + + E@ x[2,0] D + + C - F^
x[-2,1] x[-1,1] x[0,1] x[1,1] E + + + + G@ x[2,1] F + + E - H^
x[-2,2] x[-1,2] x[0,2] x[1,2] + + + dup x[2,2] H dup G dup
+ + + + + + 0.012345679 *"
isy ? Expr(a, str ) : \
UV == 1 ? Expr(a, str, "" ) : \
Expr(a, str, ex_UVexpr(str, UV, bi, rgb, un, si), scale_inputs=si)
integral = last
# BLUR
md=="gaussian" ? ex_gaussianblur(sg,pad=false,UV=uv!=3?2:3) : ex_boxblur(ceil(sg*2),mode="mean",UV=uv!=3?2:3)
# THRESHOLD
str = Format("y x {th} * "+(in ? ">" : "<")+" 0 range_max ?")
isy ? Expr(last, integral, str , lut=lut) : \
UV == 1 ? Expr(last, integral, str, "" , lut=lut) : \
Expr(last, integral, str, ex_UVexpr(str, UV, bi, rgb, un), scale_inputs="none", lut=lut)
prop = ["_Matrix","_Primaries","_Transfer","_PictType"]
propDelete(UV<4?prop:ArrayAdd(prop,"_ChromaLocation"))
propSet("_ColorRange", 0) }
# mt_invert() is 10% slower and invert(channels="Y") is 17% slower
function ex_invert(clip a, bool "tv_range", int "UV") {
rgb = isRGB(a)
isy = isy(a)
bi = BitsPerComponent(a)
fs = propNumElements (a,"_ColorRange") > 0 ? \
propGetInt (a,"_ColorRange") == 0 : rgb
lut = bi == 32 ? 0 : 1
fs = Defined(tv_range) ? tv_range ? false : fs : fs
tv = Default(tv_range, false) # enable for non-scalar TV range clips
UV = Default(UV, rgb ? 3 : 1)
si = ex_UVf(rgb, bi)
if (tv) {
rmax = ex_bs(255, 8, bi, fulls=fs)
rdif = ex_bs( 4, 8, bi, fulls=fs)
rdifc= ex_bs( 1, 8, bi, fulls=fs)
tvr = rmax - rdif
tvcr = rmax + rdifc
str = Format("{tvr} x -")
cstr = Format("{tvcr} x -")
cstr = ex_UVexpr(cstr, UV, bi, rgb, fs, si)
} else {
str = "range_max x -"
cstr = ex_UVexpr(str, UV, bi, rgb, fs, si)
str = ex_dlut (str, bi, fs)
}
isy ? Expr(a, str , lut=lut) : \
UV == 1 ? Expr(a, str, "" , lut=lut) : \
Expr(a, str, cstr, scale_inputs=si, lut=lut) }