/
configure.ac
1047 lines (905 loc) · 30.4 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
dnl
dnl Setup autoconf
dnl
AC_PREREQ([2.68])
m4_define([gap_version], [4.14dev])
m4_define([gap_releaseday], [today])
m4_define([gap_releaseyear], [this year])
m4_define([gap_tarname], [gap-gap_version])
dnl
dnl library version
dnl
dnl The version of the libgap shared library as well as the kernel version are
dnl tracked here, and follow more or less semver (semantic versioning).
dnl When making a new GAP release, these values need to be adjusted, based on
dnl the following rules:
dnl
dnl 1. If any interfaces have been removed or changed since the last public
dnl release, then increment major and set minor to 0.
dnl 2. Otherwise (i.e., if no interfaces have been removed or changed),
dnl if any interfaces have been added since the last public release, then
dnl increment minor.
dnl
m4_define([kernel_major_version], [9])
m4_define([kernel_minor_version], [0])
m4_define([GAP_DEFINE], [GAP_DEFINES="$GAP_DEFINES -D$1"])
AC_INIT([GAP],
gap_version,
[support@gap-system.org],
gap_tarname,
[https://www.gap-system.org/])
AC_CONFIG_SRCDIR([src/gap.c])
AC_CONFIG_AUX_DIR([cnf])
dnl we do not use AC_CONFIG_MACRO_DIR but rather a manually created aclocal.m4;
dnl this is in parts because autoreconf and aclocal are only available via GNU automake,
dnl which we do not use; but also because there is no obvious benefit to using it.
AC_CONFIG_HEADERS([build/config.h:src/config.h.in])
AC_CONFIG_COMMANDS([build/stamp-h], [echo timestamp > build/stamp-h])
AS_IF([test "x$srcdir" = x.],
[AC_MSG_NOTICE([in-tree build])],
[AC_MSG_NOTICE([out-of-tree build])])
dnl note that the final version used by the GAP kernel is GAP_BUILD_VERSION
dnl and is computed by cnf/gap-version-gen.sh, which takes git commit hashes into
dnl account to produce a more fine-grained version string for GAP development
dnl versions.
AC_SUBST([GAP_VERSION], "gap_version")
AC_SUBST([GAP_RELEASEDAY], "gap_releaseday")
AC_SUBST([GAP_RELEASEYEAR], "gap_releaseyear")
dnl
dnl Get canonical host information
dnl
AC_CANONICAL_HOST
dnl
dnl Check for working C and C++ compiler; insist on C99 and C++11 support
dnl
dnl In autoconf <= 2.69, we use AC_PROG_CC_C99; in autoconf >= 2.70, this
dnl is deprecated, and AC_PROG_CC subsumes it. We have to use some M4 code
dnl to deal with this in way that retains support for autoconf 2.69 while
dnl avoiding warnings in autoconf >= 2.70
m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), -1,
[AC_PROG_CC_C99],
[AC_PROG_CC])
AC_PROG_CXX
AX_CXX_COMPILE_STDCXX(11)
AC_LANG([C])
dnl
dnl ABI settings
dnl
AC_ARG_VAR(ABI, [Set this equal to 32 or 64 to build GAP (and GMP provided you
do not deselect it) in 32- or 64-bit mode. The default value
for this option is determined by testing the behaviour of your
compiler, so should be 32 on a 32-bit system and 64 on one
which is 64-bit. If this is unset, the build system will set
a value of 64 or 32 depending of the pointer size of the host.])
AC_MSG_CHECKING([ABI flags])
if test "x$ABI" = "x" ; then
ABI_CFLAGS=""
elif test "$ABI" = "64"; then
ABI_CFLAGS="-m64"
elif test "$ABI" = "32"; then
ABI_CFLAGS="-m32"
else
AC_MSG_ERROR([ $ABI is not a supported value for ABI. The supported values are ABI=64
or 32.])
fi
AC_MSG_RESULT([$ABI_CFLAGS])
AC_SUBST([ABI_CFLAGS])
dnl Start using ABI_CFLAGS *now*, so that all configure tests we
dnl run from here on use it.
AS_IF([test -n $ABI_CFLAGS],[
CC="$CC $ABI_CFLAGS"
CXX="$CXX $ABI_CFLAGS"
dnl Verify that the ABI_CFLAGS didn't break anything
AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[]],[])],
[],
[AC_MSG_ERROR([ABI_CFLAGS="$ABI_CFLAGS" not supported])]
)
])
dnl determine pointer sizes to distinguish 32 and 64 bit systems.
AC_CHECK_SIZEOF([void *])
dnl ensure that ABI and sizeof(void *) match
AC_MSG_CHECKING([ABI bit size])
if test "x$ABI" = "x" ; then
if test $ac_cv_sizeof_void_p = 8; then
ABI="64"
else
ABI="32"
fi
elif test "$ABI" = "32"; then
if test $ac_cv_sizeof_void_p != 4; then
AC_MSG_ERROR([ ABI=32 used by sizeof(void *) != 4.])
fi
elif test "$ABI" = "64"; then
if test $ac_cv_sizeof_void_p != 8; then
AC_MSG_ERROR([ ABI=64 used by sizeof(void *) != 8.])
fi
fi
AC_MSG_RESULT([$ABI])
AC_SUBST([ABI])
dnl
dnl Miscellaneous tools
dnl
AC_PROG_INSTALL
AC_PROG_MKDIR_P
dnl
dnl Check for properties of the host system and compiler
dnl
dnl endianness
AC_C_BIGENDIAN
dnl C/C++ attributes with GNU syntax (i.e., `__attribute__(FOO)`)
AX_GCC_FUNC_ATTRIBUTE([always_inline])
AX_GCC_FUNC_ATTRIBUTE([constructor])
AX_GCC_FUNC_ATTRIBUTE([fallthrough])
AX_GCC_FUNC_ATTRIBUTE([format])
AX_GCC_FUNC_ATTRIBUTE([noinline])
AX_GCC_FUNC_ATTRIBUTE([noreturn])
AX_GCC_FUNC_ATTRIBUTE([pure])
dnl compiler builtins
AC_DEFUN([CHECK_COMPILER_BUILTIN],
[AC_MSG_CHECKING([for $1])
AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[]],
[int x; $1[($2)];
]
)],
[AS_VAR_SET([[have_]$1], [yes])],
[AS_VAR_SET([[have_]$1], [no])]
)
AC_MSG_RESULT(AS_VAR_GET([[have_]$1]))
AS_IF([test yes = AS_VAR_GET([[have_]$1])],
[AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_]$1), 1,
[Define to 1 if the system has the `]$1[' built-in function])], []
)])
CHECK_COMPILER_BUILTIN([__builtin_mul_overflow],[0,0,&x]);
CHECK_COMPILER_BUILTIN([__builtin_clz],[0]);
CHECK_COMPILER_BUILTIN([__builtin_clzl],[0]);
CHECK_COMPILER_BUILTIN([__builtin_clzll],[0]);
CHECK_COMPILER_BUILTIN([__builtin_popcountl],[0]);
dnl determine sizeof of some standard types, so that the GAP headers
dnl can pick the correct builtins among those we just tested
AC_CHECK_SIZEOF([int])
AC_CHECK_SIZEOF([long])
AC_CHECK_SIZEOF([long long])
dnl
dnl User settings
dnl
dnl
dnl User setting: HPC-GAP mode (off by default)
dnl
dnl If on, build an HPCGAP executable instead of standard GAP.
dnl
AC_ARG_ENABLE([hpcgap],
[AS_HELP_STRING([--enable-hpcgap], [enable HPC-GAP])],
[],
[enable_hpcgap=no])
AC_MSG_CHECKING([whether to enable HPC-GAP])
AC_MSG_RESULT([$enable_hpcgap])
AC_SUBST([HPCGAP], [$enable_hpcgap])
AS_IF([test "x$enable_hpcgap" = xyes],
[
GAP_DEFINE([HPCGAP=1])
# HACK, see https://github.com/fingolfin/gap/issues/9
GAP_DEFINE([MAX_GC_THREADS=4])
])
dnl
dnl User setting: garbage collector to use
dnl
AC_ARG_WITH([gc],
[AS_HELP_STRING([--with-gc@<:@=default|gasman|boehm|julia@:>@],
[specify which garbage collector to use (default: gasman; for HPC-GAP: boehm)])],
[],
[with_gc=default])
dnl
dnl User setting: whether to link against Julia
dnl
dnl This comes here as it interacts with the garbage collector settings.
dnl The actual handling of with_julia comes at a later point.
dnl
AC_ARG_WITH([julia],
[AS_HELP_STRING([--with-julia@<:@=PATH@:>@],
[specify a julia binary or a prefix for a julia binary])],
[],[
AS_IF([test "x$with_gc" = xjulia],
[
with_julia=yes
],
[
with_julia=no
])
])
dnl handle the garbage collector setting
AC_MSG_CHECKING([which garbage collector to use])
AS_IF([test "x$with_gc" = xyes], [with_gc=default])
AS_IF([test "x$with_gc" = xdefault],
[
with_gc=gasman
AS_IF([test "x$enable_hpcgap" = xyes], [with_gc=boehm])
AS_IF([test "x$with_julia" != xno], [with_gc=julia])
])
AS_CASE([$with_gc],
[none|no], [AC_MSG_ERROR([cannot run GAP without a garbage collector])],
[boehm], [AC_SUBST([GC_SOURCES], [src/boehm_gc.c])
GAP_DEFINE([USE_BOEHM_GC=1])
],
[gasman], [AS_IF([test "x$enable_hpcgap" = xyes],
[AC_MSG_ERROR([GASMAN cannot be used with HPC-GAP])])
AC_SUBST([GC_SOURCES], ["src/gasman.c src/sysmem.c"])
GAP_DEFINE([USE_GASMAN=1])
],
[julia], [AC_SUBST([GC_SOURCES], [src/julia_gc.c])
GAP_DEFINE([USE_JULIA_GC=1])
],
[*], [AC_MSG_ERROR([Invalid gc method '$with_gc', use default|none|gasman|boehm|julia])],
)
AC_MSG_RESULT([$with_gc])
dnl
dnl User setting: native thread-local storage (off by default)
dnl See src/hpc/tls.h for more details on thread-local storage options.
dnl
AC_ARG_ENABLE([native-tls],
[AS_HELP_STRING([--enable-native-tls],
[use native thread-local storage implementation])],
[enable_native_tls=$enableval],
[enable_native_tls=no])
AC_MSG_CHECKING([whether to use native tls])
dnl
dnl Distinguish between cases where we support __thread declarations
dnl and situations where we use a pthread_getspecific() implementation.
dnl Right now, we only do the latter for 64-bit macOS. See src/hpc/tls.h
dnl for details.
dnl
enable_macos_tls_asm=default
AS_IF([[test "x$enable_native_tls" = "xyes"]], [
case "$host" in
x86_64-apple-darwin*)
GAP_DEFINE([USE_PTHREAD_TLS=1])
dnl
dnl Test if we can optimize pthread_getspecific() calls via
dnl inline assembly on macOS.
dnl
AC_RUN_IFELSE(
[AC_LANG_SOURCE([[
// The following code also occurs in src/hpc/thread.c and both need to be
// kept in sync.
#include <pthread.h>
#include <string.h>
#define OFFS 0x100
#define END (-1)
int cmpOpCode(unsigned char *code, int *with) {
int result = 0;
while (*with >= 0) {
if (*with == OFFS) {
result = *code;
} else {
if (*code != *with)
return -1;
}
code++;
with++;
}
return result;
}
int main() {
// This is an idea borrowed from Mono. We test if the implementation
// of pthread_getspecific() uses the assembly code below. If that is
// true, we can replace calls to pthread_getspecific() with the
// matching inline assembly, allowing a significant performance boost.
#if defined(__APPLE__) && defined(__x86_64__)
// There are two possible implementations.
static int asm_code[] = {
// movq %gs:[OFFS](,%rdi,8), %rax
// retq
0x65, 0x48, 0x8b, 0x04, 0xfd, OFFS, 0x00, 0x00, 0x00, 0xc3, END
};
static int asm_code2[] = {
// pushq %rbp
// movq %rsp, %rbp
// movq %gs:[OFFS](,%rdi,8),%rax
// popq %rbp
// retq
0x55, 0x48, 0x89, 0xe5, 0x65, 0x48, 0x8b, 0x04, 0xfd, OFFS,
0x00, 0x00, 0x00, 0x5d, 0xc3, END
};
if (cmpOpCode((unsigned char *)pthread_getspecific, asm_code) >= 0) {
return 0;
}
if (cmpOpCode((unsigned char *)pthread_getspecific, asm_code2) >= 0) {
return 0;
}
return 1;
#else
#error FAIL
#endif
}
]])],
dnl => Test succeeded
[GAP_DEFINE([USE_MACOS_PTHREAD_TLS_ASM=1])
AC_MSG_RESULT([[yes (macOS assembly)]])
enable_macos_tls_asm=yes
],
dnl => Test failed
[AC_MSG_RESULT([[yes (pthread-based)]])
enable_macos_tls_asm=no
],
dnl => Cross-compilation, test impossible
[AC_MSG_RESULT([[yes (pthread-based)]])
enable_macos_tls_asm=no
])
;;
*)
dnl => Any other OS, --with-native-tls specified
GAP_DEFINE([USE_NATIVE_TLS=1])
AC_MSG_RESULT([yes])
;;
esac
],
[
dnl => --without-native-tls
AC_MSG_RESULT([no])
]
)
dnl
dnl Test if pthread_getspecific() can be overridden as
dnl __attribute__((pure)).
dnl
AS_IF([test "x$enable_hpcgap" = xyes],[
AC_MSG_CHECKING([[whether pthread_getspecific() can be made pure]])
AC_COMPILE_IFELSE(
[AC_LANG_SOURCE([[
#include <pthread.h>
__attribute__((pure))
void * pthread_getspecific(pthread_key_t key);
]])], [
AC_MSG_RESULT(yes)
GAP_DEFINE([ALLOW_PURE_PTHREAD_GETSPECIFIC=1])
], [
AC_MSG_RESULT(no)
])
])
dnl
dnl User setting: Debug mode (off by default)
dnl
AC_ARG_ENABLE([debug],
[AS_HELP_STRING([--enable-debug], [enable debug mode])],
[],
[enable_debug=no]
)
AC_MSG_CHECKING([whether to enable debug mode])
AC_MSG_RESULT([$enable_debug])
AS_IF([test "x$enable_debug" != "xno"],
[GAP_DEFINE([GAP_KERNEL_DEBUG=1])
GAP_DEFINE([GAP_PRINT_BACKTRACE=1])],
)
dnl
dnl Maintainer mode (on by default) controls whether our build system
dnl automatically regenerates `configure` if `configure.ac` or any of its
dnl other sources changes, by running `autoconf`. Similarly, it regenerates
dnl `src/config.h.in` if necessary by running `autoheader`.
dnl
dnl While this is very useful when developing GAP, it can be problematic if
dnl a user wants to compile a release version of GAP but does not have
dnl autoconf installed; or if for some reason the GAP source code is readonly
dnl and they want to run an out-of-tree build. Thus we allow turning this
dnl off.
AC_ARG_ENABLE([maintainer-mode],
[AS_HELP_STRING([--disable-maintainer-mode], [disable maintainer mode])],
[],
[enable_maintainer_mode=yes]
)
AC_MSG_CHECKING([whether to enable maintainer-mode mode])
AC_MSG_RESULT([$enable_maintainer_mode])
AC_SUBST([MAINTAINER_MODE], [$enable_maintainer_mode])
dnl
AC_ARG_ENABLE([memory-checking],
[AS_HELP_STRING([--enable-memory-checking], [enable memory checking])],
[],
[enable_memory_checking=no]
)
AC_MSG_CHECKING([whether to enable memory checking])
AC_MSG_RESULT([$enable_memory_checking])
AS_IF([test "x$enable_memory_checking" != "xno"],
[GAP_DEFINE([GAP_MEM_CHECK=1])]
)
dnl
AC_ARG_ENABLE([valgrind],
[AS_HELP_STRING([--enable-valgrind], [enable valgrind extensions to GASMAN])],
[],
[enable_valgrind=no]
)
AC_MSG_CHECKING([whether to enable valgrind extensions to GASMAN])
AC_MSG_RESULT([$enable_valgrind])
AS_IF([test "x$enable_valgrind" != "xno"],
[GAP_DEFINE([GAP_MEMORY_CANARY=1])]
)
if test "x$enable_valgrind" != "xno" -a "x$enable_memory_checking" != "xno"; then
AC_MSG_ERROR([--enable-valgrind and --enable-memory-checking cannot be used at the same time])
fi
if test "x$with_gc" != "xgasman"; then
if test "x$enable_valgrind" != "xno" -o "x$enable_memory_checking" != "xno"; then
AC_MSG_ERROR([--enable-valgrind and --enable-memory-checking are only compatible with GASMAN])
fi
fi
dnl
dnl User setting: Enable -Werror (off by default)
dnl
AC_ARG_ENABLE([Werror],
AS_HELP_STRING([--enable-Werror], [treat compiler warnings as errors]),
[],
[enable_Werror=no])
AC_MSG_CHECKING([whether to treat C compiler warnings as errors])
AC_MSG_RESULT([$enable_Werror])
AS_IF([test "x$enable_Werror" != "xno"],
[ax_enable_compile_warnings=error],
[ax_enable_compile_warnings=yes])
AX_COMPILER_WARNING_FLAGS
dnl
dnl User setting: Enable popcnt (on by default)
dnl
AC_ARG_ENABLE([popcnt],
AS_HELP_STRING([--enable-popcnt], [use __builtin_popcountl if available]),
[],
[enable_popcnt=yes])
AC_MSG_CHECKING([whether to try and use __builtin_popcountl])
AC_MSG_RESULT([$enable_popcnt])
AS_IF([test "x$enable_popcnt" != "xno"],
[USE_POPCNT=1],
[USE_POPCNT=0])
AC_DEFINE_UNQUOTED([USE_POPCNT],
[$USE_POPCNT],
[define as 1 if we should try and use the __builtin_popcountl function if available])
dnl
dnl External dependencies
dnl
# We support finding dependencies in certain non-standard locations:
# Homebrew on macOS: $(brew --prefix) (usually /opt/homebrew or /usr/local)
# Fink on macOS: /sw
# MacPorts: /opt/local
HOMEBREW_PREFIX="$(brew --prefix 2>/dev/null || :)"
DEFAULT_SEARCH_PATH="$HOMEBREW_PREFIX /opt/local /sw"
dnl Find GMP
AC_ARG_WITH([gmp],
[AS_HELP_STRING([--with-gmp@<:@=builtin|PREFIX@:>@],
[prefix of GMP installation. e.g. /usr/local; specify `builtin' to let GAP builds its own version of GMP])],
[],[with_gmp=yes])
BUILD_GMP=no
GMP_SEARCH_PATH="DEFAULTS ${DEFAULT_SEARCH_PATH}"
GMP_CPPFLAGS=
GMP_LDFLAGS=
GMP_LIBS="-lgmp"
GMP_PREFIX=
AS_CASE([$with_gmp],
[builtin],[
# user explicitly requested to use builtin GMP
GMP_SEARCH_PATH=""
AC_MSG_NOTICE([Using bundled GMP])
],
[no],[
AC_MSG_ERROR([Building without GMP is not supported])
],
[system],[
dnl supported for backwards compatibility with old build system
with_gmp=yes
],
[yes],[],
[*],[
GMP_SEARCH_PATH="$with_gmp"
]
)
save_CFLAGS=${CFLAGS}
save_LIBS=${LIBS}
AC_MSG_CHECKING([for GMP])
gmp_found=no
for GMP_PREFIX in ${GMP_SEARCH_PATH} ; do
AS_IF([test "$GMP_PREFIX" != "DEFAULTS"],[
GMP_CPPFLAGS="-I${GMP_PREFIX}/include"
GMP_LDFLAGS="-L${GMP_PREFIX}/lib"
],[
GMP_PREFIX=""
GMP_CPPFLAGS=""
GMP_LDFLAGS=""
])
CFLAGS="${GMP_CPPFLAGS} ${save_CFLAGS}"
LIBS="${GMP_LDFLAGS} ${GMP_LIBS} ${save_LIBS}"
AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[#include <gmp.h>]],
[[mpz_t a; mpz_init (a);]])],
[gmp_found=yes
AS_IF([test x"$GMP_PREFIX" != x""],[
AC_MSG_RESULT([yes, at prefix ${GMP_PREFIX}])
],[
AC_MSG_RESULT([yes, in default search path])
])
break],
)
done
CFLAGS=${save_CFLAGS}
LIBS=${save_LIBS}
# Fall back to bundled GMP if necessary
AS_IF([test x$gmp_found = xno],[
AC_MSG_RESULT([build bundled copy])
BUILD_GMP=yes
GMP_PREFIX='${abs_builddir}/extern/install/gmp'
GMP_CPPFLAGS='-I${abs_builddir}/extern/install/gmp/include'
GMP_LDFLAGS='-L${abs_builddir}/extern/install/gmp/lib'
GMP_LIBS='-Wl,-rpath,${abs_builddir}/extern/install/gmp/lib -lgmp'
])
AC_SUBST([BUILD_GMP])
AC_SUBST([GMP_CPPFLAGS])
AC_SUBST([GMP_LDFLAGS])
AC_SUBST([GMP_LIBS])
AC_SUBST([GMP_PREFIX])
dnl Find zlib
AC_ARG_WITH([zlib],
[AS_HELP_STRING([--with-zlib@<:@=builtin|PREFIX@:>@],
[prefix of zlib installation. e.g. /usr/local; specify `builtin' to let GAP builds its own version of zlib])],
[],[with_zlib=yes])
BUILD_ZLIB=no
ZLIB_SEARCH_PATH="DEFAULTS ${DEFAULT_SEARCH_PATH}"
ZLIB_CPPFLAGS=
ZLIB_LDFLAGS=
ZLIB_LIBS="-lz"
AS_CASE([$with_zlib],
[builtin],[
# user explicitly requested to use builtin zlib
ZLIB_SEARCH_PATH=""
AC_MSG_NOTICE([Using bundled zlib])
],
[no],[
AC_MSG_ERROR([Building without zlib is not supported])
],
[system],[
dnl supported for backwards compatibility with old build system
with_zlib=yes
],
[yes],[],
[*],[
ZLIB_SEARCH_PATH="$with_gmp"
]
)
save_CFLAGS=${CFLAGS}
save_LIBS=${LIBS}
AC_MSG_CHECKING([for zlib])
zlib_found=no
for ZLIB_PREFIX in ${ZLIB_SEARCH_PATH} ; do
AS_IF([test "$ZLIB_PREFIX" != "DEFAULTS"],[
ZLIB_CPPFLAGS="-I${ZLIB_PREFIX}/include"
ZLIB_LDFLAGS="-L${ZLIB_PREFIX}/lib"
],[
ZLIB_PREFIX=""
ZLIB_CPPFLAGS=""
ZLIB_LDFLAGS=""
])
CFLAGS="${ZLIB_CPPFLAGS} ${save_CFLAGS}"
LIBS="${ZLIB_LDFLAGS} ${ZLIB_LIBS} ${save_LIBS}"
AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[#include <zlib.h>]],
[[z_stream a; inflateEnd(&a);]])],
[zlib_found=yes
AS_IF([test x"$ZLIB_PREFIX" != x""],[
AC_MSG_RESULT([yes, at prefix ${ZLIB_PREFIX}])
],[
AC_MSG_RESULT([yes, in default search path])
])
break],
)
done
CFLAGS=${save_CFLAGS}
LIBS=${save_LIBS}
# Fall back to bundled zlib if necessary
AS_IF([test x$zlib_found = xno],[
AC_MSG_RESULT([build bundled copy])
BUILD_ZLIB=yes
ZLIB_CPPFLAGS='-I${abs_builddir}/extern/install/zlib/include'
ZLIB_LDFLAGS='-L${abs_builddir}/extern/install/zlib/lib'
ZLIB_LIBS='-Wl,-rpath,${abs_builddir}/extern/install/zlib/lib -lz'
])
AC_SUBST([BUILD_ZLIB])
AC_SUBST([ZLIB_CPPFLAGS])
AC_SUBST([ZLIB_LDFLAGS])
AC_SUBST([ZLIB_LIBS])
dnl Find GNU readline
AC_ARG_WITH([readline],
[AS_HELP_STRING([--with-readline@<:@=PREFIX@:>@],
[support fancy command line editing via GNU readline; optionally
specify a prefix where it can be found])],
[],[with_readline=check])
READLINE_SEARCH_PATH="DEFAULTS DEFAULTS_EREADLINE $HOMEBREW_PREFIX/opt/readline ${DEFAULT_SEARCH_PATH}"
READLINE_CPPFLAGS=
READLINE_LDFLAGS=
READLINE_LIBS=
AS_CASE([$with_readline],
[no],[
READLINE_SEARCH_PATH=""
],
[check],[],
[yes],[],
[*],[
READLINE_SEARCH_PATH="$with_readline"
]
)
dnl Now check if we can find GNU readline. We go to some extra efforts to
dnl ensure it is GNU readline, and not e.g. BSD editline wrappers for
dnl readline, which do not suffice for GAP.
dnl
dnl note that OpenBSD installs modern (v6+) GNU readline into /usr/local under name libereadline
dnl and its headers into /usr/local/include/ereadline.
save_CFLAGS=${CFLAGS}
save_LIBS=${LIBS}
AC_MSG_CHECKING([for GNU readline])
readline_found=no
for READLINE_PREFIX in ${READLINE_SEARCH_PATH} ; do
AS_CASE([$READLINE_PREFIX],
[DEFAULTS],[
READLINE_PREFIX=""
READLINE_CPPFLAGS=""
READLINE_LDFLAGS=""
READLINE_LIBS="-lreadline"
],
[DEFAULTS_EREADLINE],[
dnl ereadline is the name of GNU readline library on OpenBSD
READLINE_PREFIX=""
READLINE_CPPFLAGS="-I/usr/local/include/ereadline"
READLINE_LDFLAGS=""
READLINE_LIBS="-lereadline"
],
[*],[
READLINE_CPPFLAGS="-I${READLINE_PREFIX}/include"
READLINE_LDFLAGS="-L${READLINE_PREFIX}/lib"
READLINE_LIBS="-lreadline"
]
)
CFLAGS="${READLINE_CPPFLAGS} ${save_CFLAGS}"
LIBS="${READLINE_LDFLAGS} ${READLINE_LIBS} ${save_LIBS}"
AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[#include <stdio.h>
#include <readline/readline.h>]],
[[rl_bind_keyseq(0,0);]])],
[readline_found=yes
AS_IF([test x"$READLINE_PREFIX" != x""],[
AC_MSG_RESULT([yes, at prefix ${READLINE_PREFIX}])
],[
AC_MSG_RESULT([yes, in default search path])
])
AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have lib(e)readline])
break],
)
done
CFLAGS=${save_CFLAGS}
LIBS=${save_LIBS}
AS_IF([test x$readline_found = xno],[
AC_MSG_RESULT([no])
AS_IF([test x$with_readline != xcheck && test x$with_readline != xno],[
AC_MSG_FAILURE([--with-readline was given, but further tests for readline failed])
])
READLINE_CPPFLAGS=
READLINE_LDFLAGS=
READLINE_LIBS=
])
AC_SUBST([READLINE_CPPFLAGS])
AC_SUBST([READLINE_LDFLAGS])
AC_SUBST([READLINE_LIBS])
dnl Find julia
AS_IF([test "x$with_julia" != xno ],[
AS_IF([test -x "$with_julia" && test ! -d "$with_julia" ],
[
JULIA="${with_julia}"
],
[
AS_IF([test -d "$with_julia" ],
[
JULIA_PATH="${with_julia}/bin:${with_julia}:${with_julia}/usr/bin"
],
[
AS_IF([test "x$with_julia" != xyes ],
[ AC_MSG_ERROR([invalid argument to --with-julia]) ] )
JULIA_PATH="${PATH}"
])
AC_PATH_PROG([JULIA], [julia], [], [$JULIA_PATH])
])
AS_IF([test "x$JULIA" = x],[ AC_MSG_ERROR([no julia executable found]) ])
AC_MSG_CHECKING([for Julia version])
JULIA_VERSION=$(${JULIA} --startup-file=no -e 'print("$(VERSION.major).$(VERSION.minor)")')
AS_IF([ test $? != 0 ], [AC_MSG_ERROR([failed to obtain Julia version])])
AC_MSG_RESULT([${JULIA_VERSION}])
JL_SHARE=$($JULIA --startup-file=no -e 'print(joinpath(Sys.BINDIR, Base.DATAROOTDIR, "julia"))')
AS_IF([test -f "${JL_SHARE}/julia-config.jl"], [], [AC_MSG_ERROR([no julia-config.jl found])])
AC_MSG_CHECKING([for JULIA_CFLAGS])
JULIA_CFLAGS=$(${JULIA} --startup-file=no ${JL_SHARE}/julia-config.jl --cflags 2>/dev/null)
JULIA_CFLAGS=${JULIA_CFLAGS/-std=gnu99/} # need to remove -std=gnu99 for our C11 and C++ code
AS_IF([ test $? != 0 ], [AC_MSG_ERROR([failed to obtain JULIA_CFLAGS from julia-config.jl])])
AC_MSG_RESULT([${JULIA_CFLAGS}])
AC_MSG_CHECKING([for JULIA_LDFLAGS])
JULIA_LDFLAGS=$(${JULIA} --startup-file=no ${JL_SHARE}/julia-config.jl --ldflags)
AS_IF([ test $? != 0 ], [AC_MSG_ERROR([failed to obtain JULIA_LDFLAGS from julia-config.jl])])
JULIA_LDFLAGS=${JULIA_LDFLAGS//\'/}
AC_MSG_RESULT([${JULIA_LDFLAGS}])
AC_MSG_CHECKING([for JULIA_LIBS])
JULIA_LIBS=$(${JULIA} --startup-file=no ${JL_SHARE}/julia-config.jl --ldlibs)
AS_IF([ test $? != 0 ], [AC_MSG_ERROR([failed to obtain JULIA_LIBS from julia-config.jl])])
# remove apostrophes, they confuse libtool in some cases.
JULIA_LIBS=${JULIA_LIBS//\'/}
AC_MSG_RESULT([${JULIA_LIBS}])
],
[
AS_IF( [ test "x$with_gc" = xjulia ],
[
AC_MSG_ERROR([ julia was selected as GC, but julia support was disabled ])
])
])
AC_SUBST([JULIA])
AC_SUBST([JULIA_VERSION])
AC_SUBST([JULIA_CFLAGS])
AC_SUBST([JULIA_LDFLAGS])
AC_SUBST([JULIA_LIBS])
dnl TODO: check if $with_gc = julia; if so, error out if julia is not found
AS_IF([test "x$with_gc" = xboehm],
[
# We bundle two libraries we need for HPC-GAP:
# Boehm garbage collector, see https://www.hboehm.info/gc/
# libatomic_ops - part of Boehm GC, but see also https://github.com/ivmai/libatomic_ops
#
# We bundle them because we need a few patches to Boehm GC which are
# not upstream (and it is unclear whether they ever will be).
# And we bundle libatomic_ops because its version must match that
# of Boehm GC; the easiest way to ensure that is to include that, too.
#
# As a side benefit, users do not have to worry about installing dependencies.
BUILD_LIBATOMIC_OPS=yes
LIBATOMIC_OPS_CPPFLAGS='-I${abs_builddir}/extern/install/libatomic_ops/include'
LIBATOMIC_OPS_LDFLAGS='-L${abs_builddir}/extern/install/libatomic_ops/lib'
LIBATOMIC_OPS_LIBS='-Wl,-rpath,${abs_builddir}/extern/install/libatomic_ops/lib -latomic_ops'
AC_SUBST([BUILD_LIBATOMIC_OPS])
AC_SUBST([LIBATOMIC_OPS_CPPFLAGS])
AC_SUBST([LIBATOMIC_OPS_LDFLAGS])
AC_SUBST([LIBATOMIC_OPS_LIBS])
ATOMIC_OPS_CFLAGS=$LIBATOMIC_OPS_CPPFLAGS
ATOMIC_OPS_LIBS=$LIBATOMIC_OPS_LDFLAGS
BUILD_BOEHM_GC=yes
BOEHM_GC_CPPFLAGS='-I${abs_builddir}/extern/install/gc/include'
BOEHM_GC_LDFLAGS='-L${abs_builddir}/extern/install/gc/lib'
BOEHM_GC_LIBS='-Wl,-rpath,${abs_builddir}/extern/install/gc/lib -lgc'
AC_SUBST([BUILD_BOEHM_GC])
AC_SUBST([BOEHM_GC_CPPFLAGS])
AC_SUBST([BOEHM_GC_LDFLAGS])
AC_SUBST([BOEHM_GC_LIBS])
]
)
dnl
dnl Export library and kernel version
dnl
AC_SUBST([gap_kernel_major_version], kernel_major_version)
AC_SUBST([gap_kernel_minor_version], kernel_minor_version)
dnl
dnl Determine the GAPARCH string, used by package build systems and more
dnl
AC_MSG_CHECKING([the GAPARCH])
dnl The "host" identifier is the start
case "$host_os" in
*darwin*)
# On macOS / Darwin, override the config.guess result, which includes
# the minor versions of macOS, which has no benefit but is painful as
# every patch update of the OS may result in all packages having to be
# recompiled. So instead of e.g. `darwin21.2.0` (for macOS 12.2.0) and
# `darwin21.4.0` (for macOS 12.3.1), use just `darwin21`, and so on.
GAPARCH="$host_cpu-$host_vendor-${host_os%%.*.*}"
;;
*)
GAPARCH="$host"
;;
esac
dnl Append primary build variant
AS_IF(
[test "x$enable_hpcgap" = xyes],
[GAPARCH="$GAPARCH-hpcgap"],
[test "x$with_julia" != xno],
[GAPARCH="$GAPARCH-julia${JULIA_VERSION}-"],
# else
[GAPARCH="$GAPARCH-default"])
dnl Append ABI (for historical reasons, we don't insert a dash before it)
GAPARCH="${GAPARCH}${ABI}"
dnl Append kernel version
GAPARCH="${GAPARCH}-kv${gap_kernel_major_version}"
dnl Allow user to extend the GAPARCH with some extra key
AS_IF([test "x$ARCHEXT" != "x"], [GAPARCH="$GAPARCH-$ARCHEXT"])
dnl Allow user to completely override the GAPARCH (should be used sparingly!)
AS_IF([test "x$ARCH" != "x"], [GAPARCH="$ARCH"])
AC_MSG_RESULT([${GAPARCH}])
AC_DEFINE_UNQUOTED([GAPARCH], ["$GAPARCH"], [the GAP architecture, for kernel extensions])
AC_SUBST([GAPARCH])
dnl
dnl Detect host specific setting
dnl
GP_C_LONG_ALIGN
case "$host_cpu" in
sparc* )
AC_DEFINE([SYS_IS_SPARC], [1], [define as 1 on SPARC architecture to flush register windows])
;;
esac
dnl
dnl check for the existence of various header files
dnl
dnl check for functionality related to child process handling,
dnl including pseudo TTY support, signals, etc.
AC_CHECK_HEADERS([termios.h])
AC_CHECK_HEADERS([sys/ioctl.h sys/resource.h])
# openpty() is available on various BSD variants, but also in glibc.
# On BSD systems, one usually needs to add -lutil to LIBS in order
# to use it.
AC_SEARCH_LIBS([openpty], [util],
AC_DEFINE([HAVE_OPENPTY], [1], [define as 1 if you have `openpty']))
AS_IF([test "x$ac_cv_search_openpty" = xno],[
# Check for POSIX 98 pty APIs to use instead of openpty()
AC_CHECK_FUNCS([ptsname grantpt unlockpt posix_openpt])
],[
# Check for headers declaring openpty()
AC_CHECK_HEADERS([util.h pty.h libutil.h])
])
dnl check for input/output functions
AC_CHECK_HEADERS([signal.h])
AC_CHECK_FUNCS([select])
dnl various functions to deal with child processes
AC_CHECK_HEADERS([spawn.h])
AC_HEADER_SYS_WAIT
AC_FUNC_FORK
AC_CHECK_FUNCS([popen posix_spawn])
AC_CHECK_FUNCS([posix_spawn_file_actions_addchdir])
AC_CHECK_FUNCS([posix_spawn_file_actions_addchdir_np])
dnl signal handling
AC_CHECK_TYPE([sig_atomic_t], [],
[AC_DEFINE([HAVE_SIG_ATOMIC_T],[],[Check for sig_atomic_t])],
[#include <signal.h>]
)
AC_CHECK_FUNCS([signal sigaction setpgid])
dnl
dnl check for dynamic loading of modules
dnl
AC_SEARCH_LIBS([dlopen], [dl],
[AC_DEFINE([HAVE_DLOPEN], [1], [define as 1 if you have `dlopen' and `dlsym'])]
)
dnl check for timing functions
AC_CHECK_HEADERS([sys/time.h])
AC_CHECK_FUNCS([getrusage gettimeofday clock_gettime clock_getres])
AC_CHECK_FUNCS([setitimer])
dnl check for functions dealing with virtual memory
AC_CHECK_FUNCS([vm_allocate sbrk madvise sysconf])