Syntax Error when Popping the Link Register (using code from Docs)

[samneggs]

This is example code from the documentation. I get this error on the pop instruction.It doesn't like popping the lr.

@micropython.asm_thumb
def fib(r0):
    b(START)
    label(DOFIB)
    push({r1, r2, lr})
    cmp(r0, 1)
    ble(FIBDONE)
    sub(r0, 1)
    mov(r2, r0) # r2 = n -1
    bl(DOFIB)
    mov(r1, r0) # r1 = fib(n -1)
    sub(r0, r2, 1)
    bl(DOFIB)   # r0 = fib(n -2)
    add(r0, r0, r1)
    label(FIBDONE)
    pop({r1, r2, lr})
    bx(lr)
    label(START)
    bl(DOFIB)

Error:

MicroPython v1.22.2 on 2024-02-22; Raspberry Pi Pico with RP2040
SyntaxError: unsupported Thumb instruction 'pop' with 1 arguments

[samneggs]

ANSWER
Instead of

pop({lr})
bx(lr)

These are combined into:

pop({pc})

It takes the address in the link register and shoves it directly into the program counter.

[rkompass]

From the ARM architecture reference:

SP, the Stack Pointer

Register R13 is used as a pointer to the active stack.

In Thumb code, most instructions cannot access SP. The only instructions that can access SP are those designed to use SP as a stack pointer. The use of SP for any purpose other than as a stack pointer is deprecated. Note Using SP for any purpose other than as a stack pointer is likely to break the requirements of operating systems, debuggers, and other software systems, causing them to malfunction.

LR, the Link Register

Register R14 is used to store the return address from a subroutine. At other times, LR can be used for other purposes.

When a BL or BLX instruction performs a subroutine call, LR is set to the subroutine return address. To perform a subroutine return, copy LR back to the program counter. This is typically done in one of two ways, after entering the subroutine with a BL or BLX instruction:

• Return with a BX LR instruction.

• On subroutine entry, store LR to the stack with an instruction of the form: PUSH {,LR} and use a matching instruction to return: POP {,PC} ...

So your finding is correct, the example however is not (sorry I'm just repeating your statement to make this point again).
We may assume it once worked and then the assembler code got improved to be closer to the official ARM assembler rules and now it doesn't - and it was not automatically tested.

So this warrants a documentation issue, I estimate. Would you raise it?

[peterhinch]

The problem here may be that the docs - and the Assembler! - were written for the Pyboard (Arm V7) while the Pico is Arm V6. Note the floating point instructions, absent on the Pico. There are restrictions on what you can do with registers > r7.

[fanoush]

Just hit this on RP2040 too, when trying fib example from
https://docs.micropython.org/en/v1.22.0/reference/asm_thumb2_hints_tips.html#code-branches-and-subroutines

Both previous answers are a bit confusing but provide good hint.
As per https://developer.arm.com/documentation/dui0662/b/The-Cortex-M0--Instruction-Set/Memory-access-instructions/PUSH-and-POP
Cortex M0 pop instruction with register list can do only PC register, not LR (and push can do only LR, not PC) so the fixed fib method example is

@micropython.asm_thumb
def fib(r0):
    b(START)
    label(DOFIB)
    push({r1, r2, lr})
    cmp(r0, 1)
    ble(FIBDONE)
    sub(r0, 1)
    mov(r2, r0) # r2 = n -1
    bl(DOFIB)
    mov(r1, r0) # r1 = fib(n -1)
    sub(r0, r2, 1)
    bl(DOFIB)   # r0 = fib(n -2)
    add(r0, r0, r1)
    label(FIBDONE)
    pop({r1, r2, pc})
    label(START)
    bl(DOFIB)

so

    pop({r1, r2, lr})
    bx(lr)

is replaced by

    pop({r1, r2, pc})