/
vforth4_3.fth
4760 lines (1749 loc) · 52.6 KB
/
vforth4_3.fth
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
\ *** Block No. 0, Hexblock 0
\\ Directory ultraFORTH 3of4 26oct87re
. &0
.. &0
rom-ram-sys &2
Transient-Assembler &4
Assembler-6502 &5
2words &14
unlink &15
scr<>cbm &16
(search &17
Editor &19
.blk &46
Tracer/Tools &47
Multi-Tasker &57
EpsonRX80 &63
VC1526 &75
CP-80 &78
\ *** Block No. 1, Hexblock 1
\\ Content volksForth 3.81.02 cas16aug06
rom ram sys 2 - 3
Transient Assembler 4
Assembler-6502 5 - 12
13 free
2words 14
unlink 15
scr<>cbm 16
(search 17
Editor 19
.blk 46
Tracer Tools 47
Multi-Tasker 57
Printer: EpsonRX80 63
Printer: VC1526 75
Printer: CP-80 78
Shadows 85 ...
\ *** Block No. 2, Hexblock 2
\ rom ram sys cas16aug06
\ Shadow with Ctrl+W--->
\ needed for jumps
\ in the ROM Area
Assembler also definitions
(16 \ Switch Bank 8000-FFFF
: rom here 9 + $8000 u> abort" not here"
$ff3e sta ;
: ram $ff3f sta ;
: sys rom jsr ram ;
\ if suffering from abort" not here"
\ see next screen Screen --> C)
(64 \ Switch Bank A000-BFFF
: rom here 9 + $A000 u> abort" not here"
$37 # lda 1 sta ;
: ram $36 # lda 1 sta ;
C)
\ *** Block No. 3, Hexblock 3
\ sysMacro Long cas16aug06
(64 .( not for C64 !) \\ C)
\ for advanced users, use macros
here $8000 $20 - u> ?exit \ not possible
' 0 | Alias ???
Label long ROM
Label long1 ??? jsr RAM rts end-code
| : sysMacro ( adr -- )
$100 u/mod pha # lda long1 2+ sta
# lda long1 1+ sta pla long jsr ;
: sys ( adr -- ) \ for Jsr to ROM
here 9 + $8000 u>
IF sysMacro ELSE sys THEN ;
\ *** Block No. 4, Hexblock 4
\ transient Assembler clv10oct87
\ Basis: Forth Dimensions VOL III No. 5)
\ internal loading 04may85BP/re)
here $800 hallot heap dp !
1 +load
dp !
Onlyforth
\ *** Block No. 5, Hexblock 5
\ Forth-6502 Assembler clv10oct87
\ Basis: Forth Dimensions VOL III No. 5)
Onlyforth Assembler also definitions
1 7 +thru
-3 +load \ Makros: rom ram sys
Onlyforth
\ *** Block No. 6, Hexblock 6
\ Forth-83 6502-Assembler 20oct87re
: end-code context 2- @ context ! ;
Create index
$0909 , $1505 , $0115 , $8011 ,
$8009 , $1D0D , $8019 , $8080 ,
$0080 , $1404 , $8014 , $8080 ,
$8080 , $1C0C , $801C , $2C80 ,
| Variable mode
: Mode: ( n -) Create c,
Does> ( -) c@ mode ! ;
0 Mode: .A 1 Mode: #
2 | Mode: mem 3 Mode: ,X
4 Mode: ,Y 5 Mode: X)
6 Mode: )Y $F Mode: )
\ *** Block No. 7, Hexblock 7
\ upmode cpu 20oct87re
| : upmode ( addr0 f0 - addr1 f1)
IF mode @ 8 or mode ! THEN
1 mode @ $F and ?dup IF
0 DO dup + LOOP THEN
over 1+ @ and 0= ;
: cpu ( 8b -) Create c,
Does> ( -) c@ c, mem ;
00 cpu brk $18 cpu clc $D8 cpu cld
$58 cpu cli $B8 cpu clv $CA cpu dex
$88 cpu dey $E8 cpu inx $C8 cpu iny
$EA cpu nop $48 cpu pha $08 cpu php
$68 cpu pla $28 cpu plp $40 cpu rti
$60 cpu rts $38 cpu sec $F8 cpu sed
$78 cpu sei $AA cpu tax $A8 cpu tay
$BA cpu tsx $8A cpu txa $9A cpu txs
$98 cpu tya
\ *** Block No. 8, Hexblock 8
\ m/cpu 20oct87re
: m/cpu ( mode opcode -) Create c, ,
Does>
dup 1+ @ $80 and IF $10 mode +! THEN
over $FF00 and upmode upmode
IF mem true Abort" invalid" THEN
c@ mode @ index + c@ + c, mode @ 7 and
IF mode @ $F and 7 <
IF c, ELSE , THEN THEN mem ;
$1C6E $60 m/cpu adc $1C6E $20 m/cpu and
$1C6E $C0 m/cpu cmp $1C6E $40 m/cpu eor
$1C6E $A0 m/cpu lda $1C6E $00 m/cpu ora
$1C6E $E0 m/cpu sbc $1C6C $80 m/cpu sta
$0D0D $01 m/cpu asl $0C0C $C1 m/cpu dec
$0C0C $E1 m/cpu inc $0D0D $41 m/cpu lsr
$0D0D $21 m/cpu rol $0D0D $61 m/cpu ror
$0414 $81 m/cpu stx $0486 $E0 m/cpu cpx
$0486 $C0 m/cpu cpy $1496 $A2 m/cpu ldx
$0C8E $A0 m/cpu ldy $048C $80 m/cpu sty
$0480 $14 m/cpu jsr $8480 $40 m/cpu jmp
$0484 $20 m/cpu bit
\ *** Block No. 9, Hexblock 9
\ Assembler conditionals 20oct87re
| : range? ( branch -- branch )
dup abs $7F u> Abort" out of range " ;
: [[ ( BEGIN) here ;
: ?] ( UNTIL) c, here 1+ - range? c, ;
: ?[ ( IF) c, here 0 c, ;
: ?[[ ( WHILE) ?[ swap ;
: ]? ( THEN) here over c@ IF swap !
ELSE over 1+ - range? swap c! THEN ;
: ][ ( ELSE) here 1+ 1 jmp
swap here over 1+ - range? swap c! ;
: ]] ( AGAIN) jmp ;
: ]]? ( REPEAT) jmp ]? ;
\ *** Block No. 10, Hexblock a
\ Assembler conditionals 20oct87re
$90 Constant CS $B0 Constant CC
$D0 Constant 0= $F0 Constant 0<>
$10 Constant 0< $30 Constant 0>=
$50 Constant VS $70 Constant VC
: not $20 [ Forth ] xor ;
: beq 0<> ?] ; : bmi 0>= ?] ;
: bne 0= ?] ; : bpl 0< ?] ;
: bcc CS ?] ; : bvc VS ?] ;
: bcs CC ?] ; : bvs VC ?] ;
\ *** Block No. 11, Hexblock b
\ 2inc/2dec winc/wdec 20oct87re
: 2inc ( adr -- )
dup lda clc 2 # adc
dup sta CS ?[ swap 1+ inc ]? ;
: 2dec ( adr -- )
dup lda sec 2 # sbc
dup sta CC ?[ swap 1+ dec ]? ;
: winc ( adr -- )
dup inc 0= ?[ swap 1+ inc ]? ;
: wdec ( adr -- )
dup lda 0= ?[ over 1+ dec ]? dec ;
: ;c:
recover jsr end-code ] 0 last ! 0 ;
\ *** Block No. 12, Hexblock c
\ ;code Code code> bp/re03feb85
Onlyforth
: Assembler
Assembler [ Assembler ] mem ;
: ;Code
[compile] Does> -3 allot
[compile] ; -2 allot Assembler ;
immediate
: Code Create here dup 2- ! Assembler ;
: >label ( adr -)
here | Create immediate swap ,
4 hallot heap 1 and hallot ( 6502-alig)
here 4 - heap 4 cmove
heap last @ count $1F and + ! dp !
Does> ( - adr) @
state @ IF [compile] Literal THEN ;
: Label
[ Assembler ] here >label Assembler ;
\ *** Block No. 13, Hexblock d
\ free cas16aug06
\ *** Block No. 14, Hexblock e
\ 2! 2@ 2variable 2constant clv20aug87re
Code 2! ( d adr --)
tya setup jsr 3 # ldy
[[ SP )Y lda N )Y sta dey 0< ?]
1 # ldy Poptwo jmp end-code
Code 2@ ( adr -- d)
SP X) lda N sta SP )Y lda N 1+ sta
SP 2dec 3 # ldy
[[ N )Y lda SP )Y sta dey 0< ?]
xyNext jmp end-code
: 2Variable ( --) Create 4 allot ;
( -- adr)
: 2Constant ( d --) Create , ,
Does> ( -- d) 2@ ;
\ 2dup exists
\ 2swap exists
\ 2drop exists
\ *** Block No. 15, Hexblock f
\ unlink clv20aug87re
$FFF0 >label plot
(64
Code unlink ( -- )
$288 lda $80 # ora tay txa
[[ $D9 ,X sty clc $28 # adc
CS ?[ iny ]? inx $1A # cpx 0= ?]
$D3 lda $28 # cmp
CS ?[ $28 # sbc $D3 sta ]?
$D3 ldy $D6 ldx clc plot jsr C)
(16 : unlink 0 0 $7EE 2! ; C)
Label setptrs
0 # ldx 1 # ldy Next jmp end-code
\ *** Block No. 16, Hexblock 10
\ changing codes cas16aug06
( mapping commodore screen codes )
Label (scr>cbm
N 6 + sta $3F # and N 6 + asl
N 6 + bit 0< ?[ $80 # ora ]?
VC ?[ $40 # ora ]? rts
Label (cbm>scr
N 6 + sta $7F # and $20 # cmp
CS ?[ $40 # cmp
CS ?[ $1F # and N 6 + bit
0< ?[ $40 # ora ]? ]? rts ]?
Ascii . # lda rts
Code cbm>scr ( 8b1 -- 8b2)
SP X) lda (cbm>scr jsr SP X) sta
Next jmp end-code
Code scr>cbm ( 8b1 -- 8b2)
SP X) lda (scr>cbm jsr SP X) sta
Next jmp end-code
\ *** Block No. 17, Hexblock 11
\ fast search cas16aug06
\needs Code -$D +load \ Trans Assembler
Onlyforth
' 0< @ 4 + >label puttrue
puttrue 3 + >label putfalse
Code (search
( text tlen buffer blen -- adr tf / ff)
7 # ldy
[[ SP )Y lda N ,Y sta dey 0< ?]
[[ N 4 + lda N 5 + ora 0<> ?[
[[ N lda N 1+ ora 0<> ?[
N 2+ X) lda N 6 + X) cmp swap
0<> ?[[ N wdec N 2+ winc ]]?
-->
\ *** Block No. 18, Hexblock 12
\ Edior fast search cas16aug06
7 # ldy
[[ N ,Y lda SP )Y sta dey 0< ?]
[[ N 2+ winc N 6 + winc N wdec
N 4 + wdec N 4 + lda N 5 + ora
0= ?[ SP lda clc 4 # adc SP sta
CS ?[ SP 1+ inc ]?
3 # ldy N 3 + lda SP )Y sta
N 2+ lda dey SP )Y sta dey
puttrue jmp ]?
N lda N 1+ ora 0= ?[
3 roll 3 roll ]? ]?
SP lda clc 6 # adc SP sta
CS ?[ SP 1+ inc ]? 1 # ldy
putfalse jmp ]?
N 2+ X) lda N 6 + X) cmp 0= not ?]
7 # ldy
[[ SP )Y lda N ,Y sta dey 0< ?]
N wdec N 2+ winc
( next char as first ) ]] end-code
\ *** Block No. 19, Hexblock 13
\ Editor loadscreen clv13jul87
\ Idea and first implementation: WE/re
Onlyforth
\needs .blk $1B +load \ .blk
\needs Code -$F +load \ Assembl
\needs (search -2 +load \ (search
Onlyforth
(64 | : at at curoff ; C) \ sorry
\needs 2variable -5 +load
\needs unlink -4 +load \ unlink
\needs scr>cbm -3 +load \ cbm><scr
Vocabulary Editor
Editor also definitions
1 $17 +thru \ Editor
$18 $19 +thru \ edit-view
$1A +load \ Ediboard
Onlyforth 1 scr ! 0 r# !
save
\ *** Block No. 20, Hexblock 14
\ Edi Constants Variables clv15jul87
$28 | Constant #col $19 | Constant #row
#col #row * | Constant b/scr
Variable shadow $55 shadow !
| Variable ascr 1 ascr !
| Variable imode imode off
| Variable char #cr char !
| Variable scroll scroll on
| Variable send 1 send !
| 2variable chars | 2variable lines
| 2variable fbuf | 2variable rbuf
(64 $288 C) (16 $53e C) >Label scradr
(64 $d800 C) (16 $800 C) >Label coladr
$d1 (16 drop $c8 C) | Constant linptr
$d3 (16 drop $ca C) | Constant curofs
(64 $D020 C) (16 $ff19 C)
| Constant border
(64 $286 C) (16 $53b C) | Constant pen
(64 $d021 C) (16 $ff15 C)
| Constant bkgrnd
\ *** Block No. 21, Hexblock 15
\ Edi special cmoves cas16aug06
( thanks to commodore.... )
Label incpointer
N lda clc #col 1+ # adc
N sta CS ?[ N 1+ inc ]?
N 2+ lda clc #col # adc
N 2+ sta CS ?[ N 3 + inc ]? rts
| Code b>sc ( blkadr --)
tya setup jsr
N 2+ stx scradr lda N 3 + sta
#row # ldx
[[ #col 1- # ldy
[[ N )Y lda (cbm>scr jsr
N 2+ )Y sta dey 0< ?]
incpointer jsr dex
0= ?]
pen lda
[[ coladr ,X sta
coladr $100 + ,X sta
coladr $200 + ,X sta
coladr $300 + ,X sta
inx 0= ?] setptrs jmp end-code
\ *** Block No. 22, Hexblock 16
\ Edi special cmoves cont. cas16aug06
( ... for screen format )
| Code sc>b ( blkadr --)
tya setup jsr
N 2+ stx scradr lda N 3 + sta
#row # ldx
[[ 0 # ldy
[[ N 2+ )Y lda (scr>cbm jsr
N )Y sta iny #col # cpy CS ?]
dex
0<> ?[[
bl # lda N )Y sta
incpointer jsr
]]? setptrs jmp end-code
| Code >scrmove ( from to 8bquan --)
3 # lda setup jsr dey
[[ N cpy 0= ?[ setptrs jmp ]?
N 4 + )Y lda (cbm>scr jsr
N 2+ )Y sta iny 0= ?] end-code
\ *** Block No. 23, Hexblock 17
\ Edi changed? cas16aug06
| Code changed? ( blkadr -- f)
tya setup jsr
N 2+ stx scradr lda N 3 + sta
#row # ldx
[[ #col 1- # ldy
[[ N )Y lda (cbm>scr jsr
N 2+ )Y cmp
0<> ?[ $FF # lda PushA jmp ]?
dey 0< ?]
incpointer jsr dex
0= ?]
txa PushA jmp end-code
| : memtop sp@ #col 2* - ;
\ *** Block No. 24, Hexblock 18
\ Edi c64-specials clv2:jull87
| Code scrstart ( -- adr)
txa pha scradr lda Push jmp end-code
| Code rowadr ( -- adr)
curofs lda #col # cmp txa
CS ?[ #col 1- # lda ]?
linptr adc pha linptr 1 + lda 0 # adc
Push jmp end-code
| Code curadr ( -- adr)
clc curofs lda linptr adc pha
linptr 1 + lda 0 # adc Push jmp
end-code
(64
| Code unlinked? \ -- f
$D5 lda #col # cmp CC ?[ dex ]?
txa PushA jmp end-code C)
\ *** Block No. 25, Hexblock 19
\ Edi scroll? put/insert/do clv2:jull87
| : blank.end? ( -- f)
scrstart [ b/scr #col - ] Literal +
#col -trailing nip 0= scroll @ or ;
| : atlast? ( -- f)
curadr scrstart b/scr + 1- =
scroll @ 0= and ;
| : putchar ( -- f)
char c@ con! false ;
| : insert ( -- f)
atlast? ?dup ?exit
(64 unlinked? C) (16 true C)
rowadr #col + 1- c@ bl = not and
blank.end? not and dup ?exit
$94 con! ;
| : dochar ( -- f)
atlast? ?dup ?exit
imode @ IF insert ?dup ?exit
THEN putchar ;
\ *** Block No. 26, Hexblock 1a
\ Edi cursor control cas16aug06
| : curdown ( -- f)
scroll @ 0= row #row 2- u> and
dup ?exit $11 con! ;
| : currite ( -- f)
atlast? dup ?exit $1D con! ;
' putchar | Alias curup
' putchar | Alias curleft
' putchar | Alias home
' putchar | Alias delete
| : >""end ( -- ff)
scrstart b/scr -trailing nip
b/scr 1- min #col /mod swap at false ;
| : +tab ( -- f)
0 $a 0 DO drop currite dup
IF LEAVE THEN LOOP ;
| : -tab ( -- f)
5 0 DO $9D con! LOOP false ;
\ *** Block No. 27, Hexblock 1b
\ Edi cr, clear/newline cas16aug06
| : <cr> ( -- f)
row 0 at unlink imode off curdown ;
| : clrline ( -- ff)
rowadr #col bl fill false ;
| : clrright ( -- ff)
curadr #col col - bl fill false ;
| : killine ( -- f)
rowadr dup #col + swap
scrstart $3C0 + dup >r
over - cmove
r> #col bl fill false ;
| : newline ( -- f)
blank.end? not ?dup ?exit
rowadr dup #col + scrstart b/scr +
over - cmove> clrline ;
\ *** Block No. 28, Hexblock 1c
\ Edi character handling cas16aug06
| : dchar ( -- f)
currite dup ?exit $14 con! ;
| : @char ( -- f)
chars 2@ + 1+ lines @ memtop min
u> dup ?exit
curadr c@ chars 2@ + c!
1 chars 2+ +! ;
| : copychar ( -- f)
@char ?dup ?exit currite ;
| : char>buf ( -- f)
@char ?dup ?exit dchar ;
| : buf>char ( -- f)
chars 2+ @ 0= ?dup ?exit
insert dup ?exit
-1 chars 2+ +!
chars 2@ + c@ curadr c! ;
\ *** Block No. 29, Hexblock 1d
\ Edi line handling, imode cas16aug06
| : @line ( -- f)
lines 2@ + memtop u> dup ?exit
rowadr lines 2@ + #col cmove
#col lines 2+ +! ;
| : copyline ( -- f)
@line ?dup ?exit curdown ;
| : line>buf ( -- f)
@line ?dup ?exit killine ;
| : !line ( --)
#col negate lines 2+ +!
lines 2@ + rowadr #col cmove ;
| : buf>line ( -- f)
lines 2+ @ 0= ?dup ?exit
newline dup ?exit !line ;
| : setimd ( -- f) imode on false ;
| : clrimd ( -- f) imode off false ;
\ *** Block No. 30, Hexblock 1e
\ Edi the stamp cas16aug06
Forth definitions
: rvson $12 con! ; : rvsoff $92 con! ;
Code ***volksFORTH83***
Next here 2- ! end-code
: Forth-Gesellschaft [compile] \\ ;
immediate
Editor definitions
Create stamp$ $12 allot stamp$ $12 erase
| : .stamp ( -- ff)
stamp$ 1+ count scrstart #col +
over - swap >scrmove false ;
: getstamp ( --)
input push keyboard stamp$ on
cr ." your stamp: " rvson $10 spaces
row $C at stamp$ 2+ $10 expect
rvsoff span @ stamp$ 1+ c! ;
| : stamp? ( --)
stamp$ c@ ?exit getstamp ;
\ *** Block No. 31, Hexblock 1f
\ Edi the screen# cas16aug06
| : savetop ( --)
scrstart pad #col 2* cmove
scrstart #col 2* $A0 fill ;
| : resttop ( --)
pad scrstart #col 2* cmove ;
| : updated? ( scr# -- n)
block 2- @ ;
| : special ( --)
curon BEGIN pause key? UNTIL curoff ;
| : drvScr ( --drv scr')
scr @ offset @ + blk/drv u/mod swap ;
| : .scr# ( -- ff) at? savetop rvson
0 0 at drvScr ." Scr # " . ." Drv " .
scr @ updated? 0=
IF ." not " THEN ." updated" 1 1 at
[ ' ***volksFORTH83*** >name ] Literal
count type 2 spaces
[ ' Forth-Gesellschaft >name ] Literal
count $1F and type
rvsoff at special resttop false ;
\ *** Block No. 32, Hexblock 20
\ Edi exits cas16aug06
| : at?>r# ( --)
at? swap #col 1+ * + r# ! ;
| : r#>at ( --)
r# @ dup #col 1+ mod #col = -
b/blk 1- min #col 1+ /mod swap at ;
| : cancel ( -- n)
unlink %0001 at?>r# ;
| : eupdate ( -- n)
cancel scr @ block changed?
IF .stamp drop scr @ block sc>b
update %0010 or THEN ;
| : esave ( -- n) eupdate %0100 or ;
| : eload ( -- n) esave %1000 or ;
\ *** Block No. 33, Hexblock 21
\ leaf thru Edi clv01aug87
| : elist ( -- ff)
scr @ block b>sc imode off unlink
r#>at false ;
| : next ( -- ff)
eupdate drop 1 scr +! elist ;
| : back ( -- ff)
eupdate drop -1 scr +! elist ;
| : >shadow ( -- ff)
eupdate drop shadow @ dup drvScr nip
u> not IF negate THEN scr +! elist ;
| : alter ( -- ff)
eupdate drop ascr @ scr @
ascr ! scr ! elist ;
\ *** Block No. 34, Hexblock 22
\ Edi digits 2oct87re
Forth definitions
: digdecode ( adr cnt1 key -- adr cnt2)
#bs case? IF dup IF
del 1- THEN exit THEN
#cr case? IF dup span ! exit THEN
capital dup digit?
IF drop >r 2dup + r@ swap c!
r> emit 1+ exit THEN drop ;
Input: digits
c64key c64key? digdecode c64expect ;
Editor definitions
| : replace ( -- f)
fbuf @ 0 DO #bs con! LOOP
false rbuf @ 0 DO insert or LOOP
dup ?exit
rbuf 2@ curadr swap >scrmove
eupdate drop ;
\ *** Block No. 35, Hexblock 23
\ Edi >bufs cas16aug06
| : .buf ( adr count --)
type Ascii < emit
#col 1- col - spaces ;
| : >bufs ( --)
input push
unlink savetop at? rvson
1 0 at ." replace with: "
at? rbuf 2@ .buf
0 0 at ." > search: "
at? fbuf 2@ .buf
0 2 2dup at send @ 3 u.r 2dup at
here 1+ 3 digits expect span @ ?dup
IF here under c! number drop send !
THEN at send @ 3 u.r keyboard