-
Notifications
You must be signed in to change notification settings - Fork 56
/
kn_ExportNew.pas
1750 lines (1417 loc) · 62.6 KB
/
kn_ExportNew.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit kn_ExportNew;
(****** LICENSE INFORMATION **************************************************
- This Source Code Form is subject to the terms of the Mozilla Public
- License, v. 2.0. If a copy of the MPL was not distributed with this
- file, You can obtain one at http://mozilla.org/MPL/2.0/.
------------------------------------------------------------------------------
(c) 2007-2023 Daniel Prado Velasco <dprado.keynote@gmail.com> (Spain) [^]
(c) 2000-2005 Marek Jedlinski <marek@tranglos.com> (Poland)
[^]: Changes since v. 1.7.0. Fore more information, please see 'README.md'
and 'doc/README_SourceCode.txt' in https://github.com/dpradov/keynote-nf
*****************************************************************************)
interface
uses
Winapi.Windows,
Winapi.Messages,
System.Classes,
System.IniFiles,
System.IOUtils,
System.SysUtils,
Vcl.Graphics,
Vcl.Controls,
Vcl.Forms,
Vcl.Dialogs,
Vcl.Buttons,
Vcl.StdCtrls,
Vcl.ExtCtrls,
Vcl.ComCtrls,
Vcl.FileCtrl,
Vcl.Samples.Spin,
TB97Ctls,
ComCtrls95,
TreeNT,
RxRichEd,
gf_misc,
gf_files,
gf_strings,
gf_streams,
kn_RTFUtils,
kn_Info,
kn_Const,
kn_Ini,
kn_Global,
kn_NoteObj,
kn_NodeList,
kn_TreeNoteMng,
kn_ExportImport,
kn_FileObj,
kn_TabSelect,
kn_Main,
kn_NoteFileMng,
kn_EditorUtils;
type
TForm_ExportNew = class(TForm)
Button_OK: TButton;
Button_Cancel: TButton;
Button_Help: TButton;
Pages: TPage95Control;
Tab_Main: TTab95Sheet;
Tab_Options: TTab95Sheet;
Tab_TreePad: TTab95Sheet;
GroupBox_Source: TGroupBox;
RB_CurrentNote: TRadioButton;
RB_AllNotes: TRadioButton;
RB_SelectedNotes: TRadioButton;
Button_Select: TButton;
Combo_TreeSelection: TComboBox;
GroupBox_Target: TGroupBox;
Label1: TLabel;
Label2: TLabel;
Combo_Format: TComboBox;
CheckBox_PromptOverwrite: TCheckBox;
Edit_Folder: TEdit;
CheckBox_Ask: TCheckBox;
GroupBox1: TGroupBox;
CB_IncNoteHeading: TCheckBox;
CB_IncNodeHeading: TCheckBox;
Edit_NodeHead: TComboBox;
Edit_NoteHead: TComboBox;
SaveDlg: TSaveDialog;
RG_TreePadVersion: TRadioGroup;
RG_TreePadMode: TRadioGroup;
RG_NodeMode: TRadioGroup;
RG_TreePadMaster: TRadioGroup;
CheckBox_ExcludeHiddenNodes: TCheckBox;
TB_OpenDlgDir: TToolbarButton97;
RG_HTML: TRadioGroup;
CB_LevelTemplates: TCheckBox;
CB_FontSizes: TCheckBox;
Edit_FontSizes: TEdit;
Edit_LengthHeading: TEdit;
Btn_TknHlp: TBitBtn;
Edit_Symbols: TEdit;
lblSymbols: TLabel;
lblLength: TLabel;
CB_IndentNodes: TCheckBox;
Spin_Indent: TSpinEdit;
lblIndent: TLabel;
CB_UseTab: TCheckBox;
procedure RG_HTMLClick(Sender: TObject);
procedure TB_OpenDlgDirClick(Sender: TObject);
procedure FormCreate(Sender: TObject);
procedure FormActivate(Sender: TObject);
procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
procedure RB_SelNotesClick(Sender: TObject);
procedure Combo_FormatClick(Sender: TObject);
procedure Button_OKClick(Sender: TObject);
procedure Button_SelectClick(Sender: TObject);
procedure Btn_TknHlpClick(Sender: TObject);
procedure Button_HelpClick(Sender: TObject);
procedure CB_FontSizesClick(Sender: TObject);
procedure CB_IndentNodesClick(Sender: TObject);
procedure CB_IncNodeHeadingClick(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
myNoteTree : TTreeNT;
myActiveNote : TTabNote;
myNotes : TNoteFile;
myINIFN : string;
ExportOptions : TExportOptions;
IsBusy : boolean;
DoAbort : boolean;
procedure ReadConfig;
procedure WriteConfig;
procedure PerformExport;
procedure FormToOptions;
procedure OptionsToForm;
function Validate : boolean;
function FlushExportFile( const RTF : TTabRichEdit; myNote: TTabNote; FN : string ) : boolean;
procedure FlushTreePadData( var tf : TTextfile; const Name : string; const Level : integer; const RTF : TTabRichEdit; const ClearRTF : boolean);
function GetExportFilename( const FN : string ) : string;
procedure PrepareRTFforPlainText (RTFAux : TTabRichEdit; TabSize: integer; RTFIndentValue: integer);
function ConfirmAbort : boolean;
function ExpandExpTokenString( const tpl, filename, notename, nodename : string; const nodelevel, nodeindex : integer; TabSize: integer ) : string;
end;
function LoadRTFHeadingTemplate( const Filename : string ) : string;
function EscapeTextForRTF( const Txt : string ) : string;
function MergeHeadingWithRTFTemplate( const Heading, RTFTemplate : string ) : string;
procedure ExportNotesEx;
procedure ExportTreeNode;
var
Form_ExportNew: TForm_ExportNew;
implementation
var
LengthsHeading_Max, LengthsHeading_Inc, LengthsHeading_Min: integer;
FontSizes_Max, FontSizes_Inc, FontSizes_Min: integer;
{$R *.DFM}
resourcestring
STR_01 = 'Exporting is underway. OK to abort?';
STR_02 = 'Please select a valid directory for exported files.';
STR_03 = 'Specified output directory does not not exit. Please select a valid directory.';
STR_04 = 'You did not select any notes for exporting.';
STR_11 = 'Error while exporting notes: ';
STR_12 = 'Exported %d notes (%d nodes).';
STR_13 = 'Exporting was aborted due to an error.';
STR_14 = 'Exporting was aborted at user request.';
STR_15 = 'The following token can be used in headings:' + #13#13 +
'%s%s - Filename' + #13 +
'%s%s - Note name' + #13 +
'%s%s - Node name' + #13 +
'%s%s - Node level' + #13 +
'%s%s - Node index' + #13 +
'%s%s - Line break' + #13 +
'%s%s - Symbols, increasing' + #13 +
'%s%s - Symbols, decreasing';
STR_16 = 'No active tree node: select a node first.';
STR_17 = 'Current node has no text: nothing to export.';
STR_18 = ' Node exported to ';
STR_19 = 'Error exporting node: ';
STR_20 = '''Current node'' will be managed as ''Current node and subtree'' for KeyNote format'+ #13 +' Continue?';
procedure PrepareExportOptions (SymbolsRepetition, FontSizesInHeading: string);
procedure GetIntegers (Str: string; var i1, i2, i3: integer);
var
p1,p2: integer;
begin
p1:= pos(',', Str, 1);
p2:= pos(',', Str, p1+1);
i1:= -1;
i2:= -1;
i3:= -1;
if TryStrToInt(Trim(Copy(Str, 1, p1-1)), i1) then
if TryStrToInt(Trim(Copy(Str, p1+1, p2-p1-1)), i2) then
TryStrToInt(Trim(Copy(Str, p2+1)), i3);
end;
begin
GetIntegers(SymbolsRepetition, LengthsHeading_Max, LengthsHeading_Inc, LengthsHeading_Min);
if (LengthsHeading_Max <0) or (LengthsHeading_Inc<0) or (LengthsHeading_Min<0) then
LengthsHeading_Max:= -1;
GetIntegers(FontSizesInHeading, FontSizes_Max, FontSizes_Inc, FontSizes_Min);
if (FontSizes_Max<0) or (FontSizes_Inc<0) or (FontSizes_Min <0) then
FontSizes_Max := -1;
end;
function TForm_ExportNew.ExpandExpTokenString(
const tpl, filename, notename, nodename : string;
const nodelevel, nodeindex : integer;
TabSize: integer ) : string;
var
i, len : integer;
wastokenchar : boolean;
thischar : Char;
LenSymbolsLine, NumTabsLevel: integer;
foundLineBreak: boolean;
function ExpandSymbolsLevel (token: char; headerLength: integer): string;
var
LenSymbolsLevel, I: integer;
Symbol: char;
begin
if nodelevel = 0 then exit('');
// Calculate length (repetition) of symbols level
if token = EXP_NODELEVELSYMB_INC then
LenSymbolsLevel:= 1 + (1*(nodelevel-1))
else begin
if LengthsHeading_Max < 0 then exit('');
LenSymbolsLevel:= LengthsHeading_Max - (LengthsHeading_Inc* (nodelevel-1));
if LenSymbolsLevel < LengthsHeading_Min then
LenSymbolsLevel:= LengthsHeading_Min;
if ExportOptions.IndentNestedNodes and not ExportOptions.SingleNodeFiles then begin
NumTabsLevel:= 1;
if ExportOptions.TargetFormat = xfPlainText then
NumTabsLevel:= ExportOptions.IndentValue div EditorOptions.IndentInc;
Dec(LenSymbolsLevel, NumTabsLevel*TabSize * (nodelevel-1));
end;
Dec(LenSymbolsLevel, headerLength);
end;
// Determine symbol to use
{ The first element of LevelSymbols corresponds to node level 1 }
if nodeLevel > Length(ExportOptions.SymbolsInHeading) then
Symbol:= ExportOptions.SymbolsInHeading[Length(ExportOptions.SymbolsInHeading)]
else
Symbol:= ExportOptions.SymbolsInHeading[nodeLevel];
Result:= StringOfChar(Symbol, LenSymbolsLevel);
end;
begin
result := '';
len := length( tpl );
LenSymbolsLine:= 0;
foundLineBreak:= false;
wastokenchar := false;
for i := 1 to len do begin
thischar := tpl[i];
case thischar of
_TokenChar : begin
if wastokenchar then begin
result := result + _TokenChar;
wastokenchar := false;
end
else
wastokenchar := true;
end;
else begin
if wastokenchar then begin
wastokenchar := false;
case thischar of
EXP_NOTENAME : result := result + notename;
EXP_NODENAME : result := result + nodename;
EXP_NODELEVEL : if ( nodelevel > 0 ) then result := result + inttostr( nodelevel );
EXP_NODEINDEX : if ( nodeindex > 0 ) then result := result + inttostr( nodeindex );
EXP_NODELEVELSYMB_INC: result := result + ExpandSymbolsLevel(thisChar, -1);
EXP_FILENAME : result := result + ExtractFilename( filename );
EXP_LINE_BREAK: begin
foundLineBreak:= true;
LenSymbolsLine:= 0;
result := result + _TokenChar + thischar;
end;
else
result := result + _TokenChar + thischar;
end;
end
else
result := result + thischar;
end;
if not foundLineBreak then
LenSymbolsLine:= Length(result)
end;
end;
Result:= StringReplace(Result, _TokenChar + EXP_NODELEVELSYMB_DEC, ExpandSymbolsLevel(thisChar, LenSymbolsLine), [rfReplaceAll]);
end; // ExpandExpTokenString
function MergeHeadingWithRTFTemplate( const Heading, RTFTemplate : string ) : string;
var
p : integer;
begin
result := RTFTemplate;
p := pos( EXP_RTF_HEADING, result );
if ( p > 0 ) then begin
delete( result, p, length( EXP_RTF_HEADING ));
insert( StringReplace(Heading, _TokenChar + EXP_LINE_BREAK, '\par ', [rfReplaceAll]), result, p );
end
else
result := '';
end; // MergeHeadingWithRTFTemplate
function LoadRTFHeadingTemplate( const Filename : String ) : String;
var
ls : TStringList;
begin
result := '';
if ( not Fileexists( Filename )) then exit;
ls := TStringList.Create;
try
try
ls.LoadFromFile( Filename );
result := ls.Text;
except
result := '';
end;
finally
ls.Free;
end;
end; // LoadRTFHeadingTemplate
function EscapeTextForRTF( const Txt : string ) : string;
var
i, len : integer;
thisChar : char;
begin
result := '';
len := length( Txt );
for i := 1 to len do begin
thisChar := Txt[i];
case thisChar of
'\', '{', '}', '<', '>' : begin
result := result + '\' + thisChar;
end;
else
result := result + thisChar;
end;
end;
end; // EscapeTextForRTF
procedure TForm_ExportNew.FormCreate(Sender: TObject);
var
ts : TTreeSelection;
f : TExportFmt;
m : THTMLExportMethod;
begin
Pages.ActivePage := Tab_Main;
IsBusy := false;
DoAbort := false;
myNoteTree := nil;
myActiveNote := nil;
myNotes := nil;
myINIFN := '';
for f := low( TExportFmt ) to high( TExportFmt ) do
Combo_Format.Items.Add( EXPORT_FORMAT_NAMES[f] );
Combo_Format.ItemIndex := 0;
for ts := low( ts ) to high( ts ) do
Combo_TreeSelection.Items.Add( TREE_SELECTION_NAMES[ts] );
Combo_TreeSelection.ItemIndex := 0;
Edit_NodeHead.Items.Add( _DefaultNodeHeading );
Edit_NoteHead.Items.Add( _DefaultNoteHeading );
for m := low( m ) to high( m ) do
RG_HTML.Items.Add( HTMLExportMethods[m] );
RG_HTML.ItemIndex:= ord(ExportOptions.HTMLExportMethod);
end; // CREATE
procedure TForm_ExportNew.FormActivate(Sender: TObject);
begin
OnActivate := nil;
ReadConfig;
OptionsToForm;
RB_SelNotesClick( RB_CurrentNote );
RB_CurrentNote.OnClick := RB_SelNotesClick;
RB_Allnotes.OnClick := RB_SelNotesClick;
RB_SelectedNotes.OnClick := RB_SelNotesClick;
Combo_FormatClick( Combo_Format );
Combo_Format.OnClick := Combo_FormatClick;
end; // ACTIVATE
function TForm_ExportNew.ConfirmAbort : boolean;
begin
result := ( messagedlg( STR_01, mtConfirmation, [mbOK,mbCancel], 0 ) = mrOK );
DoAbort := result;
end; // ConfirmAbort
procedure TForm_ExportNew.FormCloseQuery(Sender: TObject;
var CanClose: Boolean);
begin
if IsBusy then
CanClose := ConfirmAbort;
end; // CloseQuery
procedure TForm_ExportNew.RB_SelNotesClick(Sender: TObject);
begin
Combo_TreeSelection.Enabled := ( RB_CurrentNote.Checked and ( myActiveNote.Kind = ntTree )
and ( TExportFmt(Combo_Format.ItemIndex) in [xfPlainText, xfRTF, xfHTML, xfKeyNote] ));
Button_Select.Enabled := RB_SelectedNotes.Checked;
end;
procedure TForm_ExportNew.CB_FontSizesClick(Sender: TObject);
begin
Edit_FontSizes.Enabled:= CB_FontSizes.Checked;
end;
procedure TForm_ExportNew.CB_IncNodeHeadingClick(Sender: TObject);
var
Enabled: boolean;
begin
Enabled:= CB_IncNodeHeading.Checked;
CB_LevelTemplates.Enabled:= Enabled;
Edit_Symbols.Enabled:= Enabled;
Edit_LengthHeading.Enabled:= Enabled;
lblSymbols.Enabled:= Enabled;
lblLength.Enabled:= Enabled;
end;
procedure TForm_ExportNew.CB_IndentNodesClick(Sender: TObject);
var
Enabled: boolean;
begin
Enabled:= CB_IndentNodes.Checked;
Spin_Indent.Enabled:= Enabled;
LblIndent.Enabled:= Enabled;
CB_UseTab.Enabled:= Enabled;
end;
procedure TForm_ExportNew.Combo_FormatClick(Sender: TObject);
var
format: TExportFmt;
begin
Combo_TreeSelection.Enabled := ( RB_CurrentNote.Checked and ( myActiveNote.Kind = ntTree )
and ( TExportFmt(Combo_Format.ItemIndex) in [xfPlainText, xfRTF, xfHTML, xfKeyNote] ));
format:= TExportFmt( Combo_Format.ItemIndex );
Tab_TreePad.TabVisible:= (format = xfTreePad);
if format = xfKeyNote then
Tab_Options.TabVisible:= false
else begin
Tab_Options.TabVisible := (format <> xfTreePad);
RG_NodeMode.Enabled := (format <> xfTreePad);
RG_HTML.Visible := (format = xfHTML);
CB_UseTab.Enabled:= (format = xfPlainText) and (CB_IndentNodes.Checked);
end;
end;
procedure TForm_ExportNew.ReadConfig;
var
IniFile : TMemIniFile;
section : string;
begin
InitializeExportOptions( ExportOptions );
if ( not fileexists( myINIFN )) then exit;
IniFile := TMemIniFile.Create( myIniFN );
try
with IniFile do begin
section := ExportOptionsIniStr.section;
ExportOptions.ConfirmFilenames := readbool( section, ExportOptionsIniStr.ConfirmFilenames, ExportOptions.ConfirmFilenames );
ExportOptions.ConfirmOverwrite := readbool( section, ExportOptionsIniStr.ConfirmOverwrite, ExportOptions.ConfirmOverwrite );
ExportOptions.ExportSource := TExportSource( readinteger( section, ExportOptionsIniStr.ExportSource, ord( ExportOptions.ExportSource )));
ExportOptions.HTMLExportMethod := THTMLExportMethod(readinteger( section, ExportOptionsIniStr.HTMLExportMethod, ord(ExportOptions.HTMLExportMethod) ));
ExportOptions.IncludeNodeHeadings := readbool( section, ExportOptionsIniStr.IncludeNodeHeadings, ExportOptions.IncludeNodeHeadings );
ExportOptions.IncludeNoteHeadings := readbool( section, ExportOptionsIniStr.IncludeNoteHeadings, ExportOptions.IncludeNoteHeadings );
ExportOptions.ExcludeHiddenNodes := readbool( section, ExportOptionsIniStr.ExcludeHiddenNodes, ExportOptions.ExcludeHiddenNodes ); // [dpv]
ExportOptions.NodeLevelTemplates := readbool( section, ExportOptionsIniStr.UseLevelTemplates, ExportOptions.NodeLevelTemplates );
ExportOptions.SymbolsInHeading := readstring( section, ExportOptionsIniStr.SymbolsInHeading, ExportOptions.SymbolsInHeading );
ExportOptions.LengthHeading := readstring( section, ExportOptionsIniStr.LengthsHeading, ExportOptions.LengthHeading );
ExportOptions.AutoFontSizesInHeading := readbool( section, ExportOptionsIniStr.AutoFontSizesInHeading, ExportOptions.AutoFontSizesInHeading );
ExportOptions.FontSizesInHeading := readstring( section, ExportOptionsIniStr.FontSizesInHeading, ExportOptions.FontSizesInHeading );
ExportOptions.IndentNestedNodes := readbool( section, ExportOptionsIniStr.IndentNestedNodes, ExportOptions.IndentNestedNodes );
ExportOptions.IndentValue := readinteger( section, ExportOptionsIniStr.IndentValue, ExportOptions.IndentValue );
ExportOptions.IndentUsingTabs := readbool( section, ExportOptionsIniStr.IndentUsingTabs, ExportOptions.IndentUsingTabs );
ExportOptions.NumbTabInPlainText := readstring( section, ExportOptionsIniStr.NumbTabInPlainText, ExportOptions.NumbTabInPlainText );
ExportOptions.ExportPath := readstring( section, ExportOptionsIniStr.ExportPath, ExportOptions.ExportPath );
ExportOptions.NodeHeading := readstring( section, ExportOptionsIniStr.NodeHeading, ExportOptions.NodeHeading );
ExportOptions.NoteHeading := readstring( section, ExportOptionsIniStr.NoteHeading, ExportOptions.NoteHeading );
ExportOptions.SingleNodeFiles := readbool( section, ExportOptionsIniStr.SingleNodeFiles, ExportOptions.SingleNodeFiles );
ExportOptions.TargetFormat := TExportFmt( readinteger( section, ExportOptionsIniStr.TargetFormat, ord( ExportOptions.TargetFormat )));
ExportOptions.TreePadRTF := readbool( section, ExportOptionsIniStr.TreePadRTF, ExportOptions.TreePadRTF );
ExportOptions.TreePadForceMaster := readbool( section, ExportOptionsIniStr.TreePadForceMaster, ExportOptions.TreePadForceMaster );
ExportOptions.TreePadSingleFile := readbool( section, ExportOptionsIniStr.TreePadSingleFile, ExportOptions.TreePadSingleFile );
ExportOptions.TreeSelection := TTreeSelection( readinteger( section, ExportOptionsIniStr.TreeSelection, ord( ExportOptions.TreeSelection )));
end;
finally
IniFile.Free;
end;
end;
procedure TForm_ExportNew.RG_HTMLClick(Sender: TObject);
begin
ExportOptions.HTMLExportMethod := THTMLExportMethod(RG_HTML.ItemIndex);
end;
procedure TForm_ExportNew.TB_OpenDlgDirClick(Sender: TObject);
var
Dir: string;
begin
if SelectDirectory('','', Dir) then
Edit_Folder.Text:= Dir;
TB_OpenDlgDir.Down:= false;
end;
// ReadConfig
procedure TForm_ExportNew.WriteConfig;
var
IniFile : TMemIniFile;
section : string;
begin
IniFile := TMemIniFile.Create( myIniFN );
try
with IniFile do begin
section := ExportOptionsIniStr.section;
writebool( section, ExportOptionsIniStr.ConfirmFilenames, ExportOptions.ConfirmFilenames );
writebool( section, ExportOptionsIniStr.ConfirmOverwrite, ExportOptions.ConfirmOverwrite );
writeinteger( section, ExportOptionsIniStr.ExportSource, ord( ExportOptions.ExportSource ));
writeinteger( section, ExportOptionsIniStr.HTMLExportMethod, ord(ExportOptions.HTMLExportMethod) );
writebool( section, ExportOptionsIniStr.IncludeNodeHeadings, ExportOptions.IncludeNodeHeadings );
writebool( section, ExportOptionsIniStr.IncludeNoteHeadings, ExportOptions.IncludeNoteHeadings );
writebool( section, ExportOptionsIniStr.ExcludeHiddenNodes, ExportOptions.ExcludeHiddenNodes ); // [dpv]
writebool( section, ExportOptionsIniStr.UseLevelTemplates, ExportOptions.NodeLevelTemplates );
writestring( section, ExportOptionsIniStr.SymbolsInHeading, ExportOptions.SymbolsInHeading );
writestring( section, ExportOptionsIniStr.LengthsHeading, ExportOptions.LengthHeading );
writebool( section, ExportOptionsIniStr.AutoFontSizesInHeading, ExportOptions.AutoFontSizesInHeading );
writestring( section, ExportOptionsIniStr.FontSizesInHeading, ExportOptions.FontSizesInHeading );
writebool( section, ExportOptionsIniStr.IndentNestedNodes, ExportOptions.IndentNestedNodes );
writeinteger( section, ExportOptionsIniStr.IndentValue, ExportOptions.IndentValue );
writebool( section, ExportOptionsIniStr.IndentUsingTabs, ExportOptions.IndentUsingTabs );
writestring( section, ExportOptionsIniStr.NumbTabInPlainText, '"' + ExportOptions.NumbTabInPlainText + '"');
writestring( section, ExportOptionsIniStr.ExportPath, ExportOptions.ExportPath );
writestring( section, ExportOptionsIniStr.NodeHeading, ExportOptions.NodeHeading );
writestring( section, ExportOptionsIniStr.NoteHeading, ExportOptions.NoteHeading );
writebool( section, ExportOptionsIniStr.SingleNodeFiles, ExportOptions.SingleNodeFiles );
writeinteger( section, ExportOptionsIniStr.TargetFormat, ord( ExportOptions.TargetFormat ));
writebool( section, ExportOptionsIniStr.TreePadForceMaster, ExportOptions.TreePadForceMaster );
writebool( section, ExportOptionsIniStr.TreePadRTF, ExportOptions.TreePadRTF );
writebool( section, ExportOptionsIniStr.TreePadSingleFile, ExportOptions.TreePadSingleFile );
writeinteger( section, ExportOptionsIniStr.TreeSelection, ord( ExportOptions.TreeSelection ));
end;
IniFile.UpdateFile;
finally
IniFile.Free;
end;
end; // WriteConfig
procedure TForm_ExportNew.FormToOptions;
begin
with ExportOptions do begin
if RB_CurrentNote.Checked then
ExportSource := expCurrentNote
else
if RB_AllNotes.Checked then
ExportSource := expAllNotes
else
ExportSource := expSelectedNotes;
ExcludeHiddenNodes:= CheckBox_ExcludeHiddenNodes.Checked;
TreeSelection := TTreeSelection( Combo_TreeSelection.ItemIndex );
TargetFormat := TExportFmt( Combo_Format.ItemIndex );
SingleNodeFiles := ( RG_NodeMode.ItemIndex > 0 );
HTMLExportMethod := THTMLExportMethod(RG_HTML.ItemIndex);
ExportPath := ProperFolderName( Edit_Folder.Text );
ConfirmOverwrite := CheckBox_PromptOverwrite.Checked;
ConfirmFilenames := CheckBox_Ask.Checked;
IncludeNodeHeadings := CB_IncNodeHeading.Checked;
IncludeNoteHeadings := CB_IncNoteHeading.Checked;
SymbolsInHeading:= Edit_Symbols.Text;
LengthHeading:= Edit_LengthHeading.Text;
FontSizesInHeading:= Edit_FontSizes.Text;
NodeLevelTemplates:= CB_LevelTemplates.Checked;
AutoFontSizesInHeading:= CB_FontSizes.Checked;
IndentNestedNodes := CB_IndentNodes.Checked;
IndentValue := Spin_Indent.Value;
IndentUsingTabs := CB_UseTab.Checked;
NodeHeading := Edit_NodeHead.Text;
if ( NodeHeading = '' ) then
NodeHeading := _TokenChar + EXP_NODENAME;
NoteHeading := Edit_NoteHead.Text;
if ( NoteHeading = '' ) then
NoteHeading := _TokenChar + EXP_NOTENAME;
TreePadRTF := ( RG_TreePadVersion.ItemIndex > 0 );
TreePadSingleFile := ( RG_TreePadMode.ItemIndex > 0 );
TreePadForceMaster := ( RG_TreePadMaster.ItemIndex > 0 );
end;
end; // FormToOptions
procedure TForm_ExportNew.OptionsToForm;
begin
with ExportOptions do begin
case ExportSource of
expCurrentNote : RB_CurrentNote.Checked := true;
expAllNotes : RB_AllNotes.Checked := true;
expSelectedNotes : RB_SelectedNotes.Checked := true;
end;
CheckBox_ExcludeHiddenNodes.Checked:= ExcludeHiddenNodes;
Combo_TreeSelection.ItemIndex := ord( TreeSelection );
Combo_Format.ItemIndex := ord( TargetFormat );
if SingleNodeFiles then
RG_NodeMode.ItemIndex := 1
else
RG_NodeMode.ItemIndex := 0;
RG_HTML.ItemIndex := ord(HTMLExportMethod);
Edit_Folder.Text := ExportPath;
CheckBox_PromptOverwrite.Checked := ConfirmOverwrite;
CheckBox_Ask.Checked := ConfirmFilenames;
CB_IncNodeHeading.Checked := IncludeNodeHeadings;
CB_IncNoteHeading.Checked := IncludeNoteHeadings;
Edit_NodeHead.Text := NodeHeading;
Edit_NoteHead.Text := NoteHeading;
Edit_Symbols.Text:= SymbolsInHeading;
Edit_LengthHeading.Text:= LengthHeading;
Edit_FontSizes.Text:= FontSizesInHeading;
CB_LevelTemplates.Checked:= NodeLevelTemplates;
CB_FontSizes.Checked:= AutoFontSizesInHeading;
CB_IndentNodes.Checked := IndentNestedNodes;
Spin_Indent.Value:= IndentValue;
CB_UseTab.Checked:= IndentUsingTabs;
CB_IndentNodesClick(nil);
CB_IncNodeHeadingClick(nil);
if TreePadRTF then
RG_TreePadVersion.ItemIndex := 1
else
RG_TreePadVersion.ItemIndex := 0;
if TreePadSingleFile then
RG_TreePadMode.ItemIndex := 1
else
RG_TreePadMode.ItemIndex := 0;
if TreePadForceMaster then
RG_TreePadMaster.ItemIndex := 1
else
RG_TreePadMaster.ItemIndex := 0;
{
HTMLTemplateFN : string;
HTMLWithFrames : boolean;
HTMLWithTemplate : boolean;
}
// NodeLevelTemplate : string;
end;
end; // OptionsToForm
procedure TForm_ExportNew.Button_OKClick(Sender: TObject);
begin
PerformExport;
end;
function TForm_ExportNew.Validate : boolean;
begin
result := false;
if ( ExportOptions.ExportPath = '' ) then begin
DoMessageBox( STR_02, mtError, [mbOK], 0 );
exit;
end;
if ( not System.SysUtils.DirectoryExists( ExportOptions.ExportPath )) then begin
DoMessageBox( STR_03, mtError, [mbOK], 0 );
exit;
end;
result := true;
end; // Validate
procedure TForm_ExportNew.PerformExport;
var
myNote : TTabNote;
i, cnt, noteIdx : integer;
RTFAux : TTabRichEdit;
NoteHeading, NodeHeading : string;
NoteHeadingRTF, NodeHeadingRTF : string;
NoteHeadingTpl, NodeHeadingTpl : string;
NodeLevelHeadingTpl : array of string;
NodeHeadingTpl_Aux: string;
NodeText: AnsiString;
ExitMessage : string;
NodeTextSize : integer;
StartLevel, ThisNodeIndex : integer;
tmpStream : TMemoryStream;
ExportedNotes, ExportedNodes, tmpExportedNodes : integer;
WasError, WasAborted : boolean;
StartTreeNode, myTreeNode : TTreeNTNode;
myNoteNode : TNoteNode;
TreePadFile : TTextfile;
TreePadFN : string;
TreePadNodeLevelInc : integer; // 0 or 1
NodeStreamIsRTF : boolean;
Encoding: TEncoding;
FN, ext: string;
OnlyNotHiddenNodes, OnlyCheckedNodes: boolean;
ContainsImages: boolean;
ContainsImgIDsRemoved: boolean;
RTFwithImages: AnsiString;
FSize, SS, SL: integer;
SSNode: integer;
procedure LoadNodeLevelTemplates;
var
i: integer;
FileName_Aux, FileName: string;
Tpl: string;
begin
SetLength(NodeLevelHeadingTpl, 10);
FileName_Aux:= ExtractFilePath(INI_FN) + 'nodehead';
for i:= 1 to 10 do begin
FileName:= Format('%s_%d%s', [FileName_Aux, i, ext_RTF]);
Tpl := LoadRTFHeadingTemplate(FileName);
NodeLevelHeadingTpl[i-1]:= Tpl;
end;
end;
procedure IndentContent (level: integer);
var
SS: integer;
begin
SS:= RTFAux.SelStart;
RTFAux.SetSelection(SSNode, SS, true);
RTFAux.Paragraph.FirstIndentRelative := ExportOptions.IndentValue * (level-1);
RTFAux.SelStart:= SS;
end;
begin
FormToOptions;
if ( not Validate ) then exit;
WriteConfig;
if (ExportOptions.TargetFormat= xfKeyNote) and (ExportOptions.TreeSelection = tsNode) and (Combo_TreeSelection.Enabled) then
if ( messagedlg( STR_20, mtInformation, [mbOK,mbCancel], 0 ) <> mrOK ) then
Exit;
cnt := 0;
for i := 1 to myNotes.Notes.Count do begin
myNote:= myNotes.Notes[pred(i)];
case ExportOptions.ExportSource of
expCurrentNote : begin
if ( myNote = myActiveNote ) then
myNote.Info := 1
else
myNote.Info := 0;
end;
expAllNotes : begin
myNote.Info := 1;
end;
expSelectedNotes : begin
// nothing, notes already tagged for exporting
end;
end;
if ( myNote.Info > 0 ) then
inc( cnt );
end;
if ( cnt = 0 ) then begin
messagedlg( STR_04, mtError, [mbOK], 0 );
exit;
end;
IsBusy := true;
FileIsBusy := true; // To avoid that kn_Main.TimerTimer, at the beginning can interfere calling to NoteFile.UpdateTextPlainVariables(); (it also uses the same RTFAux, with GetAuxEditorControl)
Screen.Cursor := crHourGlass;
DoAbort := false;
ExportedNotes := 0;
ExportedNodes := 0;
NoteHeading := '';
NodeHeading := '';
WasError := false;
WasAborted := false;
NoteHeadingRTF := '';
NodeHeadingRTF := '';
StartLevel := 0;
TreePadFN := '';
TreePadNodeLevelInc := 0;
RTFAux:= CreateRTFAuxEditorControl;
if ExportOptions.ConfirmOverwrite then
SaveDlg.Options := [ofHideReadOnly,ofPathMustExist,ofOverwritePrompt]
else
SaveDlg.Options := [ofHideReadOnly,ofPathMustExist];
SaveDlg.Filename := '';
SaveDlg.InitialDir := ExportOptions.ExportPath;
try
try
if ExportOptions.TargetFormat = xfKeyNote then begin // --- xfKeyNote
myTreeNode := nil;
OnlyNotHiddenNodes:= ExportOptions.ExcludeHiddenNodes;
OnlyCheckedNodes:= false;
if (ExportOptions.ExportSource = expCurrentNote ) then
if (ActiveNote.Kind = ntTree) then begin
if (ExportOptions.TreeSelection in [tsNode, tsSubtree]) then
myTreeNode := TTreeNote(ActiveNote).TV.Selected;
if (ExportOptions.TreeSelection = tsCheckedNodes) then
OnlyCheckedNodes:= true;
end;
FN := GetExportFilename('Export_' + ExtractFileName(NoteFile.FileName) );
if FN <> '' then begin
ext := Extractfileext( FN );
if (ext = '') then FN := FN + ext_KeyNote;
NoteFileCopy (ExportedNotes, ExportedNodes, FN, true, myTreeNode, OnlyNotHiddenNodes, OnlyCheckedNodes );
end;
exit; // ------------
end;
// load general, default templates
NoteHeadingTpl := LoadRTFHeadingTemplate( NoteHeadingTpl_FN);
if ( NoteHeadingTpl = '' ) then
NoteHeadingTpl := _Default_NoteHeadingTpl;
NodeHeadingTpl := LoadRTFHeadingTemplate( NodeHeadingTpl_FN);
if ( NodeHeadingTpl = '' ) then
NodeHeadingTpl := _Default_NodeHeadingTpl;
// load level templates, if any
if ExportOptions.NodeLevelTemplates then
LoadNodeLevelTemplates;
PrepareExportOptions (ExportOptions.LengthHeading, ExportOptions.FontSizesInHeading);
for NoteIdx := 1 to myNotes.Notes.Count do begin // ----------------------------------------------------------- FOR EACH NOTE :
Application.ProcessMessages;
if DoAbort then break;
myNote := myNotes.Notes[pred( NoteIdx )];
if ( myNote.Info > 0 ) then begin
// this note has been marked for exporting
if ExportOptions.IncludeNoteHeadings then begin
NoteHeading := ExpandExpTokenString( ExportOptions.NoteHeading, myNotes.Filename, RemoveAccelChar( myNote.Name ), '', 0, 0, myNote.TabSize );
NoteHeadingRTF := MergeHeadingWithRTFTemplate( EscapeTextForRTF( NoteHeading ), NoteHeadingTpl );
end;
case ExportOptions.TargetFormat of
xfPlainText, xfRTF, xfHTML : begin // ============================= xfPlainText, xfRTF, xfHTML
case myNote.Kind of
ntRTF : begin // -------------------------------------------------------------- ntRTF
tmpStream := TMemoryStream.Create;
try
Encoding:= nil;
if not myNote.PlainText then
myNote.Editor.StreamFormat:= sfRichText
else begin
myNote.Editor.StreamFormat:= sfPlainText;
Encoding:= TEncoding.UTF8;
end;
myNote.Editor.Lines.SaveToStream( tmpStream, Encoding );
tmpStream.Position := 0;
RTFwithImages:= ImagesManager.ProcessImagesInRTF(tmpStream.Memory, tmpStream.Size, nil, imImage, '', 0, ContainsImgIDsRemoved, ContainsImages, false);
if RTFwithImages <> '' then
RTFAux.PutRtfText(RTFwithImages,false) // All hidden KNT characters are now removed from FlushExportFile
else
RTFAux.Lines.LoadFromStream( tmpStream );
if ( ExportOptions.IncludeNoteHeadings and ( NoteHeadingRTF <> '' )) then begin
var ApplyAutoFontSizes: boolean := ExportOptions.AutoFontSizesInHeading and (FontSizes_Max > 0);
RTFAux.SelStart := 0;
RTFAux.PutRtfText(NoteHeadingRTF, true, true, ApplyAutoFontSizes); // Keep selected if ApplyAutoFontSizes
if ApplyAutoFontSizes then begin
SL:= RTFAux.SelLength;
RTFAux.SelAttributes.Size:= FontSizes_Max;
RTFAux.SetSelection(SL, SL, true);
end;
end;
if FlushExportFile( RTFAux, myNote, RemoveAccelChar( myNote.Name )) then
inc( ExportedNotes );
finally
tmpStream.Free;
end;
end;
// --------------------------------------------------------------- ntTree
ntTree : begin
myNote.EditorToDataStream; // must flush contents of richedit to active node's internal stream
if (( ExportOptions.ExportSource = expCurrentNote ) and
( ExportOptions.TreeSelection in [tsNode, tsSubtree] )) then
myTreeNode := TTreeNote( myNote ).TV.Selected
else
myTreeNode := TTreeNote( myNote ).TV.Items.GetFirstNode;
StartTreeNode := myTreeNode;
ThisNodeIndex := 1;