forked from rabbitmq/rabbitmq-server
/
per_node_limit_SUITE.erl
205 lines (169 loc) · 7.75 KB
/
per_node_limit_SUITE.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
%% This Source Code Form is subject to the terms of the Mozilla Public
%% License, v. 2.0. If a copy of the MPL was not distributed with this
%% file, You can obtain one at https://mozilla.org/MPL/2.0/.
%%
%% Copyright (c) 2007-2024 Broadcom. All Rights Reserved. The term “Broadcom” refers to Broadcom Inc. and/or its subsidiaries. All rights reserved.
%%
-module(per_node_limit_SUITE).
-include_lib("common_test/include/ct.hrl").
-include_lib("amqp_client/include/amqp_client.hrl").
-include_lib("eunit/include/eunit.hrl").
-compile(export_all).
all() ->
[
{group, limit_tests}
].
groups() ->
[
{limit_tests, [], [
node_connection_limit,
vhost_limit,
channel_consumers_limit,
node_channel_limit
]}
].
suite() ->
[
{timetrap, {minutes, 3}}
].
%% -------------------------------------------------------------------
%% Testsuite setup/teardown.
%% -------------------------------------------------------------------
init_per_suite(Config) ->
rabbit_ct_helpers:log_environment(),
rabbit_ct_helpers:run_setup_steps(Config).
end_per_suite(Config) ->
rabbit_ct_helpers:run_teardown_steps(Config).
init_per_group(Group, Config) ->
Config1 = rabbit_ct_helpers:set_config(Config, [
{rmq_nodename_suffix, Group},
{rmq_nodes_count, 1}
]),
rabbit_ct_helpers:run_steps(Config1,
rabbit_ct_broker_helpers:setup_steps() ++
rabbit_ct_client_helpers:setup_steps()).
end_per_group(_Group, Config) ->
rabbit_ct_helpers:run_steps(Config,
rabbit_ct_client_helpers:teardown_steps() ++
rabbit_ct_broker_helpers:teardown_steps()).
init_per_testcase(Testcase, Config) ->
rabbit_ct_helpers:testcase_started(Config, Testcase).
end_per_testcase(vhost_limit = Testcase, Config) ->
set_node_limit(Config, vhost_max, infinity),
set_node_limit(Config, channel_max_per_node, infinity),
set_node_limit(Config, consumer_max_per_channel, infinity),
set_node_limit(Config, connection_max, infinity),
[rabbit_ct_broker_helpers:delete_vhost(Config, integer_to_binary(I)) || I <- lists:seq(1,4)],
rabbit_ct_helpers:testcase_finished(Config, Testcase);
end_per_testcase(Testcase, Config) ->
set_node_limit(Config, vhost_max, infinity),
set_node_limit(Config, channel_max_per_node, infinity),
set_node_limit(Config, consumer_max_per_channel, infinity),
set_node_limit(Config, connection_max, infinity),
rabbit_ct_helpers:testcase_finished(Config, Testcase).
%% -------------------------------------------------------------------
%% Test cases
%% -------------------------------------------------------------------
node_connection_limit(Config) ->
%% Set limit to 0, don't accept any connections
set_node_limit(Config, connection_max, 0),
{error, not_allowed} = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0),
%% Set limit to 5, accept 5 connections
Connections = open_connections_to_limit(Config, 5),
%% But no more than 5
{error, not_allowed} = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0),
close_all_connections(Connections),
set_node_limit(Config, connection_max, infinity),
C = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0),
true = is_pid(C),
close_all_connections([C]),
ok.
vhost_limit(Config) ->
set_node_limit(Config, vhost_max, 0),
{'EXIT',{vhost_limit_exceeded, _}} = rabbit_ct_broker_helpers:add_vhost(Config, <<"foo">>),
set_node_limit(Config, vhost_max, 5),
[ok = rabbit_ct_broker_helpers:add_vhost(Config, integer_to_binary(I)) || I <- lists:seq(1,4)],
{'EXIT',{vhost_limit_exceeded, _}} = rabbit_ct_broker_helpers:add_vhost(Config, <<"5">>),
[rabbit_ct_broker_helpers:delete_vhost(Config, integer_to_binary(I)) || I <- lists:seq(1,4)],
set_node_limit(Config, vhost_max, infinity),
[ok = rabbit_ct_broker_helpers:add_vhost(Config, integer_to_binary(I)) || I <- lists:seq(1,4)],
ok = rabbit_ct_broker_helpers:add_vhost(Config, <<"5">>),
[rabbit_ct_broker_helpers:delete_vhost(Config, integer_to_binary(I)) || I <- lists:seq(1,5)],
ok.
node_channel_limit(Config) ->
set_node_limit(Config, channel_max_per_node, 5),
VHost = <<"foobar">>,
User = <<"guest">>,
ok = rabbit_ct_broker_helpers:add_vhost(Config, VHost),
ok = rabbit_ct_broker_helpers:set_full_permissions(Config, User, VHost),
Conn1 = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0, VHost),
Conn2 = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0, VHost),
0 = count_channels_per_node(Config),
lists:foreach(fun(N) when (N band 1) == 1 -> {ok, _} = open_channel(Conn1);
(_) -> {ok,_ } = open_channel(Conn2)
end, lists:seq(1, 5)),
5 = count_channels_per_node(Config),
%% In total 5 channels are open on this node, so a new one, regardless of
%% connection, will not be allowed. It will terminate the connection with
%% its channels too. So
{error, not_allowed_crash} = open_channel(Conn2),
3 = count_channels_per_node(Config),
%% As the connection is dead, so are the 2 channels, so we should be able to
%% create 2 more on Conn1
{ok , _} = open_channel(Conn1),
{ok , _} = open_channel(Conn1),
%% But not a third
{error, not_allowed_crash} = open_channel(Conn1),
%% Now all connections are closed, so there should be 0 open connections
0 = count_channels_per_node(Config),
close_all_connections([Conn1, Conn2]),
ok.
channel_consumers_limit(Config) ->
set_node_limit(Config, consumer_max_per_channel, 1),
VHost = <<"foobar">>,
User = <<"guest">>,
ok = rabbit_ct_broker_helpers:add_vhost(Config, VHost),
ok = rabbit_ct_broker_helpers:set_full_permissions(Config, User, VHost),
Conn1 = rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0, VHost),
{ok, Ch} = open_channel(Conn1),
Q = <<"Q">>, Tag = <<"Tag">>,
{ok, _} = consume(Ch, Q, Tag),
{error, not_allowed_crash} = consume(Ch, Q, Tag), % Reusing Tag should fail
close_all_connections([Conn1]),
ok.
%% -------------------------------------------------------------------
%% Implementation
%% -------------------------------------------------------------------
open_connections_to_limit(Config, Limit) ->
set_node_limit(Config, connection_max, Limit),
Connections = [rabbit_ct_client_helpers:open_unmanaged_connection(Config, 0) || _ <- lists:seq(1,Limit)],
true = lists:all(fun(E) -> is_pid(E) end, Connections),
Connections.
close_all_connections(Connections) ->
[rabbit_ct_client_helpers:close_connection(C) || C <- Connections].
set_node_limit(Config, Type, Limit) ->
rabbit_ct_broker_helpers:rpc(Config, 0,
application,
set_env, [rabbit, Type, Limit]).
consume(Ch, Q, Tag) ->
#'queue.declare_ok'{queue = Q} = amqp_channel:call(Ch, #'queue.declare'{queue = Q}),
try amqp_channel:call(Ch, #'basic.consume'{queue = Q, consumer_tag = Tag}) of
#'basic.consume_ok'{} = OK -> {ok, OK};
NotOk -> {error, NotOk}
catch
_:_Error -> {error, not_allowed_crash}
end.
open_channel(Conn) when is_pid(Conn) ->
try amqp_connection:open_channel(Conn) of
{ok, Ch} -> {ok, Ch};
{error, _} ->
{error, not_allowed}
catch
_:_Error -> {error, not_allowed_crash}
end.
count_channels_per_node(Config) ->
NodeConfig = rabbit_ct_broker_helpers:get_node_config(Config, 0),
rabbit_ct_broker_helpers:rpc(Config, 0,
rabbit_channel_tracking,
channel_count_on_node,
[?config(nodename, NodeConfig)]).