FACE DevGuideExample Build Error

[ktk1ng]

I am trying to build the Face/Simple example from DevGuideExample's and I am unable to get it to build. I was able to build the messenger example fine. I keep getting this error:
/usr/bin/ld: CMakeFiles/publisher.dir/Publisher.cpp.o: in function main': Publisher.cpp:(.text+0x31c): undefined reference to FACE::TS::Send_Message(long, long, long&, Messenger::Message&, int&, FACE::RETURN_CODE_TYPE&)'
collect2: error: ld returned 1 exit status
gmake[2]: *** [CMakeFiles/publisher.dir/build.make:112: publisher] Error 1
gmake[1]: *** [CMakeFiles/Makefile2:115: CMakeFiles/publisher.dir/all] Error 2
gmake: *** [Makefile:101: all] Error 2

Here is the CMakeLists.txt file I am using. The publisher and subscriber files are the ones provided.

cmake_minimum_required(VERSION 3.22...3.27)
project(opendds_face_simple CXX)
enable_testing()

find_package(OpenDDS REQUIRED)
include(opendds_testing)

# IDL TypeSupport Library
add_library(face_messenger_idl)
opendds_target_sources(face_messenger_idl PUBLIC "FaceMessage.idl")
target_link_libraries(face_messenger_idl PUBLIC OpenDDS::FACE)

set(opendds_libs
  OpenDDS::FACE # Core OpenDDS Library
  OpenDDS::InfoRepoDiscovery OpenDDS::Tcp # For run_test.pl
  OpenDDS::Rtps OpenDDS::Rtps_Udp # For run_test.pl --rtps
  face_messenger_idl
)

# Publisher
add_executable(publisher
  Publisher.cpp
)

target_link_libraries(publisher ${opendds_libs})
# Subscriber
add_executable(subscriber
  Subscriber.cpp
)

target_link_libraries(subscriber ${opendds_libs})
# Callback Subscriber
add_executable(callback_subscriber
  CallbackSubscriber.cpp
)

target_link_libraries(callback_subscriber ${opendds_libs})
# Testing
configure_file(run_test.pl . COPYONLY)
configure_file(rtps.ini . COPYONLY)
opendds_add_test(NAME info_repo COMMAND perl run_test.pl)
opendds_add_test(NAME rtps COMMAND perl run_test.pl --rtps)

[mitza-oci]

The included FACE example contains build steps that invoke the opendds_idl compiler with specific command-line arguments. You'll need to use those in your build as well.

[iguessthislldo]

I don't think we've ever officially tested any FACE-related things with CMake, or at least I haven't. OpenDDS::FACE isn't even documented as a library you can use, but it exists in the code that imports libraries from the MPC build as you already have. I assume you used the MPC build/configure script because the CMake build of OpenDDS doesn't build OpenDDS::FACE.

To add to what Adam said, the settings for MPC are in MPC/config/opendds_face.mpb. Looking at the CMake code, it looks it should pass the correct IDL compiler options if you link OpenDDS::FACE and then it correctly handles them later.

That's checking if it's linked in opendds_target_sources though, so you should link to OpenDDS::FACE before opendds_target_sources:

# IDL TypeSupport Library
add_library(face_messenger_idl)
target_link_libraries(face_messenger_idl PUBLIC OpenDDS::FACE)
opendds_target_sources(face_messenger_idl PUBLIC "FaceMessage.idl")

After I switched those two lines and commented out the test code for the run_test.pl that's not there, I was able to build the FACE example.

If we want to be at least somewhat serious about FACE in CMake we should probably:

1. Add a CMakeLists.txt for DevGuideExamples/FACE/Simple.
2. Add OpenDDS::FACE to the OpenDDS CMake build.
3. Add the OpenDDS::FACE library to the list of CMake libraries.
4. Add a small not to the documentation of opendds_target_sources that OpenDDS::FACE has to be linked before hand.

[iguessthislldo]

I'm going to go ahead and mark this as the answer since I tested it and the solution is trivial. I created an issue to improve FACE support in CMake: #4598.