How do you use compiler variants with opam-nix?

[frekw]

Hi!

I'm trying to get ocaml-variants working (wasocaml in particular) working with opam-nix.

I'm pretty new to both OCaml and opam-nix to this might be trivial and just me who am missing something.

I've tried adding wasocaml as to repos but am having a hard time to get the package installed properly:

{
  inputs = {
    opam-repository = {
      url = "github:ocaml/opam-repository";
      flake = false;
    };
    opam-nix.url = "github:tweag/opam-nix";
    opam-nix.inputs.opam-repository.follows = "opam-repository";
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.follows = "opam-nix/nixpkgs";
  };
  outputs = { self, flake-utils, opam-nix, opam-repository, nixpkgs }@inputs:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        on = opam-nix.lib.${system};
        localPackagesQuery = builtins.mapAttrs (_: pkgs.lib.last)
          (on.listRepo (on.makeOpamRepo ./.));
        devPackagesQuery = {
          # You can add "development" packages here. They will get added to the devShell automatically.
          ocaml-lsp-server = "*";
          ocamlformat = "*";
        };
        query = devPackagesQuery // {
          "ocaml-variants.4.14.1+wasocaml" = "*";

          # Or should I do something else, like this?
          # but that doesn't work either.
          # ocaml-variants = "4.14.1+wasocaml";
        };
        wasocaml = pkgs.fetchFromGitHub {
          owner = "ocamlpro";
          repo = "wasocaml-opam";
          rev = "8f835900925031618b09eac3cd6ca58a4ebe023c";
          sha256 = "sha256-gef1VRleVa9hfcJFnlC6ZKCFom+SuroJx8T9wHFRg0U=";
        };
        scope = on.buildOpamProject' {
          repos = ["${opam-repository}" "${wasocaml}"];
        } ./. query;
        overlay = final: prev:
          {
            # You can add overrides here
          };
        scope' = scope.overrideScope' overlay;
        # Packages from devPackagesQuery
        devPackages = builtins.attrValues
          (pkgs.lib.getAttrs (builtins.attrNames devPackagesQuery) scope');
        # Packages in this workspace
        packages =
          pkgs.lib.getAttrs (builtins.attrNames localPackagesQuery) scope';
      in {
        legacyPackages = scope';

        packages = packages // { default = packages.backend; };

        devShells.default = pkgs.mkShell {
          inputsFrom = builtins.attrValues packages;
          buildInputs = devPackages ++ [
            # You can add packages from nixpkgs here
          ];
        };
      });
}

Happy for any help or pointers! 🙏

[frekw]

I might've figured it out. Seems I need to pass --impure to everything, otherwise I end up with a git dependency without an explicit sha1 is not supported in pure evaluation mode error. Would be nice to solve that, but at least --impure seems to be working.

[balsoft]

Currently, an --impure is required due to this line: https://github.com/OCamlPro/wasocaml-opam/blob/main/packages/ocaml-variants/ocaml-variants.4.14.1%2Bwasocaml/opam#L22

It tells opam to fetch the latest version of wasocaml, which is obviously impure, and hence Nix requires you to pass --impure.

The proper fix would be to fetch the wasocaml repo yourself and get the package from there instead of using the wasocaml-opam repository, something like this:

        query = devPackagesQuery // {
          "ocaml-variants" = "4.14.1+trunk"; # This is the version in the .opam file of wasocaml repo: https://github.com/OCamlPro/wasocaml/blob/main/ocaml-variants.opam
        };
        wasocaml = pkgs.fetchFromGitHub {
          owner = "ocamlpro";
          repo = "wasocaml";
          rev = "da7fdbffa14ad6e4a01f385020aca44edcea2eb9";
          hash = "sha256-taQ5T2qGgXZLBe+ZF+4mSygeCtKtmYE12SOgOoUnZbk=";
        };
        scope = on.buildOpamProject' {
          repos = ["${opam-repository}" (makeOpamRepo "${wasocaml}")];
        } ./. query;

Alternatively, you can override the source of the package from the repo, something like this:

        wasocaml-src = pkgs.fetchFromGitHub {
          owner = "ocamlpro";
          repo = "wasocaml";
          rev = "da7fdbffa14ad6e4a01f385020aca44edcea2eb9";
          hash = "sha256-taQ5T2qGgXZLBe+ZF+4mSygeCtKtmYE12SOgOoUnZbk=";
        };
        overlay = final: prev:
          {
            ocaml-variants = prev.ocaml-variants.overrideAttrs (_: { src = wasocaml-src; });
          };

It would also be nice to open an issue upstream (https://github.com/OCamlPro/wasocaml-opam/issues) asking to provide at least one stable version in their repo.

[zapashcanon]

Hi!

FYI we would welcome any PR on wasocaml or wasocaml-opam to make the packaging easier. :)