settings.gradle

/*
 * Copyright 2014 Netflix, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

['fiat', 'kork'].each { prj ->
  String propName = "${prj}Composite"
  String projectPath = "../$prj"
  if (settings.ext.has(propName) && Boolean.parseBoolean(settings.ext.get(propName) as String)) {
    includeBuild projectPath
  }
}

rootProject.name = "front50"

include 'front50-web',
    'front50-api',
    'front50-api-tck',
    'front50-core',
    'front50-gcs',
    'front50-integration',
    'front50-redis',
    'front50-s3',
    'front50-sql',
    'front50-sql-mysql',
    'front50-sql-postgres',
    'front50-test',
    'front50-migrations',
    'front50-azure',
    'front50-swift',
    'front50-oracle',
    'front50-bom'

def setBuildFile(project) {
  project.buildFileName = "${project.name}.gradle"
  project.children.each {
    setBuildFile(it)
  }
}

rootProject.children.each {
  setBuildFile(it)
}

// Set as an ext variable so that build scripts can access it
gradle.ext.includedProviderProjects = includeProviders.split(',').collect{ ':front50-' + it.toLowerCase() }