-
Notifications
You must be signed in to change notification settings - Fork 2
/
view.qc
1127 lines (962 loc) · 28.9 KB
/
view.qc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#include "m_player.h"
// view pitching times
const float DAMAGE_TIME = 0.5f;
const float FALL_TIME = 0.3f;
PROGS_LOCAL static entity current_player;
PROGS_LOCAL static vector forward, right, up;
PROGS_LOCAL static float xyspeed, bobmove, bobfracsin;
PROGS_LOCAL static int bobcycle;
/*
=============
P_WorldEffects
=============
*/
static void(void) P_WorldEffects =
{
bool breather;
bool envirosuit;
int current_waterlevel, old_waterlevel;
if (current_player.movetype == MOVETYPE_NOCLIP)
{
current_player.air_finished_framenum = level.framenum + 12 * BASE_FRAMERATE; // don't need air
return;
}
current_waterlevel = current_player.waterlevel;
old_waterlevel = current_player.client.old_waterlevel;
current_player.client.old_waterlevel = current_waterlevel;
breather = (bool)(current_player.client.breather_framenum > level.framenum);
envirosuit = (bool)(current_player.client.enviro_framenum > level.framenum);
//
// if just entered a water volume, play a sound
//
if (!old_waterlevel && current_waterlevel)
{
#if defined(SINGLE_PLAYER)
PlayerNoise(current_player, current_player.s.origin, PNOISE_SELF);
#endif
if (current_player.watertype & CONTENTS_LAVA)
gi.sound(current_player, CHAN_BODY, gi.soundindex("player/lava_in.wav"), 1, ATTN_NORM, 0);
else if (current_player.watertype & CONTENTS_SLIME)
gi.sound(current_player, CHAN_BODY, gi.soundindex("player/watr_in.wav"), 1, ATTN_NORM, 0);
else if (current_player.watertype & CONTENTS_WATER)
gi.sound(current_player, CHAN_BODY, gi.soundindex("player/watr_in.wav"), 1, ATTN_NORM, 0);
current_player.flags |= FL_INWATER;
// clear damage_debounce, so the pain sound will play immediately
current_player.damage_debounce_framenum = level.framenum - 1 * BASE_FRAMERATE;
}
//
// if just completely exited a water volume, play a sound
//
if (old_waterlevel && !current_waterlevel)
{
#if defined(SINGLE_PLAYER)
PlayerNoise(current_player, current_player.s.origin, PNOISE_SELF);
#endif
gi.sound(current_player, CHAN_BODY, gi.soundindex("player/watr_out.wav"), 1, ATTN_NORM, 0);
current_player.flags &= ~FL_INWATER;
}
//
// check for head just going under water
//
if (old_waterlevel != 3 && current_waterlevel == 3)
gi.sound(current_player, CHAN_BODY, gi.soundindex("player/watr_un.wav"), 1, ATTN_NORM, 0);
//
// check for head just coming out of water
//
if (old_waterlevel == 3 && current_waterlevel != 3)
{
if (current_player.air_finished_framenum < level.framenum)
#if defined(SINGLE_PLAYER)
{
#endif
// gasp for air
gi.sound(current_player, CHAN_VOICE, gi.soundindex("player/gasp1.wav"), 1, ATTN_NORM, 0);
#if defined(SINGLE_PLAYER)
PlayerNoise(current_player, current_player.s.origin, PNOISE_SELF);
}
#endif
else if (current_player.air_finished_framenum < level.framenum + 11 * BASE_FRAMERATE)
// just break surface
gi.sound(current_player, CHAN_VOICE, gi.soundindex("player/gasp2.wav"), 1, ATTN_NORM, 0);
}
//
// check for drowning
//
if (current_waterlevel == 3)
{
// breather or envirosuit give air
if (breather || envirosuit)
{
current_player.air_finished_framenum = level.framenum + 10 * BASE_FRAMERATE;
if (((int)(current_player.client.breather_framenum - level.framenum) % 25) == 0)
{
if (!current_player.client.breather_sound)
gi.sound(current_player, CHAN_AUTO, gi.soundindex("player/u_breath1.wav"), 1, ATTN_NORM, 0);
else
gi.sound(current_player, CHAN_AUTO, gi.soundindex("player/u_breath2.wav"), 1, ATTN_NORM, 0);
current_player.client.breather_sound ^= 1;
#if defined(SINGLE_PLAYER)
PlayerNoise(current_player, current_player.s.origin, PNOISE_SELF);
#endif
}
}
// if out of air, start drowning
if (current_player.air_finished_framenum < level.framenum)
{
// drown!
if (current_player.client.next_drown_framenum < level.framenum
&& current_player.health > 0)
{
current_player.client.next_drown_framenum = level.framenum + 1 * BASE_FRAMERATE;
// take more damage the longer underwater
current_player.dmg += 2;
if (current_player.dmg > 15)
current_player.dmg = 15;
// play a gurp sound instead of a normal pain sound
if (current_player.health <= current_player.dmg)
gi.sound(current_player, CHAN_VOICE, gi.soundindex("player/drown1.wav"), 1, ATTN_NORM, 0);
else if (Q_rand() & 1)
gi.sound(current_player, CHAN_VOICE, gi.soundindex("*gurp1.wav"), 1, ATTN_NORM, 0);
else
gi.sound(current_player, CHAN_VOICE, gi.soundindex("*gurp2.wav"), 1, ATTN_NORM, 0);
current_player.pain_debounce_framenum = level.framenum;
T_Damage(current_player, world, world, vec3_origin, current_player.s.origin, vec3_origin, current_player.dmg, 0, DAMAGE_NO_ARMOR, MOD_WATER);
}
}
}
else
{
current_player.air_finished_framenum = level.framenum + 12 * BASE_FRAMERATE;
current_player.dmg = 2;
}
//
// check for sizzle damage
//
if (current_waterlevel && (current_player.watertype & (CONTENTS_LAVA | CONTENTS_SLIME)))
{
if (current_player.watertype & CONTENTS_LAVA)
{
if (current_player.health > 0
&& current_player.pain_debounce_framenum <= level.framenum
&& current_player.client.invincible_framenum < level.framenum)
{
if (Q_rand() & 1)
gi.sound(current_player, CHAN_VOICE, gi.soundindex("player/burn1.wav"), 1, ATTN_NORM, 0);
else
gi.sound(current_player, CHAN_VOICE, gi.soundindex("player/burn2.wav"), 1, ATTN_NORM, 0);
current_player.pain_debounce_framenum = level.framenum + 1 * BASE_FRAMERATE;
}
if (envirosuit) // take 1/3 damage with envirosuit
T_Damage(current_player, world, world, vec3_origin, current_player.s.origin, vec3_origin, 1 * current_waterlevel, 0, 0, MOD_LAVA);
else
T_Damage(current_player, world, world, vec3_origin, current_player.s.origin, vec3_origin, 3 * current_waterlevel, 0, 0, MOD_LAVA);
}
if (current_player.watertype & CONTENTS_SLIME)
if (!envirosuit)
// no damage from slime with envirosuit
T_Damage(current_player, world, world, vec3_origin, current_player.s.origin, vec3_origin, 1 * current_waterlevel, 0, 0, MOD_SLIME);
}
}
/*
===============
SV_CalcRoll
===============
*/
static float(vector angles, vector velocity) SV_CalcRoll =
{
float sign;
float side;
float value;
side = velocity * right;
sign = side < 0f ? -1f : 1f;
side = fabs(side);
value = sv_rollangle.floatVal;
if (side < sv_rollspeed.floatVal)
side = side * value / sv_rollspeed.floatVal;
else
side = value;
return side * sign;
}
/*
=================
P_FallingDamage
=================
*/
static void(entity ent) P_FallingDamage =
{
float delta;
int damage;
vector dir;
if (ent.s.modelindex != 255)
return; // not in the player model
if (ent.movetype == MOVETYPE_NOCLIP)
return;
if ((ent.client.oldvelocity[2] < 0f) && (ent.velocity[2] > ent.client.oldvelocity[2]) && (ent.groundentity == null_entity))
delta = ent.client.oldvelocity[2];
else if (ent.groundentity == null_entity)
return;
else
delta = ent.velocity.z - ent.client.oldvelocity[2];
delta = delta * delta * 0.0001f;
#ifdef HOOK_CODE
// never take damage if just release grapple or on grapple
if ((level.framenum - ent.client.grapplereleaseframenum) <= (2 * BASE_FRAMERATE) ||
(ent.client.grapple &&
ent.client.grapplestate > GRAPPLE_STATE_FLY))
return;
#endif
// never take falling damage if completely underwater
if (ent.waterlevel == 3)
return;
if (ent.waterlevel == 2)
delta *= 0.25f;
if (ent.waterlevel == 1)
delta *= 0.5f;
if (delta < 1)
return;
if (delta < 15)
{
ent.s.event = EV_FOOTSTEP;
return;
}
ent.client.fall_value = delta * 0.5f;
if (ent.client.fall_value > 40)
ent.client.fall_value = 40f;
ent.client.fall_time = level.time + FALL_TIME;
if (delta > 30)
{
if (ent.health > 0)
{
if (delta >= 55)
ent.s.event = EV_FALLFAR;
else
ent.s.event = EV_FALL;
}
ent.pain_debounce_framenum = level.framenum; // no normal pain sound
damage = (int)((delta - 30) / 2);
if (damage < 1)
damage = 1;
dir = '0 0 1';
if !(dmflags.intVal & DF_NO_FALLING)
T_Damage(ent, world, world, dir, ent.s.origin, vec3_origin, damage, 0, 0, MOD_FALLING);
}
else
{
ent.s.event = EV_FALLSHORT;
return;
}
}
static const vector power_color = '0.0 1.0 0.0';
static const vector acolor = '1.0 1.0 1.0';
static const vector bcolor = '1.0 0.0 0.0';
/*
===============
P_DamageFeedback
Handles color blends and view kicks
===============
*/
static void(entity player) P_DamageFeedback =
{
float side;
float realcount, dcount, kick;
vector v;
int r, l;
// flash the backgrounds behind the status numbers
player.client.ps.stats[STAT_FLASHES] = 0;
if (player.client.damage_blood)
player.client.ps.stats[STAT_FLASHES] |= 1;
if (player.client.damage_armor && !(player.flags & FL_GODMODE) && (player.client.invincible_framenum <= level.framenum))
player.client.ps.stats[STAT_FLASHES] |= 2;
// total points of damage shot at the player this frame
dcount = (float)(player.client.damage_blood + player.client.damage_armor + player.client.damage_parmor);
if (dcount == 0)
return; // didn't take any damage
// start a pain animation if still in the player model
if (player.client.anim_priority < ANIM_PAIN && player.s.modelindex == 255) {
static int i;
player.client.anim_priority = ANIM_PAIN;
if (player.client.ps.pmove.pm_flags & PMF_DUCKED) {
player.s.frame = FRAME_crpain1 - 1;
player.client.anim_end = FRAME_crpain4;
} else {
i = (i + 1) % 3;
switch (i) {
case 0:
player.s.frame = FRAME_pain101 - 1;
player.client.anim_end = FRAME_pain104;
break;
case 1:
player.s.frame = FRAME_pain201 - 1;
player.client.anim_end = FRAME_pain204;
break;
case 2:
player.s.frame = FRAME_pain301 - 1;
player.client.anim_end = FRAME_pain304;
break;
}
}
}
realcount = dcount;
if (dcount < 10)
dcount = 10f; // always make a visible effect
// play an apropriate pain sound
if ((level.framenum > player.pain_debounce_framenum) && !(player.flags & FL_GODMODE) && (player.client.invincible_framenum <= level.framenum)) {
r = 1 + (Q_rand() & 1);
player.pain_debounce_framenum = (int)(level.framenum + 0.7f * BASE_FRAMERATE);
if (player.health < 25)
l = 25;
else if (player.health < 50)
l = 50;
else if (player.health < 75)
l = 75;
else
l = 100;
gi.sound(player, CHAN_VOICE, gi.soundindex(va("*pain%i_%i.wav", l, r)), 1, ATTN_NORM, 0);
}
// the total alpha of the blend is always proportional to count
if (player.client.damage_alpha < 0)
player.client.damage_alpha = 0;
player.client.damage_alpha += dcount * 0.01f;
if (player.client.damage_alpha < 0.2f)
player.client.damage_alpha = 0.2f;
if (player.client.damage_alpha > 0.6f)
player.client.damage_alpha = 0.6f; // don't go too saturated
// the color of the blend will vary based on how much was absorbed
// by different armors
v = vec3_origin;
if (player.client.damage_parmor)
v += ((float)player.client.damage_parmor / realcount * power_color);
if (player.client.damage_armor)
v += ((float)player.client.damage_armor / realcount * acolor);
if (player.client.damage_blood)
v += ((float)player.client.damage_blood / realcount * bcolor);
player.client.damage_blend = v;
//
// calculate view angle kicks
//
kick = fabs(player.client.damage_knockback);
if (kick && player.health > 0) { // kick of 0 means no view adjust at all
kick = kick * 100 / player.health;
if (kick < dcount * 0.5f)
kick = dcount * 0.5f;
if (kick > 50)
kick = 50f;
v = player.client.damage_from - player.s.origin;
VectorNormalize(v);
side = v * right;
player.client.v_dmg_roll = kick * side * 0.3f;
side = -(v * forward);
player.client.v_dmg_pitch = kick * side * 0.3f;
player.client.v_dmg_time = level.time + DAMAGE_TIME;
}
//
// clear totals
//
player.client.damage_blood = 0;
player.client.damage_armor = 0;
player.client.damage_parmor = 0;
player.client.damage_knockback = 0;
}
/*
===============
SV_CalcViewOffset
Auto pitching on slopes?
fall from 128: 400 = 160000
fall from 256: 580 = 336400
fall from 384: 720 = 518400
fall from 512: 800 = 640000
fall from 640: 960 =
damage = deltavelocity*deltavelocity * 0.0001
===============
*/
static void(entity ent) SV_CalcViewOffset =
{
float bob;
float ratio;
float delta;
vector v;
//===================================
// if dead, fix the angle and don't add any kick
if (ent.deadflag) {
ent.client.ps.kick_angles = vec3_origin;
ent.client.ps.viewangles[ROLL] = 40f;
ent.client.ps.viewangles[PITCH] = -15f;
ent.client.ps.viewangles[YAW] = ent.client.killer_yaw;
} else {
// add angles based on weapon kick
ent.client.ps.kick_angles = ent.client.kick_angles;
// add angles based on damage kick
ratio = (ent.client.v_dmg_time - level.time) / DAMAGE_TIME;
if (ratio < 0) {
ratio = 0;
ent.client.v_dmg_pitch = 0;
ent.client.v_dmg_roll = 0;
}
ent.client.ps.kick_angles[PITCH] += ratio * ent.client.v_dmg_pitch;
ent.client.ps.kick_angles[ROLL] += ratio * ent.client.v_dmg_roll;
// add pitch based on fall kick
ratio = (ent.client.fall_time - level.time) / FALL_TIME;
if (ratio < 0)
ratio = 0;
ent.client.ps.kick_angles[PITCH] += ratio * ent.client.fall_value;
// add angles based on velocity
delta = ent.velocity * forward;
ent.client.ps.kick_angles[PITCH] += delta * run_pitch.floatVal;
delta = ent.velocity * right;
ent.client.ps.kick_angles[ROLL] += delta * run_roll.floatVal;
// add angles based on bob
delta = bobfracsin * bob_pitch.floatVal * xyspeed;
if (ent.client.ps.pmove.pm_flags & PMF_DUCKED)
delta *= 6; // crouching
ent.client.ps.kick_angles[PITCH] += delta;
delta = bobfracsin * bob_roll.floatVal * xyspeed;
if (ent.client.ps.pmove.pm_flags & PMF_DUCKED)
delta *= 6; // crouching
if (bobcycle & 1)
delta = -delta;
ent.client.ps.kick_angles[ROLL] += delta;
}
//===================================
// base origin
v = vec3_origin;
// add view height
v.z += ent.viewheight;
// add fall height
ratio = (ent.client.fall_time - level.time) / FALL_TIME;
if (ratio < 0)
ratio = 0;
v.z -= ratio * ent.client.fall_value * 0.4f;
// add bob height
bob = bobfracsin * xyspeed * bob_up.floatVal;
if (bob > 6)
bob = 6f;
v.z += bob;
// add kick offset
v += ent.client.kick_origin;
// absolutely bound offsets
// so the view can never be outside the player box
if (v.x < -14)
v.x = -14f;
else if (v.x > 14)
v.x = 14f;
if (v.y < -14)
v.y = -14f;
else if (v.y > 14)
v.y = 14f;
if (v.z < -22)
v.z = -22f;
else if (v.z > 30)
v.z = 30f;
ent.client.ps.viewoffset = v;
}
/*
==============
SV_CalcGunOffset
==============
*/
static void(entity ent) SV_CalcGunOffset =
{
// gun angles from bobbing
#ifdef GROUND_ZERO
//ROGUE - heatbeam shouldn't bob so the beam looks right
if (ent.client.pers.weapon && ent.client.pers.weapon->weapmodel != WEAP_PLASMA)
{
#endif
ent.client.ps.gunangles[ROLL] = xyspeed * bobfracsin * 0.005f;
ent.client.ps.gunangles[YAW] = xyspeed * bobfracsin * 0.01f;
if (bobcycle & 1)
{
ent.client.ps.gunangles[ROLL] = -ent.client.ps.gunangles[ROLL];
ent.client.ps.gunangles[YAW] = -ent.client.ps.gunangles[YAW];
}
ent.client.ps.gunangles[PITCH] = xyspeed * bobfracsin * 0.005f;
// gun angles from delta movement
for (int i = 0; i < 3; i++)
{
float delta = ent.client.oldviewangles[i] - ent.client.ps.viewangles[i];
if (delta > 180)
delta -= 360f;
if (delta < -180)
delta += 360f;
if (delta > 45)
delta = 45f;
if (delta < -45)
delta = -45f;
if (i == YAW)
ent.client.ps.gunangles[ROLL] += 0.1f * delta;
ent.client.ps.gunangles[i] += 0.2f * delta;
}
#ifdef GROUND_ZERO
}
else
ent.client.ps.gunangles = vec3_origin;
#endif
// gun height
ent.client.ps.gunoffset = vec3_origin;
}
/*
=============
SV_AddBlend
=============
*/
static inline void(vector rgb, float a, float *v_blend) SV_AddBlend =
{
float a2 = v_blend[3] + (1 - v_blend[3]) * a; // new total alpha
float a3 = v_blend[3] / a2; // fraction of color from old
*((vector *)v_blend) = (*((vector *)v_blend) * a3) + (rgb * (1 - a3));
v_blend[3] = a2;
}
static const vector lava_blend = '1.0 0.3 0.0';
static const vector bonus_blend = '0.85 0.7 0.3';
static const vector slime_blend = '0.0 0.1 0.05';
static const vector water_blend = '0.5 0.3 0.2';
static const vector quad_blend = '0 0 1';
static const vector invul_blend = '1 1 0';
static const vector enviro_blend = '0 1 0';
static const vector breather_blend = '0.4 1 0.4';
#ifdef THE_RECKONING
static const vector quadfire_blend = '1 0.2 0.5';
#endif
#ifdef GROUND_ZERO
static const vector double_blend = '0.9 0.7 0';
static const vector nuke_blend = '1 1 1';
static const vector ir_blend = '1 0 0';
#endif
/*
=============
SV_CalcBlend
=============
*/
static void(entity ent) SV_CalcBlend =
{
int contents;
vector vieworg;
int remaining;
ent.client.ps.blend[0] = ent.client.ps.blend[1] = ent.client.ps.blend[2] = ent.client.ps.blend[3] = 0f;
// add for contents
vieworg = ent.s.origin + ent.client.ps.viewoffset;
contents = gi.pointcontents(vieworg);
if (contents & (CONTENTS_LAVA | CONTENTS_SLIME | CONTENTS_WATER))
ent.client.ps.rdflags |= RDF_UNDERWATER;
else
ent.client.ps.rdflags &= ~RDF_UNDERWATER;
if (contents & (CONTENTS_SOLID | CONTENTS_LAVA))
SV_AddBlend(lava_blend, 0.6f, &ent.client.ps.blend[0]);
else if (contents & CONTENTS_SLIME)
SV_AddBlend(slime_blend, 0.6f, &ent.client.ps.blend[0]);
else if (contents & CONTENTS_WATER)
SV_AddBlend(water_blend, 0.4f, &ent.client.ps.blend[0]);
// add for powerups
if (ent.client.quad_framenum > level.framenum)
{
remaining = ent.client.quad_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("items/damage2.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4))
SV_AddBlend(quad_blend, 0.08f, &ent.client.ps.blend[0]);
}
#ifdef THE_RECKONING
// RAFAEL
else if (ent.client.quadfire_framenum > level.framenum)
{
remaining = ent.client.quadfire_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("items/quadfire2.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4) )
SV_AddBlend (quadfire_blend, 0.08f, &ent.client.ps.blend[0]);
}
#endif
#ifdef GROUND_ZERO
else if (ent.client.double_framenum > level.framenum)
{
remaining = ent.client.double_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("misc/ddamage2.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4) )
SV_AddBlend (double_blend, 0.08f, &ent.client.ps.blend[0]);
}
#endif
else if (ent.client.invincible_framenum > level.framenum) {
remaining = ent.client.invincible_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("items/protect2.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4))
SV_AddBlend(invul_blend, 0.08f, &ent.client.ps.blend[0]);
} else if (ent.client.enviro_framenum > level.framenum) {
remaining = ent.client.enviro_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("items/airout.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4))
SV_AddBlend(enviro_blend, 0.08f, &ent.client.ps.blend[0]);
} else if (ent.client.breather_framenum > level.framenum) {
remaining = ent.client.breather_framenum - level.framenum;
if (remaining == 30) // beginning to fade
gi.sound(ent, CHAN_ITEM, gi.soundindex("items/airout.wav"), 1, ATTN_NORM, 0);
if (remaining > 30 || (remaining & 4))
SV_AddBlend(breather_blend, 0.04f, &ent.client.ps.blend[0]);
}
#ifdef GROUND_ZERO
if(ent.client.nuke_framenum > level.framenum)
{
float brightness = (ent.client.nuke_framenum - level.framenum) / 20.0;
SV_AddBlend (nuke_blend, brightness, &ent.client.ps.blend[0]);
}
if (ent.client.ir_framenum > level.framenum)
{
remaining = ent.client.ir_framenum - level.framenum;
if(remaining > 30 || (remaining & 4))
{
ent.client.ps.rdflags |= RDF_IRGOGGLES;
SV_AddBlend (ir_blend, 0.2, &ent.client.ps.blend[0]);
}
else
ent.client.ps.rdflags &= ~RDF_IRGOGGLES;
}
else
ent.client.ps.rdflags &= ~RDF_IRGOGGLES;
#endif
// add for damage
if (ent.client.damage_alpha > 0)
SV_AddBlend(ent.client.damage_blend, ent.client.damage_alpha, &ent.client.ps.blend[0]);
if (ent.client.bonus_alpha > 0)
SV_AddBlend(bonus_blend, ent.client.bonus_alpha, &ent.client.ps.blend[0]);
// drop the damage value
ent.client.damage_alpha -= 0.06f;
if (ent.client.damage_alpha < 0)
ent.client.damage_alpha = 0;
// drop the bonus value
ent.client.bonus_alpha -= 0.1f;
if (ent.client.bonus_alpha < 0)
ent.client.bonus_alpha = 0;
}
/*
===============
G_SetClientEvent
===============
*/
static void(entity ent) G_SetClientEvent =
{
if (ent.s.event)
return;
if (ent.groundentity != null_entity && xyspeed > 225) {
if ((int)(ent.client.bobtime + bobmove) != bobcycle)
ent.s.event = EV_FOOTSTEP;
}
}
/*
===============
G_SetClientEffects
===============
*/
static void(entity ent) G_SetClientEffects =
{
int remaining;
ent.s.effects = 0;
ent.s.renderfx = RF_IR_VISIBLE;
if (ent.health <= 0 || level.intermission_framenum)
return;
if (ent.powerarmor_framenum > level.framenum) {
power_armor_type_t pa_type = PowerArmorType(ent);
if (pa_type == POWER_ARMOR_SCREEN)
ent.s.effects |= EF_POWERSCREEN;
else if (pa_type == POWER_ARMOR_SHIELD) {
ent.s.effects |= EF_COLOR_SHELL;
ent.s.renderfx |= RF_SHELL_GREEN;
}
}
if (ent.client.quad_framenum > level.framenum) {
remaining = ent.client.quad_framenum - level.framenum;
if (remaining > 30 || (remaining & 4))
ent.s.effects |= EF_QUAD;
}
#ifdef THE_RECKONING
// RAFAEL
if (ent.client.quadfire_framenum > level.framenum)
{
remaining = ent.client.quadfire_framenum - level.framenum;
if (remaining > 30 || (remaining & 4) )
ent.s.effects |= EF_QUAD;
}
#endif
#ifdef GROUND_ZERO
if (ent.client.double_framenum > level.framenum)
{
remaining = ent.client.double_framenum - level.framenum;
if (remaining > 30 || (remaining & 4) )
ent.s.effects |= EF_DOUBLE;
}
if (ent.client.tracker_pain_framenum > level.framenum)
ent.s.effects |= EF_TRACKERTRAIL;
#endif
if (ent.client.invincible_framenum > level.framenum)
{
remaining = ent.client.invincible_framenum - level.framenum;
if (remaining > 30 || (remaining & 4))
ent.s.effects |= EF_PENT;
}
// show cheaters!!!
if (ent.flags & FL_GODMODE)
{
ent.s.effects |= EF_COLOR_SHELL;
ent.s.renderfx |= (RF_SHELL_RED | RF_SHELL_GREEN | RF_SHELL_BLUE);
}
#ifdef CTF
CTFEffects(ent);
#endif
}
/*
===============
G_SetClientSound
===============
*/
static void(entity ent) G_SetClientSound =
{
weap_model_t weap;
#ifdef SINGLE_PLAYER
if (ent.client.pers.game_helpchanged != game.helpchanged)
{
ent.client.pers.game_helpchanged = game.helpchanged;
ent.client.pers.helpchanged = 1;
}
// help beep (no more than three times)
if (ent.client.pers.helpchanged && ent.client.pers.helpchanged <= 3 && !(level.framenum & 63))
{
ent.client.pers.helpchanged++;
gi.sound(ent, CHAN_VOICE, gi.soundindex("misc/pc_up.wav"), 1, ATTN_STATIC, 0);
}
#endif
if (ent.client.pers.weapon)
weap = ent.client.pers.weapon->weapmodel;
else
weap = 0;
if (ent.waterlevel && (ent.watertype & (CONTENTS_LAVA | CONTENTS_SLIME)))
ent.s.sound = snd_fry;
else if (weap == WEAP_RAILGUN)
ent.s.sound = gi.soundindex("weapons/rg_hum.wav");
else if (weap == WEAP_BFG)
ent.s.sound = gi.soundindex("weapons/bfg_hum.wav");
#ifdef THE_RECKONING
else if (weap == WEAP_PHALANX)
ent.s.sound = gi.soundindex("weapons/phaloop.wav");
#endif
else if (ent.client.weapon_sound)
ent.s.sound = ent.client.weapon_sound;
else
ent.s.sound = 0;
}
/*
===============
G_SetClientFrame
===============
*/
void(entity ent) G_SetClientFrame =
{
bool duck, run;
if (ent.s.modelindex != 255)
return; // not in the player model
if (ent.client.ps.pmove.pm_flags & PMF_DUCKED)
duck = true;
else
duck = false;
if (xyspeed)
run = true;
else
run = false;
// check for stand/duck and stop/go transitions
if (duck != ent.client.anim_duck && ent.client.anim_priority < ANIM_DEATH)
goto newanim;
if (run != ent.client.anim_run && ent.client.anim_priority == ANIM_BASIC)
goto newanim;
if (ent.groundentity == null_entity && ent.client.anim_priority <= ANIM_WAVE)
goto newanim;
if (ent.client.anim_priority == ANIM_REVERSE)
{
if (ent.s.frame > ent.client.anim_end)
{
ent.s.frame--;
return;
}
}
else if (ent.s.frame < ent.client.anim_end)
{
// continue an animation
ent.s.frame++;
return;
}
if (ent.client.anim_priority == ANIM_DEATH)
return; // stay there
if (ent.client.anim_priority == ANIM_JUMP)
{
if (ent.groundentity == null_entity)
return; // stay there
ent.client.anim_priority = ANIM_WAVE;
ent.s.frame = FRAME_jump3;
ent.client.anim_end = FRAME_jump6;
return;
}
newanim:
// return to either a running or standing frame
ent.client.anim_priority = ANIM_BASIC;
ent.client.anim_duck = duck;
ent.client.anim_run = run;
if (ent.groundentity == null_entity)
{
#ifdef HOOK_CODE
// if on grapple, don't go into jump frame, go into standing frame
if (ent.client.grapple)
{
ent->s.frame = FRAME_stand01;
ent.client.anim_end = FRAME_stand40;
}
else
{
#endif
ent.client.anim_priority = ANIM_JUMP;
if (ent.s.frame != FRAME_jump2)
ent.s.frame = FRAME_jump1;
ent.client.anim_end = FRAME_jump2;
#ifdef HOOK_CODE
}
#endif
}
else if (run)
{
// running
if (duck)
{
ent.s.frame = FRAME_crwalk1;
ent.client.anim_end = FRAME_crwalk6;
}
else
{
ent.s.frame = FRAME_run1;
ent.client.anim_end = FRAME_run6;
}
}
else
{
// standing
if (duck)
{
ent.s.frame = FRAME_crstnd01;
ent.client.anim_end = FRAME_crstnd19;
}
else
{
ent.s.frame = FRAME_stand01;
ent.client.anim_end = FRAME_stand40;
}
}
}
/*
=================
ClientEndServerFrame
Called for each player at the end of the server frame
and right after spawning
=================
*/
void(entity ent) ClientEndServerFrame =
{
float bobtime;