-
Notifications
You must be signed in to change notification settings - Fork 2
/
pmove.qc
1199 lines (975 loc) · 23.9 KB
/
pmove.qc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
Copyright (C) 1997-2001 Id Software, Inc.
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
See the GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
*/
#ifdef QUAKEC_PMOVE
// all of the locals will be zeroed before each
// pmove, just to make damn sure we don't have
// any differences when running on client or server
static struct
{
vector origin; // full float precision
vector velocity; // full float precision
vector forward, right, up;
float frametime;
csurface_t groundsurface;
vector groundnormal;
int groundcontents;
vector previous_origin;
bool ladder;
} pml;
static pmove_t *pm;
// movement parameters
static const float pm_stopspeed = 100;
static const float pm_maxspeed = 300;
static const float pm_duckspeed = 100;
static const float pm_accelerate = 10;
static const float pm_airaccelerate = 0;
static const float pm_wateraccelerate = 10;
static const float pm_friction = 6;
static const float pm_waterfriction = 1;
static const float pm_waterspeed = 400;
static hashset pm_entity_list;
/*
walking up a step should kill some velocity
*/
/*
==================
PM_StepSlideMove
Each intersection will try to step over the obstruction instead of
sliding along it.
Returns a new origin, velocity, and contact entity
Does not modify any world state?
==================
*/
static const float MIN_STEP_NORMAL = 0.7; // can't step up onto very steep slopes
static void PM_StepSlideMove_ (void)
{
int bumpcount, numbumps;
vector dir;
float d;
int numplanes;
vector planes[MAX_CLIP_PLANES];
vector primal_velocity;
int i, j;
trace_t trace;
vector end;
float time_left;
numbumps = 4;
primal_velocity = pml.velocity;
numplanes = 0;
time_left = pml.frametime;
for (bumpcount = 0; bumpcount < numbumps; bumpcount++)
{
end = pml.origin + (time_left * pml.velocity);
pm->trace(&trace, pml.origin, pm->mins, pm->maxs, end);
if (trace.allsolid)
{
// entity is trapped in another solid
pml.velocity[2] = 0; // don't build up falling damage
return;
}
if (trace.fraction > 0)
{
// actually covered some distance
pml.origin = trace.endpos;
numplanes = 0;
}
if (trace.fraction == 1)
break; // moved the entire distance
// save entity for contact
if (trace.ent != null_entity)
hashset_add(pm_entity_list, TYPE_ENTITY, trace.ent);
time_left -= time_left * trace.fraction;
// slide along this plane
if (numplanes >= MAX_CLIP_PLANES)
{
// this shouldn't really happen
pml.velocity = vec3_origin;
break;
}
planes[numplanes] = trace.normal;
numplanes++;
//
// modify original_velocity so it parallels all of the clip planes
//
for (i=0 ; i<numplanes ; i++)
{
pml.velocity = ClipVelocity (pml.velocity, planes[i], 1.01);
for (j=0 ; j<numplanes ; j++)
if (j != i)
{
if ((pml.velocity * planes[j]) < 0)
break; // not ok
}
if (j == numplanes)
break;
}
if (i == numplanes)
{
// go along the crease
if (numplanes != 2)
{
pml.velocity = vec3_origin;
break;
}
dir = CrossProduct (planes[0], planes[1]);
d = dir * pml.velocity;
pml.velocity = dir * d;
}
//
// if velocity is against the original velocity, stop dead
// to avoid tiny occilations in sloping corners
//
if ((pml.velocity * primal_velocity) <= 0)
{
pml.velocity = vec3_origin;
break;
}
}
if (pm->s.pm_time)
pml.velocity = primal_velocity;
}
/*
==================
PM_StepSlideMove
==================
*/
static void PM_StepSlideMove (void)
{
vector start_o, start_v;
vector down_o, down_v;
trace_t trace;
float down_dist, up_dist;
vector up, down;
start_o = pml.origin;
start_v = pml.velocity;
PM_StepSlideMove_ ();
down_o = pml.origin;
down_v = pml.velocity;
up = start_o;
up[2] += STEPSIZE;
pm->trace (&trace, up, pm->mins, pm->maxs, up);
if (trace.allsolid)
return; // can't step up
// try sliding above
pml.origin = up;
pml.velocity = start_v;
PM_StepSlideMove_ ();
// push down the final amount
down = pml.origin;
down[2] -= STEPSIZE;
pm->trace (&trace, pml.origin, pm->mins, pm->maxs, down);
if (!trace.allsolid)
pml.origin = trace.endpos;
up = pml.origin;
// decide which one went farther
down_dist = (down_o[0] - start_o[0])*(down_o[0] - start_o[0])
+ (down_o[1] - start_o[1])*(down_o[1] - start_o[1]);
up_dist = (up[0] - start_o[0])*(up[0] - start_o[0])
+ (up[1] - start_o[1])*(up[1] - start_o[1]);
if (down_dist > up_dist || trace.normal[2] < MIN_STEP_NORMAL)
{
pml.origin = down_o;
pml.velocity = down_v;
return;
}
//!! Special case
// if we were walking along a plane, then we need to copy the Z over
pml.velocity[2] = down_v[2];
}
/*
==================
PM_Friction
Handles both ground friction and water friction
==================
*/
static void PM_Friction (void)
{
float speed, newspeed, control;
float friction;
float drop;
speed = VectorLength(pml.velocity);
if (speed < 1)
{
pml.velocity[0] = pml.velocity[1] = 0;
return;
}
drop = 0;
// apply ground friction
if ((pm->groundentity != null_entity && !(pml.groundsurface.flags & SURF_SLICK)) || pml.ladder)
{
friction = pm_friction;
control = speed < pm_stopspeed ? pm_stopspeed : speed;
drop += control*friction*pml.frametime;
}
// apply water friction
if (pm->waterlevel && !pml.ladder)
drop += speed*pm_waterfriction*pm->waterlevel*pml.frametime;
// scale the velocity
newspeed = speed - drop;
if (newspeed < 0)
{
newspeed = 0;
}
newspeed /= speed;
pml.velocity *= newspeed;
}
/*
==============
PM_Accelerate
Handles user intended acceleration
==============
*/
static void PM_Accelerate (vector wishdir, float wishspeed, float accel)
{
float addspeed, accelspeed, currentspeed;
currentspeed = pml.velocity * wishdir;
addspeed = wishspeed - currentspeed;
if (addspeed <= 0)
return;
accelspeed = accel*pml.frametime*wishspeed;
if (accelspeed > addspeed)
accelspeed = addspeed;
pml.velocity += accelspeed * wishdir;
}
static void PM_AirAccelerate (vector wishdir, float wishspeed, float accel)
{
float addspeed, accelspeed, currentspeed, wishspd = wishspeed;
if (wishspd > 30)
wishspd = 30f;
currentspeed = pml.velocity * wishdir;
addspeed = wishspd - currentspeed;
if (addspeed <= 0)
return;
accelspeed = accel * wishspeed * pml.frametime;
if (accelspeed > addspeed)
accelspeed = addspeed;
pml.velocity += accelspeed * wishdir;
}
/*
=============
PM_AddCurrents
=============
*/
static void PM_AddCurrents (inout vector wishvel)
{
vector v;
float s;
//
// account for ladders
//
if (pml.ladder && fabs(pml.velocity[2]) <= 200)
{
if ((pm->viewangles[PITCH] <= -15) && (pm->cmd.forwardmove > 0))
wishvel[2] = 200f;
else if ((pm->viewangles[PITCH] >= 15) && (pm->cmd.forwardmove > 0))
wishvel[2] = -200f;
else if (pm->cmd.upmove > 0)
wishvel[2] = 200f;
else if (pm->cmd.upmove < 0)
wishvel[2] = -200f;
else
wishvel[2] = 0;
// limit horizontal speed when on a ladder
if (wishvel[0] < -25)
wishvel[0] = -25f;
else if (wishvel[0] > 25)
wishvel[0] = 25f;
if (wishvel[1] < -25)
wishvel[1] = -25f;
else if (wishvel[1] > 25)
wishvel[1] = 25f;
}
//
// add water currents
//
if (pm->watertype & MASK_CURRENT)
{
v = vec3_origin;
if (pm->watertype & CONTENTS_CURRENT_0)
v[0] += 1;
if (pm->watertype & CONTENTS_CURRENT_90)
v[1] += 1;
if (pm->watertype & CONTENTS_CURRENT_180)
v[0] -= 1;
if (pm->watertype & CONTENTS_CURRENT_270)
v[1] -= 1;
if (pm->watertype & CONTENTS_CURRENT_UP)
v[2] += 1;
if (pm->watertype & CONTENTS_CURRENT_DOWN)
v[2] -= 1;
s = pm_waterspeed;
if (pm->waterlevel == 1 && pm->groundentity != null_entity)
s *= 0.5f;
wishvel += s * v;
}
//
// add conveyor belt velocities
//
if (pm->groundentity != null_entity)
{
v = vec3_origin;
if (pml.groundcontents & CONTENTS_CURRENT_0)
v[0] += 1;
if (pml.groundcontents & CONTENTS_CURRENT_90)
v[1] += 1;
if (pml.groundcontents & CONTENTS_CURRENT_180)
v[0] -= 1;
if (pml.groundcontents & CONTENTS_CURRENT_270)
v[1] -= 1;
if (pml.groundcontents & CONTENTS_CURRENT_UP)
v[2] += 1;
if (pml.groundcontents & CONTENTS_CURRENT_DOWN)
v[2] -= 1;
wishvel += 100 * v;
}
}
/*
===================
PM_WaterMove
===================
*/
static void PM_WaterMove (void)
{
vector wishvel;
float wishspeed;
vector wishdir;
//
// user intentions
//
wishvel = pml.forward * pm->cmd.forwardmove + pml.right * pm->cmd.sidemove;
if (!pm->cmd.forwardmove && !pm->cmd.sidemove && !pm->cmd.upmove)
wishvel[2] -= 60; // drift towards bottom
else
wishvel[2] += pm->cmd.upmove;
PM_AddCurrents (wishvel);
wishdir = wishvel;
wishspeed = VectorNormalize(wishdir);
if (wishspeed > pm_maxspeed)
{
wishvel *= pm_maxspeed / wishspeed;
wishspeed = pm_maxspeed;
}
wishspeed *= 0.5;
PM_Accelerate (wishdir, wishspeed, pm_wateraccelerate);
PM_StepSlideMove ();
}
/*
===================
PM_AirMove
===================
*/
static void PM_AirMove (void)
{
int i;
vector wishvel;
int fmove, smove;
vector wishdir;
float wishspeed;
float maxspeed;
fmove = pm->cmd.forwardmove;
smove = pm->cmd.sidemove;
for (i = 0; i < 2; i++)
wishvel[i] = pml.forward[i]*fmove + pml.right[i]*smove;
wishvel[2] = 0;
PM_AddCurrents (wishvel);
wishdir = wishvel;
wishspeed = VectorNormalize(wishdir);
//
// clamp to server defined max speed
//
maxspeed = (pm->s.pm_flags & PMF_DUCKED) ? pm_duckspeed : pm_maxspeed;
if (wishspeed > maxspeed)
{
wishvel *= maxspeed / wishspeed;
wishspeed = maxspeed;
}
if (pml.ladder)
{
PM_Accelerate (wishdir, wishspeed, pm_accelerate);
if (!wishvel[2])
{
if (pml.velocity[2] > 0)
{
pml.velocity[2] -= pm->s.gravity * pml.frametime;
if (pml.velocity[2] < 0)
pml.velocity[2] = 0;
}
else
{
pml.velocity[2] += pm->s.gravity * pml.frametime;
if (pml.velocity[2] > 0)
pml.velocity[2] = 0;
}
}
PM_StepSlideMove ();
}
else if (pm->groundentity != null_entity)
{ // walking on ground
pml.velocity[2] = 0; //!!! this is before the accel
PM_Accelerate (wishdir, wishspeed, pm_accelerate);
if(pm->s.gravity > 0)
pml.velocity[2] = 0;
else
pml.velocity[2] -= pm->s.gravity * pml.frametime;
if (!pml.velocity[0] && !pml.velocity[1])
return;
PM_StepSlideMove ();
}
else
{ // not on ground, so little effect on velocity
if (pm_airaccelerate)
PM_AirAccelerate (wishdir, wishspeed, pm_accelerate);
else
PM_Accelerate (wishdir, wishspeed, 1);
// add gravity
pml.velocity[2] -= pm->s.gravity * pml.frametime;
PM_StepSlideMove ();
}
}
/*
=============
PM_CatagorizePosition
=============
*/
static void PM_CatagorizePosition (void)
{
vector point;
int cont;
trace_t trace;
int sample1;
int sample2;
// if the player hull point one unit down is solid, the player
// is on ground
// see if standing on something solid
point[0] = pml.origin[0];
point[1] = pml.origin[1];
point[2] = pml.origin[2] - 0.25;
if (pml.velocity[2] > 180) //!!ZOID changed from 100 to 180 (ramp accel)
{
pm->s.pm_flags &= ~PMF_ON_GROUND;
pm->groundentity = null_entity;
}
else
{
pm->trace (&trace, pml.origin, pm->mins, pm->maxs, point);
pml.groundnormal = trace.normal;
pml.groundsurface = trace.surface;
pml.groundcontents = trace.contents;
if (trace.ent == null_entity || (trace.normal[2] < 0.7 && !trace.startsolid))
{
pm->groundentity = null_entity;
pm->s.pm_flags &= ~PMF_ON_GROUND;
}
else
{
pm->groundentity = trace.ent;
// hitting solid ground will end a waterjump
if (pm->s.pm_flags & PMF_TIME_WATERJUMP)
{
pm->s.pm_flags &= ~(PMF_TIME_WATERJUMP | PMF_TIME_LAND | PMF_TIME_TELEPORT);
pm->s.pm_time = 0;
}
if (! (pm->s.pm_flags & PMF_ON_GROUND) )
{ // just hit the ground
pm->s.pm_flags |= PMF_ON_GROUND;
// don't do landing time if we were just going down a slope
if (pml.velocity[2] < -200)
{
pm->s.pm_flags |= PMF_TIME_LAND;
// don't allow another jump for a little while
if (pml.velocity[2] < -400)
pm->s.pm_time = 25;
else
pm->s.pm_time = 18;
}
}
}
if (trace.ent != null_entity)
hashset_add(pm_entity_list, TYPE_ENTITY, trace.ent);
}
//
// get waterlevel, accounting for ducking
//
pm->waterlevel = 0;
pm->watertype = 0;
sample2 = (int)(pm->viewheight - pm->mins[2]);
sample1 = sample2 / 2;
point[2] = pml.origin[2] + pm->mins[2] + 1;
cont = pm->pointcontents (point);
if (cont & MASK_WATER)
{
pm->watertype = cont;
pm->waterlevel = 1;
point[2] = pml.origin[2] + pm->mins[2] + sample1;
cont = pm->pointcontents (point);
if (cont & MASK_WATER)
{
pm->waterlevel = 2;
point[2] = pml.origin[2] + pm->mins[2] + sample2;
cont = pm->pointcontents (point);
if (cont & MASK_WATER)
pm->waterlevel = 3;
}
}
}
/*
=============
PM_CheckJump
=============
*/
static void PM_CheckJump (void)
{
if (pm->s.pm_flags & PMF_TIME_LAND)
{ // hasn't been long enough since landing to jump again
return;
}
if (pm->cmd.upmove < 10)
{ // not holding jump
pm->s.pm_flags &= ~PMF_JUMP_HELD;
return;
}
// must wait for jump to be released
if (pm->s.pm_flags & PMF_JUMP_HELD)
return;
if (pm->s.pm_type == PM_DEAD)
return;
if (pm->waterlevel >= 2)
{ // swimming, not jumping
pm->groundentity = null_entity;
if (pml.velocity[2] <= -300)
return;
if (pm->watertype == CONTENTS_WATER)
pml.velocity[2] = 100f;
else if (pm->watertype == CONTENTS_SLIME)
pml.velocity[2] = 80f;
else
pml.velocity[2] = 50f;
return;
}
if (pm->groundentity == null_entity)
return; // in air, so no effect
pm->s.pm_flags |= PMF_JUMP_HELD;
pm->groundentity = null_entity;
pml.velocity[2] += 270;
if (pml.velocity[2] < 270)
pml.velocity[2] = 270f;
}
/*
=============
PM_CheckSpecialMovement
=============
*/
static void PM_CheckSpecialMovement (void)
{
vector spot;
int cont;
vector flatforward;
trace_t trace;
if (pm->s.pm_time)
return;
pml.ladder = false;
// check for ladder
flatforward[0] = pml.forward[0];
flatforward[1] = pml.forward[1];
flatforward[2] = 0;
VectorNormalize (flatforward);
spot = pml.origin + (1 * flatforward);
pm->trace (&trace, pml.origin, pm->mins, pm->maxs, spot);
if (trace.fraction < 1 && (trace.contents & CONTENTS_LADDER))
pml.ladder = true;
// check for water jump
if (pm->waterlevel != 2)
return;
spot = pml.origin + (30 * flatforward);
spot[2] += 4;
cont = pm->pointcontents (spot);
if (!(cont & CONTENTS_SOLID))
return;
spot[2] += 16;
cont = pm->pointcontents (spot);
if (cont)
return;
// jump out of water
pml.velocity = flatforward * 50;
pml.velocity[2] = 350f;
pm->s.pm_flags |= PMF_TIME_WATERJUMP;
pm->s.pm_time = 255;
}
/*
===============
PM_FlyMove
===============
*/
static void PM_FlyMove (bool doclip)
{
float speed, drop, friction, control, newspeed;
float currentspeed, addspeed, accelspeed;
vector wishvel;
int fmove, smove;
vector wishdir;
float wishspeed;
vector end;
trace_t trace;
pm->viewheight = 22f;
// friction
speed = VectorLength (pml.velocity);
if (speed < 1)
pml.velocity = vec3_origin;
else
{
drop = 0;
friction = pm_friction*1.5; // extra friction
control = speed < pm_stopspeed ? pm_stopspeed : speed;
drop += control*friction*pml.frametime;
// scale the velocity
newspeed = speed - drop;
if (newspeed < 0)
newspeed = 0;
newspeed /= speed;
pml.velocity *= newspeed;
}
// accelerate
fmove = pm->cmd.forwardmove;
smove = pm->cmd.sidemove;
VectorNormalize (pml.forward);
VectorNormalize (pml.right);
wishvel = pml.forward*fmove + pml.right*smove;
wishvel[2] += pm->cmd.upmove;
wishdir = wishvel;
wishspeed = VectorNormalize(wishdir);
//
// clamp to server defined max speed
//
if (wishspeed > pm_maxspeed)
{
wishvel *= pm_maxspeed / wishspeed;
wishspeed = pm_maxspeed;
}
currentspeed = pml.velocity * wishdir;
addspeed = wishspeed - currentspeed;
if (addspeed <= 0)
return;
accelspeed = pm_accelerate*pml.frametime*wishspeed;
if (accelspeed > addspeed)
accelspeed = addspeed;
pml.velocity += accelspeed * wishdir;
if (doclip)
{
end = pml.origin + (pml.frametime * pml.velocity);
pm->trace (&trace, pml.origin, pm->mins, pm->maxs, end);
pml.origin = trace.endpos;
}
else
pml.origin += pml.frametime * pml.velocity; // move
}
/*
==============
PM_CheckDuck
Sets mins, maxs, and pm->viewheight
==============
*/
static void PM_CheckDuck (void)
{
trace_t trace;
pm->mins[0] = -16f;
pm->mins[1] = -16f;
pm->maxs[0] = 16f;
pm->maxs[1] = 16f;
if (pm->s.pm_type == PM_GIB)
{
pm->mins[2] = 0;
pm->maxs[2] = 16f;
pm->viewheight = 8f;
return;
}
pm->mins[2] = -24f;
if (pm->s.pm_type == PM_DEAD)
pm->s.pm_flags |= PMF_DUCKED;
else if (pm->cmd.upmove < 0 && (pm->s.pm_flags & PMF_ON_GROUND))
pm->s.pm_flags |= PMF_DUCKED; // duck
else if (pm->s.pm_flags & PMF_DUCKED)
{
// try to stand up
pm->maxs[2] = 32f;
pm->trace (&trace, pml.origin, pm->mins, pm->maxs, pml.origin);
if (!trace.allsolid)
pm->s.pm_flags &= ~PMF_DUCKED;
}
if (pm->s.pm_flags & PMF_DUCKED)
{
pm->maxs[2] = 4f;
pm->viewheight = -2f;
}
else
{
pm->maxs[2] = 32f;
pm->viewheight = 22f;
}
}
/*
==============
PM_DeadMove
==============
*/
static void PM_DeadMove (void)
{
float forward;
if (pm->groundentity == null_entity)
return;
// extra friction
forward = VectorLength (pml.velocity);
forward -= 20;
if (forward <= 0)
pml.velocity = vec3_origin;
else
{
VectorNormalize (pml.velocity);
pml.velocity *= forward;
}
}
static bool PM_GoodPosition (void)
{
trace_t trace;
vector origin, end;
if (pm->s.pm_type == PM_SPECTATOR)
return true;
origin = end = pm->s.origin * 0.125;
pm->trace (&trace, origin, pm->mins, pm->maxs, end);
return !trace.allsolid;
}
/*
================
PM_SnapPosition
On exit, the origin will have a value that is pre-quantized to the 0.125
precision of the network channel and in a valid position.
================
*/
static void PM_SnapPosition (void)
{
int sign[3] = { 0 };
int i, j, bits;
int base[3] = { 0 };
// try all single bits first
static int jitterbits[8] = {0,4,1,2,3,5,6,7};
// snap velocity to eigths
for (i=0 ; i<3 ; i++)
pm->s.velocity[i] = (float)(int)(pml.velocity[i]*8);
for (i=0 ; i<3 ; i++)
{
if (pml.origin[i] >= 0)
sign[i] = 1;
else
sign[i] = -1;
pm->s.origin[i] = (float)(base[i] = (int)(pml.origin[i]*8));
if (pm->s.origin[i]*0.125 == pml.origin[i])
sign[i] = 0;
}
// try all combinations
for (j=0 ; j<8 ; j++)
{
bits = jitterbits[j];
pm->s.origin = [ (float)base[0], (float)base[1], (float)base[2] ];
for (i=0 ; i<3 ; i++)
if (bits & (1<<i) )
pm->s.origin[i] += sign[i];
if (PM_GoodPosition ())
return;
}
// go back to the last position
pm->s.origin = pml.previous_origin;
}
/*
================
PM_InitialSnapPosition
================
*/
static void PM_InitialSnapPosition(void)
{
int x, y, z;
static int offset[3] = { 0, -1, 1 };
int base[3] = { (int)pm->s.origin[0], (int)pm->s.origin[1], (int)pm->s.origin[2] };
for ( z = 0; z < 3; z++ ) {
pm->s.origin[2] = (float)(base[2] + offset[z]);
for ( y = 0; y < 3; y++ ) {
pm->s.origin[1] = (float)(base[1] + offset[y]);
for ( x = 0; x < 3; x++ ) {
pm->s.origin[0] = (float)(base[0] + offset[x]);
if (PM_GoodPosition ()) {
pml.origin = pm->s.origin * 0.125;
pml.previous_origin = pm->s.origin;
return;
}
}
}