publish.gradle

import org.gradle.api.XmlProvider
import org.gradle.api.artifacts.maven.MavenDeployment

apply plugin: 'maven'
apply plugin: 'signing'

group = 'com.underwaterapps.overlap2druntime'

version = '0.1.1'
ext.packaging = 'jar'

def isDevBuild
def isCiBuild
def isReleaseBuild

def sonatypeRepositoryUrl

//set build variables based on build type (release, continuous integration, development)
if(hasProperty("release")) {
    isReleaseBuild = true
    sonatypeRepositoryUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
    println "Performing release build"
} else if (hasProperty("snapshot")) {
    isCiBuild = true
    version += "-SNAPSHOT"
    sonatypeRepositoryUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
    println "Performing snapshot build"
} else {
    isDevBuild = true
    println "Performing local build"
}

repositories {
    mavenCentral()
}

task artifactDocs(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

task artifactSources(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives artifactDocs
    archives artifactSources
}

if(isReleaseBuild) {
    signing {
        sign configurations.archives
    }
} else {
    task signArchives {
        // do nothing
    }
}

uploadArchives {
    repositories {
        if (isDevBuild) {
            mavenLocal()
        }
        else {
            mavenDeployer {
                if(isReleaseBuild) {
                    beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                }

                repository(url: sonatypeRepositoryUrl) {
                  authentication(userName: sonatypeUsername, password: sonatypePassword)
                }

                pom.version = version
                pom.packaging = 'jar'

                pom.project {
                   name 'overlap2d-runtime-libgdx'
                   description 'overlap2d-runtime-libgdx provides functionality to load, manipulate and render scenes generated by Overlap2D.'
                   url 'https://github.com/UnderwaterApps/overlap2d-runtime-libgdx'

                   scm {
                       url 'scm:git@github.com:UnderwaterApps/overlap2d-runtime-libgdx.git'
                       connection 'scm:git@github.UnderwaterApps/overlap2d-runtime-libgdx.git'
                       developerConnection 'scm:git@github.com:UnderwaterApps/overlap2d-runtime-libgdx.git'
                   }

                   licenses {
                       license {
                           name 'The Apache Software License, Version 2.0'
                           url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                           distribution 'repo'
                       }
                   }

                   developers {
                       developer {
                           id 'gevorg.kopalyan'
                           name 'Gevorg Kopalyan'
						               email 'gevorg.kopalyan@gmail.com'
                       }
                       developer {
                           id 'azakhary'
                           name 'Avetis Zakharyan'
                           email 'avetis.zakharyan@gmail.com'
                       }
                   }
               }
            }
        }
    }
}