Ctrl-r for shell history but also bulk select and remove from history

[rieje]

Ctrl-r is super useful for shell history but along with Enter to insert the command to the prompt, I would like (within the same Ctrl-r interface, preferably) to also switch to interface where selecting an entry removes it from history. It should support selecting multiple entries and repeat filtering to select additional entries to remove (only except with e.g. Ctrl-c).

Any ideas on how to implement this if it's not implemented already?

[LangLangBart]

This setup requires 3 things:

• a modified fzf-history-widget
• the assigned FZF_CTRL_R_OPTS environment variable with a complex keybinding for deletion and
  reloading
• assigned HISTFILE, HISTSIZE, and SAVEHIST environment variables

Note

The values assigned to FZF_CTRL_R_OPTS can also be incorporated into the modified
fzf-history-widget. However, I found this method simpler to avoid complications with quotation
marks.

If you place everything in your .zshrc, after sourcing the fzf/shell/key-bindings.zsh file,
it should work seamlessly. The history will always be read from your $HISTFILE, thus I also set
these options:

setopt INC_APPEND_HISTORY  # Write to the history file immediately, not when the shell exits.
setopt SHARE_HISTORY  # Share history between all sessions.

More details on how the deletion works can be found in: #3522

modified-fzf-history-widget() {
  local selected
  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases no_bash_rematch 2> /dev/null
  # appends the current shell history buffer to the HISTFILE
  builtin fc -AI $HISTFILE
  # pushes entries from the $HISTFILE onto a stack and uses this history
  builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST
  selected="$(builtin fc -rl 1 |
    awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, "", cmd); if (!seen[cmd]++) print $0 }' |
    FZF_DEFAULT_OPTS="--height ${FZF_TMUX_HEIGHT:-40%} ${FZF_DEFAULT_OPTS-} -n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,ctrl-z:ignore ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} --multi" $(__fzfcmd))"
  local ret=$?
	if [[ -n $selected ]]; then
    if [[ "$selected" =~ ^[[:blank:]]*[[:digit:]]+ ]]; then
	  builtin fc -pa "$HISTFILE"
	  zle vi-fetch-history -n "$MATCH"
    else # selected is a custom query, not from history
      LBUFFER="$selected"
    fi
  fi
  # Read the history from the history file into the history list
  builtin fc -R $HISTFILE
  zle reset-prompt
  return $ret
}
zle -N modified-fzf-history-widget
bindkey "^R" modified-fzf-history-widget


export FZF_CTRL_R_OPTS="$(
	cat <<'FZF_FTW'
--bind "ctrl-d:execute-silent(zsh -ic 'builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; for i in {+1}; do ignore+=( \"${(b)history[$i]}\" );done;
	HISTORY_IGNORE=\"(${(j:|:)ignore})\";builtin fc -W $HISTFILE')+reload:builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; builtin fc -rl 1 |
	awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, \"\", cmd); if (!seen[cmd]++) print $0 }'"
--bind 'enter:accept-or-print-query'
--header 'enter select · ^d remove'
--prompt ' Global History > '
FZF_FTW
)"


# 'ZDOTDIR' is a Parameter used by the shell, it refers to the location of your 
# shell startup files (see 'man zshparam')
export HISTFILE="${ZDOTDIR:-$HOME}"/.zsh_history
export HISTSIZE=12000
export SAVEHIST=10000

EDIT: use builtin and read history when exiting fzf widget

[junegunn]

Thanks. Would it be possible to merge execute-silent and reload?

[LangLangBart]

The fc -W command needs to be run interactively (zsh -ic)

man zshbuiltins
# fc -ARWI [ filename ]
#        The fc command controls the interactive history mechanism.  Note
#        that reading and writing of history options is only performed if
#        the shell is interactive.  Usually this  is  detected  automati-
#        cally,  but  it can be forced by setting the interactive option
#        when starting the shell.

However, when I attempt to run it with reload, it blocks

: | fzf --bind "ctrl-b:reload:zsh -ic 'echo 4'"

[junegunn]

Huh, that's strange. I'll look into it.

---

This gives an even weirder result.

: | fzf --bind "ctrl-b:reload:zsh -ic 'echo 4'; echo 5"

Seems related: jonas/tig#951

(execute-silent doesn't set pgid, but reload does)