Trouble understanding local variable effects and their relationship to effect polymorphism

[AZMCode]

Suppose there is the following koka code:

pub fun normal(fine: unit -> div unit): div list<int>
  var out := []
  for(0,10) fn(i)
    fine()
    out := Cons(i,out)
  out

pub fun local-inferred<e>(trouble: unit -> e unit): e list<int>
  var out := []
  for(0,10) fn(i)
    trouble()
    out := Cons(i,out)
  out

The code defines two very similar functions, yet one doesn't compile, with the error

effects do not match
context        :     trouble()
term           :     trouble()
inferred effect: <local<_h>|_e1>
expected effect: $e

This is, to my understanding, because the mutability of the internal variable out could potentially escape the 'local-inferred' function, due to the effects e could be representing.

I fail, however, to understand how trouble, without a reference to said mutable variable, could potentially cause mutable state to escape.

I'd appreciate help understanding this part.

Furthermore, I also want to ask how precisely one could make a function of this sort, being polymorphic over effects, while disallowing the troublesome effects that cause this issue to happen.

[TimWhiting]

This is a solution:

pub fun local-inferred<e>(trouble: () -> e ()): e list<int>
  var out := []
  for(0,10) fn(i)
    mask<local>{trouble()}
    out := Cons(i,out)
  out

fun main()
  val x = local-inferred() fn()
    "Hi".println
  x.show.println

As far as understanding the issue, it is more related to unification and inference and not that the trouble function has access to the mutable state.

I could give a stab at explaining the unification / type checking process, but I need to dig into it a bit more to understand myself why this happens. This is a common issue, and I wonder if there is something we could do to improve local var inference in particular. Anyways I hope the sample solution helps you in the meantime. Masking is also useful in general, when you come across an error like this.

[AZMCode]

While masking appears to work on this simple example, the more complicated project I'm working on (which this example was inspired by) appears to have other issues besides this. Regardless, this is an answer to the initial question and will mark it as such. I'll open another discussion asking a bit more about the other issue when I get the chance, after breaking it down to understand why that happens. Thanks a lot for the answer, I'll read up more on masking to understand exactly why this happens too.