[Bug]: Invalid diagnostic when initializing readonly record with object as a field

[xlight05]

Description

$Subject. Consider the below code. Code works fine when we remoe readonly from the type def.

Consider the following code -

Getting following diagnostics from the compiler -
cannot initialize abstract object 'null'
too many arguments in call to 'new()'

type TokenHandler readonly & record {
    http:Client meow;
};

function foo() {
    TokenHandler handler = {
        meow: check new ("http://localhost:8080")
    };
}

Steps to Reproduce

No response

Affected Version(s)

No response

OS, DB, other environment details and versions

No response

Related area

-> Compilation

Related issue(s) (optional)

No response

Suggested label(s) (optional)

No response

Suggested assignee(s) (optional)

No response

[MaryamZi]

This is not a bug.

Since the field is in a readonly type, the type of the field is effectively http:Client & readonly, and when you use a readonly intersection with a non-readonly class you get an object type, not a class. So you can't use new to provide a value for such a field, because new isn't allowed with object types, only classes.

Moreover, new http:Client("http://localhost:8080") wouldn't work since it creates a mutable object, not an immutable one. You need to provide an immutable value that is also a subtype of http:Client.

Simplified sample:

class MutableObject {
    string url;

    function init(string url) returns error? {
        self.url = url;
    }
}

readonly class ImmutableObject {
    string url;

    function init(string url) returns error? {
        self.url = url;
    }
}

type TokenHandler readonly & record {
    MutableObject meow;
};

function foo() {
    TokenHandler _ = {
        meow: check new ("http://localhost:8080") // error
    };

    TokenHandler _ = {
        meow: check new ImmutableObject("http://localhost:8080") // OK
    };

    TokenHandler _ = {
        meow: object { // OK, constructed as immutable object
            string url = "http://localhost:8080";
        }
    };
}